Discussion :

[stefsas]

Salut,

Je dispose d'une table de 4 colonnes.
La première "individu" correspond au numéro de mes individus
La deuxième "groupe" correspond au numéro du groupe à laquelle appartient chaque individu
La troisième "coord1" correspond aux coordonnées des individus sur le premier axe
La quatrième "coord2" correspond aux coordonnées des individus sur le deuxième axe

Ce que je voudrais faire, c'est pouvoir afficher les individus avec une couleur différente pour chaque groupe.

Si qq a une idée.

Merci.

[olivier.decourt]

Salut.
Je te propose une syntaxe PLOT y*x=groupe ; dans une proc GPLOT. C'est assez simple et ça doit correspondre à ton besoin.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
SYMBOL i = none v = circle ;
PROC GPLOT DATA = table ;
   PLOT coord2 * coord1 = groupe / LEGEND ;
RUN ; QUIT ;

Sinon, plus spectaculaire mais plus lourd à écrire, en GTL (SAS 9.1.3 Windows obligatoire) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
PROC TEMPLATE ;
	DEFINE STATGRAPH stefsas.acpPlot ;
		DYNAMIC varX varY varGpe ;
		 LAYOUT OVERLAY ;
			SCATTERPLOT X=varX Y=varY / GROUP=varGpe NAME="graphique" ;
			DISCRETELEGEND "graphique" / HALIGN=LEFT VALIGN=TOP ;
		ENDLAYOUT ;
	END ;
RUN ;
ODS HTML GPATH="c:\temp" ;
DATA _NULL_ ;
	FILE PRINT ODS=(TEMPLATE="stefsas.acpPlot" 
					 DYNAMIC=(varX="coord1" varY="coord2" varGpe="groupe")) ;
	SET table ;
	PUT _ODS_ ;
RUN ;
ODS HTML CLOSE ;

Olivier

[stefsas]

Ok d'accord.

Dans ton deuxième script, à quoi correspond la commande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ODS HTML GPATH="c:\temp" ;

car j'ai le message

ERREUR: Le fichier physique n'existe pas, c:\temp\FichierPrint10.gif.
ERREUR: Échec de l'Output Delivery System. Suspendu durant la phase EXECUTION.

Merci.

[olivier.decourt]

C'est pour indiquer un répertoire dans lequel créer l'image générée. Il faut que le répertoire existe déjà.
Sinon, tu peux aussi remplacer l'ODS HTML par un ODS RTF et créer un document Word qui contiendra ton image.

[stefsas]

Ok merci.