Discussion :

[_debutant]

Salut,

J'ai dans une table SAS des colonnes vides ce qui me crée un problème pour exporter cette table en Excel ( ERROR: Error attempting to CREATE a DBMS table. ERROR: Execute error: Too many fields defined..)

Je pense que si j'arrive à deleter ces colonnes vides, ca peut marcher.


Maintenant question comment deleter une colonne vide?

[green_fr]

Qu'est-ce qu'une colonne vide pour toi ?
1) C'est une colonne de la liste que tu connais - fais une étape data avec l'instruction drop.
2) Ce sont toutes les colonnes après une colonne donnée - trouve la liste des colonnes dans la view sashelp.VCOLUMN, ensuite comme dans 1).
3) C'est une colonne où aucune ligne n'a pas d'information - avec l'aide de même view que dans 2), et une macro, trouve la liste des colonnes (je ferais une proc sql avec un count(distinct NOM_DE_LA_COLONNE) pour détecter des colonnes avec une seule valeur présente), ensuite comme dans 1).
4) Une autre définition ?

[_debutant]

une colonne avec toute les lignes sans valeur .

[green_fr]

Justement, c'est le cas 3). Si tu as des questions - n'hésite pas.

[_debutant]

Un drop est suffisant pour se débarasser des colonnes vident, seul truc vraiment ch... c'est le fait de taper (200 fois voir plus ) le nom des variables.

y'a t'il une autre solution plus simple ?

[green_fr]

J'ai bien proposé une solution automatique :
1) Créer une table à une colonne "COLUMN_TO_DROP" pour garder les noms des colonnes à supprimer.
2) Créer un macro à un paramètre (nom d'une colonne) qui (avec la proc sql que j'ai mentionnée plus haut) vérifie si la colonne est vide, si oui - insère son nom dans la table de 1)
3) Avec l'aide de sashelp.VCOLUMN parcourir toutes les colonnes de la table, pour chaque colonne appeler le macro de 2)
4) Après 3) on doit avoir une table avec la liste des noms des colonnes vides. Lire son contenu dans une variable macro, avec laquelle générer l'instruction drop de l'étape data.

Ça prendra le temps comparable avec la saisie manuelle de 200+ noms :-) Par contre c'est recyclable et surtout plus enrichissant.

[olivier.decourt]

Bonjour.
En SAS 9, la proc Freq peut compter le nombre de valeurs distinctes de toutes les variables d'une table (option NLEVELS, identique au COUNT DISTINCT de SQL mais plus automatique). On pourrait résoudre ton problème en générant ce tableau avec Freq, en le sauvegardant dans une table (avec ODS OUTPUT), en le relisant avec du SQL pour voir quelles colonnes sont vides, et mettre leurs noms dans une macro-variable, avant de se servir de la macro-variable dans un DROP.
Aucune saisie manuelle à l'horizon !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
DATA work.test ;
	INFILE CARDS MISSOVER DSD DLM = " " ;
	INPUT (v1-v30) (:2.) ;
CARDS ;
1  2  3
4  5
.  6 7  9  10
;
RUN ;
ODS OUTPUT nLevels = work.cardinalites ;
PROC FREQ DATA=work.test NLEVELS ;
	TABLE _ALL_ / NOPRINT ;
RUN ;
PROC SQL NOPRINT ;
	SELECT STRIP(tableVar) INTO : listeDrop SEPARATED BY ","
	FROM work.cardinalites
	WHERE NnonMissLevels = 0
	;
	ALTER TABLE work.test DROP &listeDrop ;
QUIT ;

Olivier