Discussion :

[Pierre67]

Bonjour,

j'ai une petite difficulté à écrire une code.
J'ai une plage de cellule non contigues C1:L1 - C4:L4 - C7:L7 - C10:L10 .....(toujours avec un pas de 3).
Et je souhaite utiliser target.value. Je ne sais pas où définir ma plage à l'intérieur de laquelle target.value sera appliquée ?
j'ai le code de target.value pour tout un tableau mais pas pour une plage.

Merci pour vos conseils
@+

[cb_60]

Bonsoir
Il faudrais en voir un peu plus

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("C1:L1,C4:L4,C7:L7,C10:L10").Select

ce que j'ai mis au dessus permet de selectionner tes cellules

[Pierre67]

Bonjour,

OK merci.
Deux précisions :

1 - mes lignes vont jusqu'à 112
2 - je ne veux pas les sélectionner, je veux nommer cette plage et c'est à l'intérieur de cette plage que va s'appliquer target.value

[cb_60]

Re
Une adaptation d'une macro de Michel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
       Dim x As Integer, y As Integer
 
        'Crée une boucle de 1 à 112
        For x = 1 To 112 Step 3
            'Crée une boucle de 1 à 7
            For y = 1 To 7
                'Ecrit dans les colonnes
                Cells(x, y) = TAvaleur '"L" & x & "-C" & y
            Next y
        Next x

correction pour ne pas boucler sur toutes les feuilles

[JackOuYA]

bonsoir,

à ton tour de m'éclaircir


c'est quoi pour toi

Et je souhaite utiliser target.value

target.value ?

PS: pour t'aider, pour moi target et le nom du paramétre utilisé par Excel VBA, dans la plus part des procédure événementielles possédant un paramétre de type range (plage).

[Pierre67]

En fait, Target.value est utilisé comme RechercheV mais dans la cellule courante.

le code ci-dessous fonctionne à merveille MAIS sur tout un tableau.

Je cherche à limiter cela à, disons aux lignes 4 - 7 - 10 - 13 - 16 -.....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim i As Byte
Dim code As String
 
On Error GoTo fin
If Target.Value <> "" Then
    code = Target.Value
    For i = 3 To 9
        If code = Cells(i, 14) Then Target.Value = Cells(i, 15)
    Next
End If
fin:
End Sub

[JackOuYA]

Bonjour,Pierre

je continue à essayer de t'expliquer ce qu'est target avant de te répondre...

regarde ton code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub Worksheet_Change(ByVal Target As Excel.Range)

tu vois bien que Target et un paramétre range de la fonction événemetielle Worksheet_change. Ainsi lorsque un changement intervient dans ta feuille excel , excel appelle cette fonction avec comme paramétre target qui pointe sur la plage de cellule modifié.

cela n'as rien à voir avec rechercheV que tu "lance toi même" en lui passant tes paramétres.

[Pierre67]

Oui j'ai bien compris le fonctionnement de Worksheet_Change.

Je cherche à adapter cela non pas à la feuille entière mais à une plage de lignes non contigues du style Plage_Change...

[JackOuYA]

non je ne pense pas que tu puisse créer tes propres fonctions événementielles..


mais tu peu tester la plage target en paramétre, pour cela utilise Intersect, fonction qui permet de renvoyé l'intersection de deux plage , dans ton cas la plage Target, et par exemple les colonnes ou ta fonction doit être active A:H..
tu peu aussi tester le numéro de ligne Target.Row pour connaitre la ligne de ta cellule..
cependant Target contient une plage et donc pas forcément une seule cellule par exemple dans le cas d'une copie d'une plage de donnée c'est toute la plage qui est envoyé par excel en paramétre à la fonction change..
pour traiter cela tu peu boucler par un for Each dans chacune des cellules de la plage , cela donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim i As Byte
Dim code As String
Static yaEncours As Boolean
Dim yaC As Range 'Cellule
Dim yAPlage As Range
'4 - 7 - 10 - 13 - 16
'
If Not yaEncours Then 'Si pas déjà en cours
  yaEncours = True
'Limitation aux colones A et H ..
    Set yAPlage = Intersect(Range("A:H"), Target)
            If Not yAPlage Is Nothing Then 'IL ya bien des cellules dans l'intersection des deux plages
               For Each yaC In yAPlage.Cells 'Parcours des cellules de la plage
                  If (yaC.Row - 1) Mod 3 = 0 Then ' Limitation au lignes '4 - 7 - 10 - 13 - 16 ....
                        code = yaC.Value
                       For i = 3 To 9
                          If code = Cells(i, 14) Then yaC.Value = Cells(i, 15)
                      Next
                   End If
               Next
            End If
    yaEncours = False
 End If

A oui j'ai rajouté yAEncours, pour éviter que la fonction parte en boucle..

[Pierre Fauconnier]

Bonjour

Target renvoie à la plage (<> cellule) modifiée.

Si tu modifies plusieurs cellules en même temps, la plage Target ne peut donc pas être utilisée comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

if target.value =...

Tu dois donc utiliser une variable pour boucler sur les cellules de la plage Target

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cellule As Range
 
    For Each Cellule In Target.Cells
        If Cellule.Value <> "" Then
            ' ...
        End If
    Next
End Sub

[Mytå_Qc]

Salut le forum

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
If Not Application.Intersect(Target, Range("A1:A12, D4:D10, D20, D22, D55, E1:E12")) Is Nothing Then 
MsgBox "Click on " & Target.Address 
End If 
End Sub

[Lao Pi]

Bonjour et Merci à tous pour votre aide
Cela fonctionne.

[AlainTech]

Cela fonctionne.

Dans ce cas, veux-tu bien cliquer sur le bouton , stp?

Merci