Discussion :

[modjo]

bonjour

je debute, alors soyer pas trop mechant

je vous explique
apres avoir executer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Private Sub Command3_Click() 
 
   mapage.Hide
 
End Sub

je voudrai réafficher cette page

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

mapage.show

grâce à la touche F9 mais je n'y arrive pas je n'ai que des bouts de code que je modifie mais aucun résultat

car en fait j'ai un bit de vie qui passe a 1 et 0 toutes les seconde car l'appli communique avec un automate c'est pour cela kil ne faut pas que je quitte l'appli mai que je la cache et ainsi l'opérateur pourra afficher cette page en appuyant sur F9


quelqu'un une idée

merci

[OhMonBato]

Bonjour,

Tu peux mettre la propriété "Keypreview" de la feuille que tu caches à "True" et gérer l'appuis de la touche F9 dans l'événement KeyPress par exemple.
Tu peux aussi créer un menu "Show/Hide" et lui affecter le raccourci F9.

[AnneCa]

Utilise l'évènement KeyDown. Tu as juste besoin de connaitre le code Ascii de la touche F9 et c'est gagné...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
if KeyCode = codeF9 then
    mapage.Show
end if
End Sub

Il faudra peut-être jouer avec un DoEvents quelquepart... A voir

[ProgElecT]

ou encor:
dans un module .BAS

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Option Explicit
 
Declare Function SetTimer Lib "User32" (ByVal hWnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
Declare Function KillTimer Lib "User32" (ByVal hWnd As Long, ByVal nIDEvent As Long) As Long
Declare Function GetAsyncKeyState Lib "User32" (ByVal vKey As Long) As Integer
 
Sub TimerProc(ByVal hWnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long)
'If GetAsyncKeyState(vbKeyF9) <> 0 Then
If GetAsyncKeyState(vbKeyF12) <> 0 Then
 Form1.Visible = Not Form1.Visible
End If
End Sub

dans un Form sans aucun control

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Option Explicit
 
Private Sub Form_Load()
SetTimer Me.hWnd, 0, 500, AddressOf TimerProc ' on crée un timer
End Sub
Private Sub Form_Unload(Cancel As Integer)
KillTimer Me.hWnd, 0 ' supprimer le timer
End Sub

[modjo]

merci à tous les trois mais j'ai retenu la solution de ProgElecT avec une modif au niveau de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

mapage.Visible = Not Mapage.visible

c'est devenu

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
if mapage.Visible = false then
mapage.visible = true 
end if

ainsi il n'y a pas de basculement d'affichage

merci encore

[Delbeke]

Si non tu as la classique solution de l'icontray (une icone s'affichant en bas et à droite de ton ecran) associé à un popup menu.
En suivant le lien dans mas signatue, tu trouveras un composant (DiIcontray6) ecrit en VB avec ses sources.

[ucfoutu]

Bonjour,

Je ne sais pas si j'ai bien compris, mais si oui, je l'aurais plutôt vu ainsi, sans timer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Type ordre
    hWnd As Long
    notre_message As Long
End Type
Private Declare Function RegisterHotKey Lib "user32" (ByVal hWnd As Long, ByVal id As Long, ByVal fsModifiers As Long, ByVal vk As Long) As Long
Private Declare Function UnregisterHotKey Lib "user32" (ByVal hWnd As Long, ByVal id As Long) As Long
Private Declare Function PeekMessage Lib "user32" Alias "PeekMessageA" (lpMsg As ordre, ByVal hWnd As Long, ByVal wMsgFilterMin As Long, ByVal wMsgFilterMax As Long, ByVal wRemoveMsg As Long) As Long
Private Declare Function WaitMessage Lib "user32" () As Long
Private couic As Boolean
Private Sub obeissons()
  Dim notre_message As ordre
  Do While Not couic
     WaitMessage
     If PeekMessage(notre_message, Me.hWnd, &H312, &H312, &H1) Then Me.Visible = Not Me.Visible
     DoEvents
  Loop
End Sub
 
Private Sub Form_Activate()
    couic = False
    RegisterHotKey Me.hWnd, &HBFFF&, 0, vbKeyF9
    obeissons
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    couic = True
    Call UnregisterHotKey(Me.hWnd, &HBFFF&)
End Sub

Pour essayer, appuyer plusieurs fois sur F9 et voir... (si j'ai bien compris la demande)