Discussion :

[distro]

Tout d'abord bonjour à tous.

Je suis nouveau sur le forum et en sas
J'ai cherché sur ce forum s'il y avait déjà un post traitant de mon problème mais n'en ayant trouvé je crée un nouveau sujet.
Je cherche à faire un histogramme à partir d'une variable santé (chaine de caractères) dont la valeur est fonction des donnés de la table gestrim (valeurs numériques). J'ai essayé de changer l'ordre par défaut des colonnes de l'histogramme pour obtenir un graphe partant de 5 à 1 (c'est-à-dire ici de "franchement mauvais" à "très bon"). J'ai rajouté la ligne commençant par axis1 pour cela, mais rien ne se passe.
Pourriez-vous m'indiquer où est mon erreur svp ?
Merci d'avance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
libname lib 'C:\FSAS';
data lib.ba2;
set lib.base2;
if gestim=1 then sante='très bon';
if gestim=2 then sante='bon';
if gestim=3 then sante='moyen';
if gestim=4 then sante='médiocre';
if gestim=5 then sante='franchement mauvais';
axis1 order=("franchement mauvais" "médiocre" "moyen" "bon" "très bon");
proc gchart;
vbar sante;
run;

[Bruno.Thevenin]

Bonjour,

1. Pour recoder une variable, en SAS il est préférable de passer par un FORMAT d'affichage
2. Dans l'instruction AXIS ce sont les VALEURS REELLES que l'on nomme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
data work.test (label="Jeu d'essai") ;
	input gestrim ;
	cards ;
1
2
2
3
3
3
4
4
4
4
5
5
5
5
5
;
run ;
 
proc format ;
   value Fsante /* Nom du format */
      1 = 'très bon'
      2 = 'bon'
      3 = 'moyen'
      4 = 'médiocre'
      5 = 'franchement mauvais'
      ;
run ;
axis1 ORDER=5 4 3 2 1 ; /* Ordre des colonnes du VBAR */
proc gchart data = work.test ;
   format gestrim Fsante. ; /* Appliquer le format à la variable */
   vbar gestrim / maxis=axis1 ; /* Appliquer l'ordre des colonnes */
run ;
QUIT ; /* Sortir du graphique */

Bon courage !

[distro]

Ca marche ! Merci beaucoup pour ces explications !