Discussion :

[ibilliau]

Bonjour,
j'ai un souci tres bien geré sous excel, mais que je ne sais pas resoudre sous access:

j'ai 4 colonnes:

n° semaine Chiffre d'affaire 2008 Chiffre d'affaire 2007 Chiffre d'affaire 2006
1 100€ 50€ 150€
2 100€ 200€ 50€
3 20€ 50€ 60€


Ce que je veux c'est le min (ou le max d'ailleurs) de chacune de mes semaines
ex
semaine1 50€
semaine2 50€
semaine3 20€

la fonction min dans access me renvoie le min de la colonne, et pas le min entre plusieurs colonnes.
Merci de votre aide.

[User]

salut,

tu peux programmer ta propre fonction en VBA ,
fonction a 3 parametres (tes 3 champs) que tu utiliseras ensuite dans ta requete

@+

[ibilliau]

Le probleme c'est que je suis une buse en VBA; il n'existe donc aucune fonction dans access?

[Pierre Fauconnier]

Salut.

Je pense qu'une requête avec le champ suivant donnerait le résultat souhaité

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Minimum: VraiFaux([ca2008]<VraiFaux([ca2006]<[ca2007];[ca2006];[ca2007]);[ca2008];VraiFaux([ca2006]<[ca2007];[ca2006];[ca2007]))

A adapter à tes noms de champs, bien entendu

[User]

tu peux aussi utiliser la fonction iif dans ta requete , fonction qui permet de prendre en compte des conditions, sinon voici une fonction min en VBA:

à mettre dans un module:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public Function mmin(c1 As Integer, c2 As Integer, c3 As Integer) As Integer
 
   If c1 <= c2 And c1 <= c3 Then
      mmin = c1
   ElseIf c2 <= c1 And c2 <= c3 Then
      mmin = c2
   Else
      mmin = c3
   End If
 
End Function

@+

[francishop]

Bonsoir,

il n'existe donc aucune fonction dans access?

Si on est "Fan" d'Excel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
'// ajouter Microsoft Excel dans Outils/références
Function Mini(ParamArray LesChamps())
    On Error Resume Next
    Dim xl As Excel.Application, i As Integer, t As Integer
    Dim A
    ReDim lesChamps2(UBound(LesChamps()))
    '// obligé si null ou monétaire
    For i = 0 To UBound(LesChamps())
        If Not IsNull(LesChamps(i)) Then
            lesChamps2(t) = CDbl(LesChamps(i))
            t = t + 1
        End If
    Next
 
    Set xl = New Excel.Application
    Mini = xl.WorksheetFunction.Min(lesChamps2)
    xl.Quit
    Set xl = Nothing
    If Err <> 0 Then Mini = Null
End Function

Et on continue :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Function Maxi(ParamArray LesChamps())
    On Error Resume Next
    Dim xl As Excel.Application, i As Integer, t As Integer
    Dim A
    ReDim lesChamps2(UBound(LesChamps()))
    '// obligé si null ou monétaire
    For i = 0 To UBound(LesChamps())
        If Not IsNull(LesChamps(i)) Then
            lesChamps2(t) = CDbl(LesChamps(i))
            t = t + 1
        End If
    Next
 
    Set xl = New Excel.Application
    Maxi = xl.WorksheetFunction.Max(lesChamps2)
    xl.Quit
    Set xl = Nothing
    If Err <> 0 Then Maxi = Null
 
End Function

Mais tout ceci "Rame". C'est triste...
***************************************************************************
On travailles avec Access? Oui? Alors :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Public Function TrouveMin(ParamArray NosVariables() As Variant)
    'Retourne la variable la plus basse
 
    Dim intVariable As Integer
    Dim varMin
 
    For intVariable = 0 To UBound(NosVariables())
        If IsEmpty(varMin) Or IsNull(varMin) Or IsMissing(varMin) Then
            varMin = NosVariables(intVariable)
        End If
        If IsMissing(NosVariables(intVariable)) = False _
            And IsNull(NosVariables(intVariable)) = False _
            And IsNumeric(NosVariables(intVariable)) Then
            If NosVariables(intVariable) < varMin Then varMin = NosVariables(intVariable)
        End If
    Next intVariable
 
    TrouveMin = varMin
 
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Public Function TrouveMax(ParamArray NosVariables() As Variant)
    'Retourne la variable la plus basse
 
    Dim intVariable As Integer
    Dim varMax
 
    For intVariable = 0 To UBound(NosVariables())
        If IsEmpty(varMax) Or IsNull(varMax) Or IsMissing(varMax) Then
            varMax = NosVariables(intVariable)
        End If
        If IsMissing(NosVariables(intVariable)) = False _
            And IsNull(NosVariables(intVariable)) = False _
            And IsNumeric(NosVariables(intVariable)) Then
            If NosVariables(intVariable) > varMax Then varMax = NosVariables(intVariable)
        End If
    Next intVariable
 
    TrouveMax = varMax
 
End Function

Dans une requête :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
SELECT [n° semaine],[Chiffre d'affaire 2008],[Chiffre d'affaire 2007],[Chiffre d'affaire 2006],
 TrouveMin([Chiffre d'affaire 2008],[Chiffre d'affaire 2007],[Chiffre d'affaire 2006]) AS [Ton mini],
 TrouveMax([Chiffre d'affaire 2008],[Chiffre d'affaire 2007],[Chiffre d'affaire 2006]) AS [Ton maxi]
FROM Tatable;

Cordialement.

[ibilliau]

Merci ça fonctionne.