Discussion :

[Melodie]

Bonjour,

existe-t'il une solution pour accélérer la création dynamique de composants dans une TForm ?

Dans l'exemple ci-dessous, je créé une centaine de TEdit.
Cela prend un certain temps.
Peut-être existe-t'il une astuce du type "BeginUpdate/EndUpdate" pour éviter par exemple que la Form ne se rafraîchisse pendant la création ?

Merci d'avance pour vos idées.
Yann

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
procedure TForm1.Button1Click(Sender: TObject);
var
	n: integer;
	fEdit: TEdit;
begin
   for n:=1 to 100 do
   begin
       fEdit:= TEdit.Create(Self);
       fEdit.Parent:=Self;
       fEdit.Top:=(n*20);
       fEdit.Left:=10;
   end;
end;

[khaled-benloucif]

Bonsoir, essayes ce code, il n'accélère pas mais il affiche à la fois tes TEdit.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
procedure TForm1.Button1Click(Sender: TObject);
var    n: integer;
       Panel: TPanel;
       T: DWord;
begin
 T:= GetTickCount;
 Panel:= TPanel.Create(Self);
 with Panel do
  begin
   AutoSize:= true;
   Visible:= false;
   Left:= 10;
   Top:= 10;
   Parent:= Form1;
   for n:=1 to 100 do
       with TEdit.Create(Self) do
        begin
         Parent:= Panel;
         Top:=(n*20);
         Left:= 0
        end;
   Resize;
   Visible:= true
  end;
 T:= GetTickCount- T;
 ShowMessage(IntToStr(T))
end;

temps d'exécution en moyenne entre 40ms à 150 ms chez moi sur un processeur 3Go H.T

[Andnotor]

Tu peux ajouter un LockWindowUpdate, mais le gain en temps et tout relatif .
Par contre, ça t'évitera le flicker.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
procedure TForm1.Button1Click(Sender: TObject);
var
  n: integer;
  fEdit: TEdit;
begin
  try
     LockWindowUpdate(Handle);
 
     for n:=1 to 100 do
     begin
         fEdit:= TEdit.Create(Self);
         fEdit.Parent:=Self;
         fEdit.Top:=(n*20);
         fEdit.Left:=10;
     end;
  finally
     LockWindowUpdate(0);
  end;
end;

[khaled-benloucif]

salut Andnotor, je viens d'essayer ton code, il mets prés de 400ms à 500ms pour afficher les edits! t'en pense quoi ?

[Andnotor]

Pas grand chose à part que 100 edits seraient avantageusement remplacé par une StringGrid ou un ValueListEditor .

[Gilbert Geyer]

Bonjour,

Peut-être existe-t'il une astuce ... pour éviter par exemple que la Form ne se rafraîchisse pendant la création ?

Suggestion : Comme il n'y a raffraîchissement que si fEdit.visible:=True ce qui est le cas par défaut lors de la création dynamique, pour ma part j'ajouterais un fEdit.visible:=False; et un fEdit.Tag:=k + n; dans la boucle de création de n = 1 à 100
... et en fin création j'ajouterais une 2ième boucle pour rendre les Edit visibles en une seule rafale de raffraîchissement.

