Création dynamique de contrôles

**Jertho** · 30/10/2008, 18h43

Bonsoir,

J'essaie de créer un controle de façon dynamique c'est à dire aprés "click" d'un bouton sur un formulaire.

Le code que j'utilise est le suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Dim Top, Left, Width, Height, i As Integer 
Dim NumeroTextBox As Integer 
Dim TextBoxName As String 
 
Top = 150 
Left = 150 
Width = 2000 
Height = 275 
NumeroTextBox = 1 
 
For i = 0 To 4 - 1 
 
TextBoxName = "NomdelaTextBox" & NumeroTextBox 
Set TextBox = Controls.Add("VB.textbox", "" & TextBoxName & "", Me.Name) 
With TextBox 
.Visible = True 
.Top = Top 'Definit la distance entre le bord de la fenetre et le bord du conteneur 
.Left = Left 'Definit la distance entre le bord gauche de la fenetre et le bord du conteneur 
.Width = Width 'Definit la largeur de l'objet 
.Height = Height 'Definit la hauteur de l'objet 
.Font.Size = 8 ématiqu
End With 
 
Top = Top + 500 
NumeroTextBox = NumeroTextBox + 1 
 
Next

Aprés avoir cherché sur différent forums j'ai lié FM20.dll

Malgré cela j'ai une erreur de compil sur Controls.Add.
J'utilise Access 2003

Je ne sais plus comment faire pour résoudre ce pb.

Quelqu'un peut il me donner un coup de main ?

Merci d'avance.

**Jean-Philippe André** · 30/10/2008, 18h46

salut,
on ne peut pas faire comme avec les objets TableDef ou Field ?
du style

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
dim a as Control
a.Top = top
.
.
.
Forms("").Controls.Append a

?

**Jertho** · 30/10/2008, 18h52

Non il n'y a que Controls.Count, ou .Remove en standard mais non souci, je pense, c'est qu'il me manque une référence pour faire reconnaitre Controls.Add.

**cbleas** · 30/10/2008, 20h36

bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
              Dim ctlCréé As Control
               Set ctlCréé = CreateControl(Nom, acTextBox, , , "numServiceGMAO", 0, 0, 200)

cela fonctionne.

Bonne soirée

**LE VIEUX** · 30/10/2008, 20h37

bonsoir,
et en regardant par la
http://access.developpez.com/faq/?pa...reeDynCtrlCode

**Jertho** · 31/10/2008, 05h42

Merci des réponses, je teste et vous tiens au courant

**Jertho** · 31/10/2008, 05h50

Je viens de tester, CreateControl ne marche qu'en mode Creation.

Mon pb reste entier.

**helas** · 31/10/2008, 06h53

On ne peut créer de contrôles qu'en mode création
mais il est possible de créer d'avance des objets non visibles rendus visibles au besoin après avoir modifié quelques propriétés

Invité · 31/10/2008, 06h55

Bonjour

Envoyé par Jertho

Je viens de tester, CreateControl ne marche qu'en mode Creation.

Mon pb reste entier.

Tout à fait, tu ne peux donc lancer ton code de ton formulaire, il faut le faire d'un autre.

Petite remarque, si ta base doit être transformée en fichier .mde, la création dynamique de contrôle ne fonctionnera pas.

Philippe

**Jertho** · 31/10/2008, 09h24

La "petite remarque" est d'une grande importance pour moi car en effet ma base sera transformée en .mde.
Donc j'en conclue que dans mon cas il n'est pas possible d'obtenir ce dont j'ai besoin.
Je suis donc désormais à la recherche d'autres alternatives

Merci beaucoup à tous.

**Kaarelott** · 02/12/2008, 09h03

bonjour à tous !

Moi aussi j'ai un problème pour la création dynamique de contrôles.
En fait je veux créer des textbox et des checkbox. jusque là ça va et ça fonctionne. Seulement, lorsque que je les créé, je veux également leurs attibuer une valeur avec .value.
Etant en mode création, il me fait une erreur car "cette propriété n'est pas dispo en mode création", alors entre temps je repasse en mode normal, et là il me dit : "Erreur d'éxecution '2467' Erreur défenie par l'application ou par l'objet"

Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Set ctl = CreateControl(frm.Name, acTextBox, acDetail)
With ctl
    .Top = (haut + (cptLigne * (hauteur + ecart)))
    .Left = (gauche + cpt * (largeur + ecart))
    .Height = hauteur
    .Width = largeur
    DoCmd.OpenForm "MonFormulaire"
    .value = ValeurQuiVientDUneTable
    DoCmd.OpenForm "MonFormulaire", acDesign
