Discussion :

[Elvis32]

Bonjour

Petite précision : je suis très novice !

Voila ce que je souhaiterais faire. J'ai créé une macro Word qui doit ouvrir un fichier Excel, mais en lecture seule. En plus, quand on utilise cette macro et que le fichier Excel s'ouvre, on ne doit pas voir de fenêtre du genre "Ce fichier n'est disponible qu'en lecture seule, voulez vous continuer".

Avez vous des idées, car je suis complètement perdu !

Merci grandement pour votre aide.

[Pierre Fauconnier]

Bonjour et bienvenue sur les forums de DVP.

En cochant la référence à la bibliothèque Microsoft Excel x.0, tu bénéficies de l'aide syntaxique sur les objets que tu utilises, et tu peux utiliser le code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Ouvrir()
 
    Dim xl As Excel.Application
 
    Set xl = New Excel.Application
    xl.Visible = True
    xl.Workbooks.Open FileName:="d:\données\classeur1.xls", ReadOnly:=xlYes
End Sub

Si tu souhaites utiliser le classeur au sein du code de ta macro, crée un objet de ce type pour le manipuler, par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Ouvrir()
 
    Dim xl As Excel.Application
    Dim wb As Excel.Workbook
 
    Set xl = New Excel.Application
    xl.Visible = True
    Set wb = xl.Workbooks.Open(FileName:="d:\données\classeur1.xls", ReadOnly:=xlYes)
    wb.SaveAs "d:\données\blabla.xls"
 
End Sub

Si tu n'as pas coché la référence à Excel ou que tu ne peux pas le faire facilement (compatibilité de version), tu peux utiliser un objet non typé, mais tu n'auras pas l'aide syntaxique et tu devras donc la connaître. Tu ne pourras pas non plus utiliser la constante xlYes et tu devras donc la remplacer par sa valeur, à savoir 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Ouvrir()
 
    Dim xl As Object
    Dim wb As Object
 
    Set xl = CreateObject("Excel.Application")
    xl.Visible = True
    Set wb = xl.Workbooks.Open(FileName:="d:\données\classeur1.xls", ReadOnly:=1)
 
End Sub

Ok?

[Elvis32]

Merci pour ton aide ! C'est très bien expliqué pour un débutant comme moi.

Pourrais-je poser une autre question ? Comment faire pour que la macro ne lance pas le fichier Excel s'il est déjà ouvert ?

[ouskel'n'or]

Quelle est la finalité de ta question ?
Si tu souhaites l'ouvrir en lecture seule, il peut être ouvert et modifié, de toutes façons tu ne pourras pas l'enregistrer sous le même nom.
Veux-tu simplement savoir si un autre utilisateur l'a ouvert afin d'attendre qu'il le ferme ?

[Elvis32]

C'est parce que l'utilisateur peut lancer la macro plusieurs fois de suite, et qu'il risque donc de voir le fichier Excel s'afficher plusieurs fois, ce qui est un peu génant...

[ouskel'n'or]

Ok, alors teste ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub OuvertClosOuiNon()
Dim xlApp As Object
Dim xlCL1 As Object
    Set xlApp = CreateObject("Excel.Application")
 
    On Error Resume Next
        Set xlApp = GetObject(, "Excel.Application")
        'si le fichier est fermé, génère une erreur
        Set xlCL1 = xlApp.Workbooks("NomDuClasseur.xls")
    On Error GoTo 0
 
    If xlCL1 Is Nothing Then
        MsgBox "Classeur fermé"
        Else
        MsgBox "Classeur ouvert"
    End If
    'xlApp.Quit 'pour fermer l'instance de l'appli Excel
    Set xlApp = Nothing
    Set xlCL1 = Nothing
End Sub

Tu sauras adapter ?
Bon après-midi

[Heureux-oli]

Salut,

Je ne sais pas ce que tu veux faire avec ton fichier, mais si c'est pour récupérer des données pour les utiliser dans Word, tu peux ouvrir ton fichier, récupérer les données et fermer le fichier, les temps d'accès sont alors assez court et les télescopages assez réduits.

[Sepia]

Salut,

En effet, je suis d'accord avec Heureux-Oli, et dans ce cas, tu n'as même pas besoin d'ouvrir en lecture seule ton Excel, il suffit de le fermer sans sauvegarder (c'est encore plus rapide et tu n'as pas les pb de fenêtre d'avertissement du type "Voulez-vous ouvrir en lecture seule ?"

@+

[Elvis32]

Merci, tout fonctionne !