Discussion :

[jenniferIUP]

bonjour,

je possède dans un formulaire un champ numéro de facture qui doit se créer seul mais fur et a mesure que les commandes sont enregistrées dans la base de données.
Or mes supérieures veulent que cette "référence facture" soit contruite d'une façon particulière:

elle doit commencer obligatoirement par P ensuite l'année, le mois et un numéro
ce qui donne par exemple P2009-02-01 c'est a dire que cette référence et la première facture de février 2009
autre exemple p2009-02-25 se sera la référence de la 25ème facture du mois de février 2009

comment puis je mettrecela en place??

je vous remercie par avance pour vos conseils

[Chtulus]

Bonjour,

Il s'agirait pas du même sujet qu'ici ?

[jenniferIUP]

oui a peu près je sui en stage au même endroit mais moi je travail sur une autre base de donnée qui gère une autre activité de l'association mais on nous a posé la même colle

Moi je pensai dans une requête extraire l'année et le mois de now, puis trouvr un systeme pour rajouter le dernier numéro de facture +1 mais pour cette dernière partie je vois pas tro commen faire

[Maxence HUBICHE]

Tu peux faire une fonction pour cela, non ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Public Function NumFacture(Prefixe As String, TableSource As String, ChampDate As String, Optional laDate As Variant) As String
'---------------------------------------------------------------------------------------
' Procedure : NumFacture
' Auteur    : Maxence Hubiche
' Site      : http://www.1formaxion.com   et http://mhubiche.developpez.com
' Date      : 06/02/2009
' Objet     : Calculer un nouveau n° de facture
'---------------------------------------------------------------------------------------
'
    Dim nTemp       As Long
    'remplacer laDate par la date du jour si elle n'a pas été fournie
    If IsNull(laDate) Or IsMissing(laDate) Then laDate = Date
    'Vérifier qu'il s'agit d'une date valide
    If Not IsDate(laDate) Then Err.Raise vbObjectError + 1, "Date", "La date '" & laDate & "' passée en paramètre de la fonction NumFacture n'est pas valide"
    'Si on est arrivé ici ...
    '---Calculer le nombre de lignes déjà faites
    nTemp = DCount("[" & ChampDate & "]", "[" & TableSource & "]", "format([" & ChampDate & "],'yyyymm') = format(#" & Format(laDate, "mm/dd/yyyy") & "#, 'yyyymm') ") + 1
    '---Renvoyer le code
    NumFacture = Prefixe & Year(laDate) & "-" & Format(Month(laDate), "00") & "-" & Format(nTemp, "00")
End Function

par exemple ...
Et pour l'utiliser, quelque chose comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

?numfacture("P","tblFactures","facDateFacture")