Discussion :

[Rifton007]

Bonjour à vous tous et voici le probléme que j'ai rencontré.
Je suis actuellement le tuto "Les modèles et papiers à lettres sous Outlook"

Je suis censé coller ce code dans mon macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub CreationMailHTML()
'---------------------------------------------------------------------------------------
' Procédure : CreationMailHTML
' Auteur    : Dolphy35 - http://dolphy35.developpez.com/
' Date      : 01/05/2008
' Détail    : Récupère le contenu d'un fichier HTML et le charge en tant que corps du message du mail
'---------------------------------------------------------------------------------------
'
'Déclarations des objets et des variables
    Dim olApp As Outlook.Application
    Dim objMail As Outlook.MailItem
    Dim strBody As String
    Dim oFSO As Scripting.FileSystemObject
    Dim oFl As Scripting.File
    Dim oTxt As Scripting.TextStream
 
    'Instance des objets
    Set olApp = Outlook.Application
    Set objMail = olApp.CreateItem(olMailItem)
    'instance des objets Fso pour récupérer le contenu du fichier HTML
    Set oFSO = New Scripting.FileSystemObject
    Set oFl = oFSO.GetFile("C:\source.html")
    Set oTxt = oFl.OpenAsTextStream(ForReading)
 
    'récupère le contenu du fichier HTML
    strBody = oTxt.ReadAll
 
    'Objet mail
    With objMail
       .BodyFormat = olFormatHTML                           'définition du format du mail, ici HTML
       .Subject = "Lettre d'Office - wwww.developpez.com"   'sujet du mail
       .HTMLBody = strBody                                  'chargement du fichier HTML en tant que coprs du message
       .Display                                             'affichage du mail
    End With
 
End Sub

Mais le macro bug sur cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim oFSO As Scripting.FileSystemObject

Type défini par l'utilisateur non défini

Merci de votre aide.

[Invité]

Bonjour

As-tu coché la référence Microsoft Scripting Runtime dans le menu Outils référence ?

Je viens de relire le tuto de Dolphy35, il semble avoir oublié de le mentionner, je vais le lui signaler.

Starec

[Rifton007]

Merci bien le noeud du probléme était là.

Encore merci.

[Dolphy35]

Bonjour

As-tu coché la référence Microsoft Scripting Runtime dans le menu Outils référence ?

Je viens de relire le tuto de Dolphy35, il semble avoir oublié de le mentionner, je vais le lui signaler.

Starec

Merci bien le noeud du probléme était là.

Encore merci.

oups petit oubli

je viens de corriger http://dolphy35.developpez.com/artic...deles/#LIV-A-2

[Invité]

Re

Alors un petit clique sur le bouton en bas de la discussion, c'est comme la ceinture de sécurité, un petit clique vaut mieux qu'un grand choc d'un modérateur

Starec

[Rifton007]

Ca fait super plaisir d'être suivit, aidé et d'être dans un forum aussi agréable.

Merci à tout les deux de votre aide et super le tuto Dolphy35.