Discussion :

[brand003]

bonjour a tous!!

j'ai besoin d'aide assez rapidement svp!!!!

J ai une table sas que je dois exporter en format .csv et mettre les variables texte entre double quote (identificateur de texte double quote et séparatuer de texte .

Ex :

"julie";"marchand";"10 rue de la tour";(…)

Mais Je ne parviens pas à mettre les variables entre double quote.

Mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
PROC EXPORT DATA= dir1.adr_post_optin_P
            OUTFILE= "U:\test.csv" 
            DBMS=dlm ;
            delimiter=';';
run;

Est-ce que quelqu'un sait comment faire ?

ce serait suuper!!!!!

[Bruno.Thevenin]

Bonjour,

Une idée serait de passer par une simple étape data et des instructions put...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
data work.test ;
   input nom $ pnom $ adr $ ;
   cards;
Julie Marchand Adr1
Eric  Acheteur Adr2
   ;
run ;
data _null_ ;
   set work.test ;
   file 'c:\temp\test.csv' ;
   put '"' nom '";"' pnom '";"' adr '";' ;
run ;

Bon courage !

[datametric]

Bonjour,

une façon élégante est de créer un tagset. Je vous propose un ancien que j'utilisais. Vous obtiendrez votre fichier plat.

Stéphane.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
/*********************************************/
 
proc template; 
    define tagset tagsets.semisv;
        notes "SEMI-CSV definition";
        parent = tagsets.csv;
        define event header;
          start:
            put ';' / if !cmp(COLSTART, "1");
            put '"';
            put VALUE;
          finish:
            put '"';
        end;
        define event data;
          start:
            put ';' / if !cmp(COLSTART, "1");
            put '"';
            put VALUE;
          finish:
            put '"';
        end;
        define event colspanfill;
            put ';';
        end;
 
        define event rowspanfill;
            put ';' /if ! exists(VALUE);
        end;
    end; 
run;
/*********************************************/
 
 
ods _all_ close;
 
ods tagsets.semisv file='c:\temp\test.txt' ;
proc print data=sashelp.class noobs ;
run;
 
 
ods tagsets.semisv close;

[brand003]

bonjour!

merci pour vos réponses
mais en fait les double quote doivent être un identificateur de texte

par ex:
"Paula";"Marie";;;"10 rue de la tour"

et non
"Paula";"Marie";"";"";"10 rue de la tour"

????

merci de m'aider si vous avez une autre solution

[olivier.decourt]

Bonjour.
Le format SAS $QUOTE. permet d'ajouter des guillemets autour d'une valeur. Pourquoi ne pas le modifier légèrement (avec une proc Format) pour indiquer que le seul cas à ne pas encadrer de guillemets serait une chaîne vide ?
Ensuite, on exporte avec une étape Data, FILE et PUT, dans laquelle on applique le format surchargé à toutes les variables de type caractère.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
DATA work.test ;
	INFILE CARDS DLM="," DSD MISSOVER ;
	INPUT nom $ prenom $ cpt1 $ cpt2 $ adr :$40. ;
CARDS ;
Paula,Marie,,,"10 rue de la tour"
Forum,John,"Appt 2","3e etage","17 rue du bois"
;
RUN ;
 
PROC FORMAT ;
	VALUE $export
		" " = [$1.]
		OTHER = [$QUOTE.]
	;
RUN ;
DATA _NULL_ ;
	SET work.test ;
	FILE "c:\temp\test.txt" DLM=";" ;
	FORMAT 	_CHARACTER_ $export. ;
	PUT nom prenom cpt1 cpt2 adr ;
RUN ;

Olivier

[brand003]

merci beaucoup!! ça marche parfaitement!!

par contre comment je peux faire pour avoir les en-têtes (avec séparateur
mais sans les double quote ?
car elles s'affichent à la suite sans séparateur... je ne sais pas pourquoi..

merci

[datametric]

J'insiste ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
data class;
set sashelp.class;
if sex='F' then sex='';
run;
 
/*********************************************/
proc template; 
    define tagset tagsets.semisv;
        notes "SEMI-CSV definition";
        parent = tagsets.csv;
        define event header;
          start:
            put ';' / IF !cmp(COLSTART, "1");
            put '';
            put VALUE;
          finish:
            put '';
        end;
        define event DATA;
          start:
            put ';' / IF !cmp(COLSTART, "1");
            put '"'  /IF EXISTS(VALUE);
            put VALUE;
          finish:
            put '"'  /IF EXISTS(VALUE);
        end;
        define event colspanfill;
            put ';';
        end;
 
        define event rowspanfill;
            put ';' /IF ! EXISTS(VALUE);
        end;
    end; 
run;
/*********************************************/
 
 
ods _all_ close;
 
ods tagsets.semisv file='c:\temp\test.txt' ;
proc print DATA=class noobs ;
run;

=>
Name;Sex;Age;Height;Weight
"Alfred";"M";"14";"69.0";"112.5"
"Alice";;"13";"56.5";" 84.0"
"Barbara";;"13";"65.3";" 98.0"
"Carol";;"14";"62.8";"102.5"
"Henry";"M";"14";"63.5";"102.5"
"James";"M";"12";"57.3";" 83.0"

ods tagsets.semisv close;

[olivier.decourt]

La solution de Stéphane/Datametric est effectivement très chic, très moderne, très ODS.
Nos propositions -- Bruno et moi -- sont plus rustiques, mais fonctionnent avec toutes les versions de SAS (j'ai eu des mauvais souvenirs de tests dans la proc Template avec SAS v8).
Pour l'en-tête, si tu veux garder la solution de l'étape Data, tu prévois un PUT qui affiche ce que tu veux, à exécuter une fois (condition IF _N_=1, pour la 1e observation lue seulement).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
DATA _NULL_ ;
  SET work.test ;
  FILE "c:\temp\test.txt" DLM=";" ;
  FORMAT 	_CHARACTER_ $export. ;
  IF _N_=1 THEN PUT "nom ; prénom ; adresse (complément 1) ; adresse (complément 2) ; adresse (numéro et voie)" ;        
  PUT nom prenom cpt1 cpt2 adr ;
RUN ;

Olivier

[brand003]

merci datametric mais je ne peux pas avoir accès à sasuser et donc je ne peux utiliser les template car cela indique que je n'ai pas l'autorisation...

donc je dois trouver une autre solution

mais merci beaucoup!!

j utiliserai ceci dès que mon soucis d'autorisation sera réglé!!!

[olivier.decourt]

L'accès à SASUSER n'est pas une condition sine qua non pour utiliser des proc Template personnalisées. On peut utiliser n'importe quelle bibliothèque, par exemple WORK.
Pour ça, il faut ajouter dans la proc Template le lien de stockage :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    define tagset tagsets.semisv / store = work.tag ;

et avant de s'en servir, mettre à jour la liste des chemins où sont stockées les définitions utiles à l'ODS :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ODS PATH work.tag sasuser.templat sashelp.tmplmst ;

[datametric]

Pas d'accès à SASUSER ? C'est pas commun ça.

Mais peux-tu réessayer avec cela en premier :

ods path work.templat(write);

Merci.

[brand003]

ah ok super !! merci beaucoup!!
ça marche mais par contre les infos sont les unes après les autres (et non à la ligne lorsqu'il s'agit d'une autre personne)
vous savez pourquoi?

[olivier.decourt]

les infos sont les unes après les autres (et non à la ligne lorsqu'il s'agit d'une autre personne)

Je crois qu'il faudrait ajouter dans la proc Template

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 define event row;
  finish:
    put NL ; /* NL=New Line */
end;

avant "define event rowspanfill" par exemple.

[brand003]

merci beaucoup!!
là c'est parfait !!

merci encore!!

bonne soirée à vous tous