Discussion :

[y-master]

bonjour,

J'ai récupéré ce code sur le forum, que j'ai adapté a mes besoins :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Sub GetSenderFromCurrentFolder()
 
Dim MonOutlook As Outlook.Application
Dim LesMails As Object
 
'Déclaration des variables
    Dim appExcel As Excel.Application 'Application Excel
    Dim wbExcel As Excel.Workbook     'Classeur Excel
    Dim wsExcel As Excel.Worksheet    'Feuille Excel
 
    'Ouverture de l'application
    Set appExcel = CreateObject("Excel.Application")
    appExcel.Visible = True
    appExcel.Workbooks.Add
    Set wbExcel = appExcel.ActiveWorkbook
    Set wsExcel = wbExcel.ActiveSheet
 
    wsExcel.Range("a1").Value = "Mail"
 
    Dim ligne
    ligne = 2
 
Set MonOutlook = Outlook.Application
Set LesMails = MonOutlook.ActiveExplorer.Selection
If LesMails.Count <= 1 Then
toutmails = MsgBox("Selectionner tous les mails du dossier ?", vbYesNo, "pour recherche des adresses Email")
    If toutmails = vbYes Then
    Set LesMails = MonOutlook.ActiveExplorer.CurrentFolder.Items
    End If
End If
For Each lemail In LesMails
 
     wsExcel.Cells(ligne, 1).Value = lemail.SenderEmailAddress
    ligne = ligne + 1
 
Next lemail
 
MsgBox "Opération terminée"
End Sub

Je n'arrive pas a rajouter le fait que la recherche se fasse dans le dossier courant et dans ses sous dossiers.

Si quelqun à une piste a me proposer, je prend

Merci d'avance.

[Oliv-]

Salut,

Voici un exemple de syntaxe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub ProcessFolder(StartFolder As Outlook.MAPIFolder)
    Dim objFolder As Outlook.MAPIFolder
    Dim objItem as Object
    On Error Resume Next
 
    ' Ici on fait quelque chose dans chaque dossier
   ' on écrit une ligne dans la fenêtre exécution
    Debug.Print StartFolder.FolderPath, StartFolder.Items.Count
    Debug.Print
 
    ' Parcourt tous les sous-dossiers de ce dossier 
    For Each objFolder In StartFolder.Folders
        Call ProcessFolder(objFolder)
    Next
 
    ' Parcourt tous les éléments de ce dossier. 
    For Each objItem In StartFolder.Items
        Call ProcessItem(objItem)
    Next
 
    Set objFolder = Nothing
End Sub

Exemple d'utilisation à la racine de la BOÎTE .

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub ListSubFolders()
 
    Dim OL As Outlook.Application
    Dim OLNS As Outlook.NameSpace
    Dim OLItem As Object
    Dim OLFolder As Outlook.Folders
 
    Set OL = New Outlook.Application
    Set OLNS = OL.GetNamespace("MAPI")
 
    Set OLFolder = OLNS.GetDefaultFolder(olFolderInbox).Folders
'Ici on exécute la macro en question
    ProcessFolder OLNS.GetDefaultFolder(olFolderInbox).Parent
End Sub

[y-master]

merci pour l'exemple, je voie l'idée.
mais a quel moment tu défini ton ProcessItem ?

[Oliv-]

il faut bien sur la créer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
sub ProcessItem (item as object)
if Item.Class = olMail then
msgbox item.SenderEmailAddress
end if
end sub

Après il y a une méthode alternative c'est de créer dans les "dossiers de recherche" une recherche qui correspond à tous tes mails et de lancer ta procédure dans ce dossier uniquement. ok ?