Le fEdit.Tag:=k + n; servant dans la deuxième boucle à distinguer les Edit ainsi créés de tous les autres Edit éventuellement présents sur la Form et dont le Tag est inférieur à k.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
for ic:=0 to Form1.ComponentCount-1
          do if (Form1.components[ic] is TEdit) and (Form1.components[ic].Tag > k
             then (Form1.components[ic] as TEdit).Visible:=True;

... Reste plus qu'à chronométrer.

A+

[Andnotor]

Salut Gilbert,

Tu peux simplifier en supprimant tes deux lignes Visibles et en déplaçant le Parent := dans ta deuxième boucle. L'Edit sera invisible jusqu'à l'assignation du Parent . (Il faudra par contre gérer une liste annexe pour la 2ème boucle)

[exoseven]

la solution donnée par khaled, placer les TEdit dans un TPanel caché me semble la meilleure tant en rapidité qu'en fluidité, on remarque aussi que si l'on ajoute plusieurs séries la solution de khaled reste stable en vitesse alors que l'ajout direct des TEdit sur la forme prend de plus en plus de temps.

[Gilbert Geyer]

Salut,

Exoseven a dit :

la solution donnée par khaled, placer les TEdit dans un TPanel caché [créé chaque fois dynamiquement] me semble la meilleure tant en rapidité qu'en fluidité,

... en jouant directement sur le "Visible/Pas-Visible" des Edit on gagne le temps mis pour créer chaque fois le Panel dynamiquement à moins d'utiliser un Panel créé une fois pour toutes lors de la conception avec Visible:=False.

Andnotor a dit :

Tu peux simplifier en supprimant tes deux lignes Visibles et en déplaçant le Parent := dans ta deuxième boucle. L'Edit sera invisible jusqu'à l'assignation du Parent . (Il faudra par contre gérer une liste annexe pour la 2ème boucle)

... ça peut être intéressant, mais je ne pige pas le "Il faudra par contre gérer une liste annexe pour la 2ème boucle" : c'est quoi cette liste annexe à gérer ??? (car qui dit liste à gérer dit durée d'exécution éventuellement supérieure)

Vu les diverses soluces proposées il ne reste plus à Melodie qu'à chronométrer... c'est le chrono qui tranchera .

A+

[exoseven]

franchement pas sur qu'une boucle sur 100 TEdit + 100 visible := true soit plus rapide que la création d'un seul panel, et si il veut 1000 TEdit cela sera encore moins rapide.

la solution du TPanel me semble plus "propre" et d'après mes tests plus rapide

[Andnotor]

@Gilbert

Si le Parent n'est pas assigné avant, la boucle sur ComponentCount n'est pas possible .

Quelque chose style array[1..100] of TEdit. Alloué une fois au début, donc pas une grande perte de temps comparé à 200 appels à SetVisible.
Cela supprime également tout les tests dans la 2ème boucle.

(Un Grid reste le plus adapté.)

[Just-Soft]

Salut;

Au fait pourquoi 100 Edits et pas un autre composant plus dédié comme proposé par Andnotor (un Grid p.e)

si on savait à quoi ça sert on pourrait contribuer (peut-être )

Bonne chance.

[Gilbert Geyer]

Re-salut,

Je crois que vous avez tous raison : le chronomêtre de Mélodie guidera son choix : à lui ou elle de faire ses tests.

A Andnotor qui a dit :

1]Si le Parent n'est pas assigné avant, la boucle sur ComponentCount n'est pas possible.
2] Quelque chose style array[1..100] of TEdit. Alloué une fois au début, donc pas une grande perte de temps comparé ...

... merci pour la mise en garde du 1]
... Ok pour l'array[1..100] of TEdit. Alloué une fois au début c'est encore mieux que le Panel invisible créé une fois au début ... reste à savoir si cela convient à Melodie.

A+

[Paul TOTH]

Pas grand chose à part que 100 edits seraient avantageusement remplacé par une StringGrid ou un ValueListEditor .

tout à fait d'accord, 100 edit c'est 100 HWnd, c'est autant de ressource Windows allouée pour rien (je ne connais pas encore de PC avec 100 claviers

Même si l'interface ne se prête pas à la grid, il est tout à fait possible de n'utiliser qu'un seul TEdit qui se baladera sur la fiche en fonction de clics et des touches de clavier (Tab par exemple).

[Melodie]

merci pour toutes ces réponses

l'objet de ma question ne reposait pas sur le nombre de TEdit à créer dynamiquement. J'avais donné 100 comme exemple, et TEdit aussi comme exemple. Je cherchais simplement à savoir si la création dynamique d'un grand nombre d'objets de type TWinControl peut être accélérée.

Je vais mettre en place l'idée du panel
Merci !