Discussion :

[samlepiratepaddy]

Slt,
Petit souci sur la prise de focus sur mon formulaire (continu) qui me permet de téléphoner sur click d'un bouton.
Pour ce faire j'utilise l'assistant qui me crée un bouton qui appele le numéroteur, mais quand je me déplace dans mon formulaire a l'aide la souris, je que je click sur le numéroteur, il ne récupère pas le numéro de téléphone de l'enregistrement selectionné de la ligne !
J'ai rajouter en début de code un "SetFocus" mais rien n'y fait !
Je précise que par défault l'entrée dans le champ [TelFixe] récupère le champ ENTIER !
En plus, juste après la numérotation, je souhaite ouvrir un formulaire selon, bien sur Id correspondant à la ligne appelé !?
Voici le code en entier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub LancerAppel_Click()
Me.TelFixe.SetFocus
On Error GoTo Err_LancerAppel_Click
    Dim stDialStr As String
    Dim PrevCtl As Control
    Const ERR_OBJNOTEXIST = 2467
    Const ERR_OBJNOTSET = 91
    Const ERR_CANTMOVE = 2483
    Set PrevCtl = Screen.PreviousControl
    If TypeOf PrevCtl Is TextBox Then
      stDialStr = IIf(VarType(PrevCtl) > V_NULL, PrevCtl, "")
    ElseIf TypeOf PrevCtl Is ListBox Then
      stDialStr = IIf(VarType(PrevCtl) > V_NULL, PrevCtl, "")
    ElseIf TypeOf PrevCtl Is ComboBox Then
      stDialStr = IIf(VarType(PrevCtl) > V_NULL, PrevCtl, "")
    Else
      stDialStr = ""
    End If
    Application.Run "utility.wlib_AutoDial", stDialStr
    DoCmd.OpenForm "R_RépartitionDuJour", , "[N°Prospect]=" & Me![N°Prospect]
Exit_LancerAppel_Click:
    Exit Sub
Err_LancerAppel_Click:
    If (Err = ERR_OBJNOTEXIST) Or (Err = ERR_OBJNOTSET) Or (Err = ERR_CANTMOVE) Then
      Resume Next
    End If
 
    MsgBox Err.Description
    Resume Exit_LancerAppel_Click
End Sub

La condition dans ne fonctionne pas

DoCmd.OpenForm "R_RépartitionDuJour", , "[N°Prospect]=" & Me![N°Prospect]

Le formulaire s'ouvre sur le premier enregistrement mais sur celui selectionné ???
Il est vrai que pour un null comme moi pas facile d'ajouter quelque chose sur ce type de code....
Quelqu'un a une idée ?
Merci d'avance

[=JBO=]

Bonjour samlepiratepaddy,

Pour ce faire j'utilise l'assistant qui me crée un bouton qui appele le numéroteur, [...]

Une remarque: quand on voit le code produit par l'assistant, il y a de quoi s'emmêler les idées .

Je te propose de réécrire cette procédure pour aller directement au but.

En plus, juste après la numérotation, je souhaite ouvrir un formulaire selon, bien sur Id correspondant à la ligne appelé !?La condition dans ne fonctionne pas

DoCmd.OpenForm "R_RépartitionDuJour", , "[N°Prospect]=" & Me![N°Prospect]

Le formulaire s'ouvre sur le premier enregistrement mais sur celui selectionné ???

Je te suggère d'utiliser plutôt le 4ème paramètre de la méthode OpenForm, à savoir [ConditionWhere]. Concrêtement, ajoute une virgule avant le critère permettant de filtrer le prospect.

Voici le code que je te propose (hypothèse: le contrôle TelFixe contient bien un n° de téléphone).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub LancerAppel_Click()
    Dim stDialStr As String
 
    On Error GoTo Err_LancerAppel_Click
 
    stDialStr = Me.TelFixe.Value
    Application.Run "utility.wlib_AutoDial", stDialStr
 
    DoCmd.OpenForm "R_RépartitionDuJour", , , "[N°Prospect]=" & Me![N°Prospect]
 
Exit_LancerAppel_Click:
    Exit Sub
 
Err_LancerAppel_Click:
    MsgBox Err.Description
    Resume Exit_LancerAppel_Click
End Sub

=JBO=

[samlepiratepaddy]

EXTRAORDINAIRE!!!!
Trop cool
Enfin un code simple qui fait la même chose !!
Vraiment MERCI
Et plus j'comprend !
Et ça avec moi c'est pas gagner de suite !

Merci encore =JBO=

@+