1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79
| Option Explicit
'cette collection nous donne la taille, la date de création,l'heure de création,
'le repertoire,le chemin d'acces a un fichier
'elle nous donne aussi la posibilité de copier, deplacer
Dim m_strPath As String
Const Con_Error_FichierInexistant As Long = vbObjectError + 1
Public Event Information(Message As String)
'===========================================================
' Propriete en lecture seul
'===========================================================
Property Get Nom() As String
'nom = prendre l'expression du milieu a partire du \
'InStrRev donne la position du delimiteur
RaiseEvent Information("vous avez demandé le nom du fichier")
Nom = Mid(m_strPath, InStrRev(m_strPath, "\") + 1)
End Property
Property Get Taille() As String
Dim lngTaille As Long
lngTaille = FileLen(m_strPath)
Select Case lngTaille
Case Is < 1024
Taille = lngTaille & " o"
Case Is < 1024 ^ 2
Taille = Round(lngTaille / 1024, 2) & " Ko"
Case Else
Taille = Round(lngTaille / 1024 ^ 2, 2) & " Mo"
End Select
End Property
Property Get DatCreation() As Date
'convertie en date la partie entiere de ce que me renvoi la fonction
'exemple : date 4,75 => 4eme jour depuis 1/1/1900 et 0.75 d'une heure
DatCreation = CDate(Int(FileDateTime(m_strPath)))
End Property
Property Get HeureCreation() As Date
'date de création moins "ma" date de creation
HeureCreation = FileDateTime(m_strPath) - Me.DatCreation
End Property
Property Get Repertoire() As String
Repertoire = Left(m_strPath, InStrRev(m_strPath, "\") - 1)
End Property
'===========================================================
' Propriete en ecriture et lecture de donnée
'===========================================================
Property Get CheminAccess() As String
CheminAccess = m_strPath
End Property
Property Let CheminAccess(path As String)
If Dir(path) = "" Then
Err.Raise Con_Error_FichierInexistant, "CheminAccess", "il n'y a pas de fichier a l'emplacement :" & vbNewLine & path
Else
m_strPath = path
End If
End Property
'===========================================================
' Methodes
'===========================================================
Sub Copier(destination)
FileCopy m_strPath, destination
End Sub
Sub Deplacer(destination)
Me.Copier destination
Kill m_strPath
End Sub
Sub Supprimer(m_strPath)
Kill m_strPath
End Sub |
Partager