End With

Si quelqu'un pouvais avoir une solution, ou juste une idée de solution ça m'arrangerais bien

**Kloun** · 02/12/2008, 09h10

Une fois les contrôles créés, il faut fermer le formulaire (en sauvant), puis l'ouvrir normalement pour pouvoir affecter des valeurs aux contrôles.

**Kaarelott** · 02/12/2008, 09h18

j'ai ajouter dans mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
DoCmd.Close acForm, "Monformulaire", acSaveYes
DoCmd.OpenForm "Monformulaire", acNormal
.value = MaValeur
DoCmd.OpenForm "Monformulaire", acDesign

Et ça ne fonctionne toujours pas...
Mais est ce qu'il faut d'abord créer tous les controls, puis leur affecter une valeur, ou est ce qu'il y a moyen lors de la création de lui affecter une valeur?

**Kloun** · 02/12/2008, 09h24

Faut créer tous les contrôles, sauver le formulaire, l'ouvrir et là, tu peux affecter une valeur aux contrôles avec un truc du style :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Formulaire.control("NomDuControle").value = "La valeur"

**Kaarelott** · 02/12/2008, 09h38

D'accord !
Merci pour cette réponse rapide

Mais bon si ça continu je ne vais pas pourvoir faire ce que je souhaite car là j'ai une "erreur" je crée trop de contrôles à prioris.. il ne veut pas plus de 800

**Jean-Philippe André** · 02/12/2008, 09h39

es-tu sûr que ton approche est la bonne dans ce cas là ?
l'utilisation d'un contrôle dans la zone détail du formulaire ne serait-elle pas suffisante ?

**Kloun** · 02/12/2008, 09h46

800 contrôles ?!

A mon avis, y'a un problème de conception.
Tu veux faire quoi exactement ?

**Kaarelott** · 02/12/2008, 09h48

En fait je crée une sorte de "tableau" ... car le but est de réaliser un tableau de bord
Je met en acLabel les titres des "colonnes"
Puis les différentes zone de texte ou une checkbox ("ça fait plus joli que "oui/non") dans les "cellules".
Le nombre de colomnes est variable, de même que le monbre de lignes.... donc je ne vois pas comment faire pour crée cela avec avec juste un control..
De plus dans l'avenir je voudrais que l'on puisse cliquer sur une ligne par exemple pour traiter des info derière, enfin je ne rentre pas dans les détails...
Enfin bref je crois que je vais devoir réfléchir à autre autre chose...

**Kloun** · 02/12/2008, 09h55

Ok.
J'ai fait un truc a peu près identique (et j'en ai un peu ch...) mais le rendu est pas mal.
1/ il faut créer tes contrôles dans un formulaire, autant de contrôles que de colonnes.
2/ ouvrir le formulaire en mode liste.

Un bout du code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
 
    SuppressionForm "Grille"
    DoCmd.CopyObject , "Grille", acForm, "FrmA"
    DoCmd.OpenForm "Grille", acDesign, , , , acHidden
