Discussion :

[zandru]

Bonjour,

Ce que je souhaite faire c'est créer un bouton dans une barre de menu. Ce bouton devra commander une macro qui lance le menu de mon application.

Si je le fait à la main, cela fonctionne très bien mais le bouton disparait dès que je change de PC, car il est lié à excel et pas au fichier.

Donc je souhaiterai le créer par macro à l'ouverture du fichier et le supprimer ensuite.

Pour l'instant, j'ai réussi à avoir la barre de menu et à y insérer la bouton (merci l'enregistreur de macro ), mais je n'arrive pas à modifier le bouton (image, texte) et à affecter la macro.

voilà ce que j'ai pour l'instant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Application.CommandBars.Add(Name:="menutest", Position:=msoBarTop, temporary:=True).Visible = True
    Application.CommandBars("menutest").Controls.Add Type:=msoControlButton, id:=2950, Before:=1

Comment modifier l'image du bouton (un smiley ce ne fait pas serieux ), y ajouter du texte à coté, et surtout le lier à ma macro ?

[pgz]

Bonjour.

Pour créer la barre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set myBar = Application.CommandBars.Add(sProjBarName, msoBarTop, False, True)

Bien mettre la propriété Temporary à True pour ne pas garder la barre en permanance dans les autres classeurs.

Puis les contrôles, par exemple pour un bouton de commande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub subCreateCmdBarButton(ByVal myBar As office.CommandBar, _
                        ByVal sControlName As String, _
                        ByVal sProcName As String, _
                        ByVal TTText As String)
 
Dim ctl As office.CommandBarButton
 
Set ctl = myBar.Controls.Add(office.msoControlButton)
 
With ctl
    .Style = office.msoButtonCaption
    .Caption = sControlName
    .TooltipText = TTText
    .BeginGroup = True
    .Visible = True
    If sProcName = "subRien" Then
        .Enabled = False
    Else
        .OnAction = Application.ThisWorkbook.FullName & "!" & sProcName
    End If
End With
 
Set ctl = Nothing
End Sub

Comme tu le vois pour lier une procédure, c'est .OnAction.
Préciser dans le nom de macro le nom du classeur est utile au cas où plusieurs classeurs peuvent être ouverts en même temps.

Après, une barre de menu, ce n'est pas une planche à dessin. Mais avec beaucoup d'effort, sûrement, ...

Bon courage,

PGZ

[zandru]

Bonjour pgz,

En fouinant dans l'aide autour des propriétés et méthodes que tu m'as donné j'ai écrit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Set newbar = Application.CommandBars.Add(Name:="menu", Position:=msoBarTop, temporary:=True)
newbar.Visible = True
Set mybtn = newbar.Controls.Add(Type:=msoControlButton, id:=2950, Before:=1)
mybtn.FaceId = 65
mybtn.Caption = "Menu Gestion"
mybtn.Style = msoButtonIconAndCaption
mybtn.OnAction = "lancement_menu_gestion"

Et pour trouver le FaceId :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub newbouton()
    Set newbar = Application.CommandBars.Add(Name:="menu", Position:=msoBarTop, temporary:=True)
    newbar.Visible = True
    Set mybtn = newbar.Controls.Add(Type:=msoControlButton, id:=2950, Before:=1)
    For i = 1 To 1000
        mybtn.FaceId = i
        MsgBox i
    Next
End Sub

Merci pour m'avoir montré le chemin de la Vérité