Discussion :

[G_Kill]

Je suis en VB6

Je veux être capable de valider un adresse email

1 - C'est a dire, vérifier que tout les caractère soit des caractère valide pour une adresse email
2 - Vérifier que ce soit: nom@serveur.ext

Dans le fond je veut etre capable de vérifier que l'adresse pourrait exister.

[Theocourant]

Salut,

Voici 2 fonctions pour faire cela:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Function TestMailAd(monAd As String) As Boolean
Dim nom As String
Dim servad As String
 
    'Contrôle la présence de @ dans l'adresse
    If InStr(monAd, "@") = 0 Then
        TestMailAd = False
        Exit Function
    End If
 
    'Récupère le nom du serveur et le nom destinataire
    servad = Mid(monAd, InStr(monAd, "@") + 1)
    nom = Mid(monAd, 1, InStr(monAd, "@") - 1)
 
    'Contrôle de la présence du . dans l'adresse (penser aux adresses du type ".fr.st"
    If InStr(servad, ".") <= 1 Then 'on part du principe que l'adresse est au moins "a.*"
        TestMailAd = False
        Exit Function
    End If
 
    'Contrôle la validité des chaînes de caratères
    If ValidChaine(nom) And ValidChaine(servad) Then
        TestMailAd = True
    Else
        TestMailAd = False
    End If
 
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Function ValidChaine(maChaine As String) As Boolean
 
    For I = 1 To 45
        If InStr(maChaine, Chr(I)) <> 0 Then
            ValidChaine = False
            Exit Function
        End If
    Next I
    ' chr(46)="."
    If InStr(maChaine, Chr(47)) <> 0 Then
        ValidChaine = False
        Exit Function
    End If
    ' "0..9"
    For I = 58 To 64
        If InStr(maChaine, Chr(I)) <> 0 Then
            ValidChaine = False
            Exit Function
        End If
    Next I
    ' "A..Z"
    For I = 91 To 94
        If InStr(maChaine, Chr(I)) <> 0 Then
            ValidChaine = False
            Exit Function
        End If
    Next I
    ' "_"
    If InStr(maChaine, Chr(96)) <> 0 Then
        ValidChaine = False
        Exit Function
    End If
    ' "a..z"
    For I = 123 To 255
        If InStr(maChaine, Chr(I)) <> 0 Then
            ValidChaine = False
            Exit Function
        End If
    Next I
    ValidChaine = True
 
End Function

et 1 exemple d'utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub test()
    MsgBox TestMailAd("theo@dvp.com")
End Sub

Bonne continuation

Théo

[G_Kill]

parfait, merci

[yuan]

Vous pouvez utiliser les expressions régulières pour valider la syntaxe d'une adresse email. J'ai modifié code posté pour obtenir une procédure de validation beaucoup plus compacte.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Function TestMailAd(monAd As String) As Boolean
  Dim RegChaine As RegExp
  Dim ColChaine
 
  Set RegChaine = New RegExp
  RegChaine.Global = False
  RegChaine.Pattern = "^[a-zA-Z][\w\.-]*[a-zA-Z0-9]@[a-zA-Z0-9][\w\.-]*[a-zA-Z0-9]\.[a-zA-Z][a-zA-Z\.]*[a-zA-Z]$"
  Set ColChaine = RegChaine.Execute(monAd)
  If ColChaine.Count = 0 Then
    TestMailAd = False
    Exit Function
  End If
 
  TestMailAd = True
End Function

PS : Le 'Pattern' de l'expression régulière n'est pas de moi, je l'ai trouvée dans un autre forum.

[yuan]

Ah j'oubliais ... pour pouvoir utilser les expression régulières dans un projet VB, il faut ajouter la référence à la DLL qui permet de gérer les Regexp :

Aller dans le menu Outils/Références et cocher "Microsoft VBScript Regular Expressions 5.5"