Discussion :

[progfou]

Bonjour à tous et toutes !

Je viens vers vous car j'ai un problème qui ne me semble pas compliqué, mais que je ne parviens pas à résoudre...

Dans ma feuille, j'ai 3 colonnes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Date de début || Date de fin || Durée

Vous avez compris, je pense, que c'est une sorte de gestion de planning.
J'aimerai pouvoir :

• Entrer la date de début
• Entrer la durée
• Et faire en sorte que le calcul de la date de fin soit automatique !

Mon problème, c'est que je veux que cette date de fin soit calculée aussi en fonction du jour de la semaine ouvré suivant !
Si j'ai une date de début un jeudi, et une durée de 3 jours, je ne veux pas que la date de fin soit calculée le samedi, mais le lundi suivant.

J'ai essayé d'utiliser les fonctions NB.Jours.Ouvres, Date, Semaine, etc.
Mais je n'y arrive pas. Pour le moment, je ne m'inquiète pas des jours fériés, congés, etc.

Merci d'avance de votre aide !

[wilfried_42]

Bonjour

en fonction de ce que j'ai compris la formule en B1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=A1+C1 + ((JOURSEM(A1+C1;2)=6)*2)+((JOURSEM(A1+C1;2)=7)*1)

ne tient pas compte dés jours feries

Autre Formule qui prend en compte les jours feries : formule matricielle à valider en appyant sur les touche Ctrl + Maj + Entrée

Creer une plage avec les jours feries et la nommer ferie
en B1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(JOURSEM(LIGNE(INDIRECT(A1+C1 & ":" & A1+C1+3));2)>5;9^9;SI(NB.SI(ferie;LIGNE(INDIRECT(A1+C1 & ":" & A1+C1+3)))>0;9^9;LIGNE(INDIRECT(A1+C1 & ":" & A1+C1+3)))))

[progfou]

Sans parler pour l'instant des jours fériés, ce n'est malheureusement pas aussi simple que cette formule. Exemple:
Si je prends dans A1 10/02/2009 et dans C1 7, il m'affiche dans B1 17/02/2009.

Ce qui semble exact... Mais en fait, ça ne tient pas compte du week-end.
Donc je devrais avoir 19/02/2009.

Il est bien là mon problème principal

[wilfried_42]

re:

selon l'ennoncé premier, j'avais compris que la date de fin devait etre un jour ouvré, pas que le nombre de jours etaient en réalité un nombre de jours ouvres...

voici une formule à tester (Matricielle) tenant compte des jours feries sur le même principe (autant le faire de suite)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=PETITE.VALEUR(SI(JOURSEM(LIGNE(INDIRECT(A1 & ":" & A1+C1+(ENT(C1/7)*2)+3));2)>5;9^9;SI(NB.SI(ferie;LIGNE(INDIRECT(A1 & ":" & A1+C1+(ENT(C1/7)*2)+3)))>0;9^9;LIGNE(INDIRECT(A1 & ":" & A1+C1+(ENT(C1/7)*2)+3))));C1+1)

[progfou]

Je tombe sur un #NOMBRE!
Quand j'affiche les étapes de calcul, je suis un peu paumé...

[wilfried_42]

re:

c'est une formule matricielle, à valider en appuyant sur les touche Ctrl + Maj + Entrée
si la validation est correctement effectuée, de {} encadent automatiquement la formule

si tu trouve #NOM c'est que le nom de plage ferie n'existe pas, il te faut le créer, tu y integres les jours feries

[progfou]

Chapeau bas !
Merci beaucoup !

[progfou]

Finalement, ce n'est pas si simple...
La durée peut être une fraction (0,5 par exemple).
Dans ce cas, ça ne fonctionne pas.

[wilfried_42]

re:

là c'est certain, ça devient des plus compliqués les jours c'est ok mais les heures ???? ça devient presque impossible à faire en formule, mais dans tous les cas, il va falloir garder une unité unique.

et gérer les heures ??? quelle est l'heure de départ ?, les heures creuses ? 5 jours ouvrés = 5 jours de 24h00 ou 5 jour de 7h30 de 8h00 à 1700 avec des heures creuse de 12:00 à 13:30 ? et on commence à quelle heure ???

ou bien plus plus simple : tu travailles en demis journées et au lieu de mettre 7 ,5 jours on mets 15 demis-journées (ca c'est possible)

[progfou]

Tant pis, je vais le gérer en mettant 1 jour pour les 0.5.
Je mets moi-même la date de début, donc ça ne posera pas de soucis.
Merci !

[wilfried_42]

re:

tu me dois une boite de dolicrane (si ca marche)

formule matricielle à mettre en D2, la date en A2, le nombre de jour en E2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=PETITE.VALEUR(SI(JOURSEM(A2+ENT((LIGNE(INDIRECT("1:"&(E2*2)+6))/2)+0,5);2)>5;9999999;SI(NB.SI(ferie;A2+ENT((LIGNE(INDIRECT("1:"&(E2*2)+6))/2)+0,5))=0;A2+ENT((LIGNE(INDIRECT("1:"&(E2*2)+6))/2)+0,5);9999999));E2*2)

nombre de jours : 1 ou 2 ou 3 ou 2,5 ou 4 ou 5,5 ou 0,5