...
' iRst est le recordset qui renvoie les données à afficher.
' La partie droite des noms des champs du recordset indique le format du champ et s'il faut l'afficher ou nom.
Set mdl = Forms("Grille").Module
        For Each Fl In iRst.Fields
            'Créer le contrôle k
            If InStr(iRst.Fields(k).Name, "INVISIBLE") <> 0 Or right(iRst.Fields(k).Name, 4) = "DATE" Then
                iInt_Code = iInt_Code + 1
                ReDim Preserve iStr_Code(iInt_Code)
                iStr_Code(iInt_Code) = "redim preserve iStr_Param(iInt_Param) : iStr_Param(iInt_Param) = """ & iRst.Fields(k).Name & "$"" & Me![" & iRst.Fields(k).Name & "].Value : iInt_Param = iInt_Param + 1"
            End If
            If InStr(iRst.Fields(k).Name, "INVISIBLE") = 0 Then
                Set Controle = CreateControl("Grille", acTextBox)
                With Controle
                    If right(iRst.Fields(k).Name, 3) = "REF" Then
                        .Name = Left(iRst.Fields(k).Name, Len(iRst.Fields(k).Name) - 3)
                        .Tag = "REF" '
                    ElseIf right(iRst.Fields(k).Name, 4) = "DATE" Then
                        .Name = Left(iRst.Fields(k).Name, Len(iRst.Fields(k).Name) - 4)
                        .Tag = "DATE"
                    Else
                        .Name = iRst.Fields(k).Name
                    End If
                    .Left = 1200
                    .Top = 100 + j
                    .ControlSource = iRst.Fields(k).Name
                    iStr_NomChamp = Controle.Name
                End With
            End If
            If InStr(iRst.Fields(k).Name, "POURCENTAGE") > 0 Then
                With Controle
                    .Format = "0%"
                    .DecimalPlaces = 2
                    .Name = Left(iRst.Fields(k).Name, Len(iRst.Fields(k).Name) - 11)
                    iStr_NomChamp = Controle.Name
                End With
            ElseIf InStr(iRst.Fields(k).Name, "NOMBRE") > 0 Then
                With Controle
                    .Format = "0"
                    .DecimalPlaces = 2
                    .Name = Left(iRst.Fields(k).Name, Len(iRst.Fields(k).Name) - 6)
                    iStr_NomChamp = Controle.Name
                End With
            End If
            If InStr(iRst.Fields(k).Name, "INVISIBLE") = 0 And right(iRst.Fields(k).Name, 3) <> "REF" And right(iRst.Fields(k).Name, 4) <> "DATE" Then
                iStr = iStr_NomChamp
                iStr_NomChamp = Replace(iStr_NomChamp, " ", "_")
                iStr_NomChamp = Replace(iStr_NomChamp, "-", "_")
                iStr_NomChamp = Replace(iStr_NomChamp, "<", "Ctl_")
                iStr_NomChamp = Replace(iStr_NomChamp, ">", "Ctl_")
                iStr_NomChamp = Replace(iStr_NomChamp, "%", "Ctl_")
                If Left(iStr_NomChamp, 1) >= "0" And Left(iStr_NomChamp, 1) <= "9" Then
                    iStr_NomChamp = "ctl" & iStr_NomChamp
                End If
                'MsgBox iStr & " => " & iStr_NomChamp
                iLng_Retour = mdl.CreateEventProc("DblClick", Replace(iStr_NomChamp, " ", "_"))
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, "Dim ctl As Control"
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, "Dim iStr_Param() As string"
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, "Dim iInt_Param As integer"
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, vbTab & "redim preserve iStr_Param(iInt_Param) : iStr_Param(iInt_Param) = ""TypeDate$" & lstChoixDate.Value & """ : iInt_Param = iInt_Param + 1"
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, vbTab & "redim preserve iStr_Param(iInt_Param) : iStr_Param(iInt_Param) = ""Valeur$"" & Me![" & iStr & "].Value : iInt_Param = iInt_Param + 1"
                If iInt_Code > -1 Then
                    For iInt_Code = 0 To UBound(iStr_Code)
                        iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, vbTab & iStr_Code(iInt_Code)
                    Next
                End If
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, vbTab & "redim preserve iStr_Param(iInt_Param) : iStr_Param(iInt_Param) = ""KPI$" & iRst.Fields(k).Name & """ : iInt_Param = iInt_Param + 1"
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, vbTab & "gStr_NomFormAppelant = cStr_NomFormClose"
                iLng_Retour = iLng_Retour + 1: mdl.InsertLines iLng_Retour, vbTab & "OuvertureDetailDossier iStr_Param"
            End If
            j = j + 320
            k = k + 1
        Next
 
        Set Formul = Forms.item("Grille")
        Formul.RecordSource = "tblCCMResultat"
        DoCmd.Close acForm, "Grille", acSaveYes
        Application.Echo True
        DoCmd.OpenForm "Resultat"
        Set Formul = Forms.item("Resultat")
        Formul.Caption = lStr_Titre
        Formul.Controls("etiTitre").Caption = lStr_Titre

Accessoirement, je crée dynamiquement le code pour le double-click, afin de pouvoir ensuite ouvrir un autre formulaire dépendant du contrôle sur lequel on a double-cliqué.

**Kaarelott** · 02/12/2008, 10h05

Et bien merci de ton aide.
je vais voir un peu ton code et je vais tenter de comprendre ce que tu y fais (je devrais m'en sortir quand même lol )
Merci encore, et si j'ai une question je sais où poster

Création dynamique de contrôles

VBA Access

Discussions similaires

Partager

Partager