Discussion :

[zoopsys]

Bonjour,

Je souhaiterai ouvrir plusieurs classeurs Excel (à partir d'Access) dans un seul processus Excel.

le code que j'utilise actuellement est le suivant, mais il m'ouvre plusieurs processus Excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Dim  xxx As String
 
strExcel = "C:\Program Files\Microsoft Office\OFFICE10\EXCEL.EXE"
strClasseur = xxx
Shell Chr(34) & strExcel & Chr(34) & " " & Chr(34) & strClasseur & Chr(34),   vbMaximizedFocus

j'ai aussi essayé çà mais çà donne bien évidemment le même résultat que précédemment :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim  xxx As String
Dim appExcel As Excel.Application 'Application Excel
Dim wbExcel As Excel.Workbook 'Classeur Excel
 
'Ouverture de l'application
Set appExcel = CreateObject("Excel.Application")
appExcel.Visible = True
'Ouverture d'un fichier Excel
Set wbExcel = Workbooks.Open(xxx)

Merci.

[LedZeppII]

Bonjour,

Il faut d'abord essayer d'utiliser GetObject, puis ci cela échoue, CreateObject.

Exemple:

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub OuvrirDesClasseurs()
 
'Ouverture d'un fichier Excel
OuvrirClasseurExcel "C:\Mes Documents\Excel\fichier1.xls"
 
'Ouverture d'un fichier Excel
OuvrirClasseurExcel "C:\Mes Documents\Excel\fichier2.xls"
 
'Ouverture d'un fichier Excel
OuvrirClasseurExcel "C:\Mes Documents\Excel\fichier3.xls"
 
End Sub

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub OuvrirClasseurExcel(strClasseur As String)
Dim appExcel As Excel.Application 'Application Excel
Dim wbExcel As Excel.Workbook 'Classeur Excel
Dim blnExcelRunning As Boolean
 
'Ouverture de l'application
On Error Resume Next
Set appExcel = GetObject(, "Excel.Application")
On Error GoTo 0
If appExcel Is Nothing Then
   ' Excel n'est pas ouvert (aucune instance)
   Set appExcel = CreateObject("Excel.Application")
Else
   blnExcelRunning = True
End If
appExcel.Visible = True
 
If blnExcelRunning Then
   Debug.Print "Une instance d'Excel existe déjà"
Else
   Debug.Print "Aucune instance d'Excel -> Ouverture d'Excel"
End If
 
'Ouverture du fichier Excel
appExcel.Workbooks.Open strClasseur
End Sub

La sub OuvrirClasseurExcel tente dans un premier temps de récupérer une instance d'Excel avec GetObject.
Si GetObject échoue, l'objet appExcel vaut Nothing.
On utilise alors CreateObject pour ouvrir Excel.

Cette partie du code

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
If blnExcelRunning Then
   Debug.Print "Une instance d'Excel existe déjà"
Else
   Debug.Print "Aucune instance d'Excel -> Ouverture d'Excel"
End If

sert juste à tracer le fonctionnement du code.

A+

[zoopsys]

Merci LedZeppII