Discussion :

[SlySylvain]

Bonjour,

Débutant en Access, j'ai un peu de mal avec le vocabulaire exact, ce qui ne facilite pas les recherches sur le net...

J'ai créé dans une base Access plusieurs formulaires. Dans un des formulaires, il y a un bouton qui ouvre un second formulaire. En même temps que l'ouverture de ce second formulaire, je voudrais rendre visible un des boutons placé dans ce formulaire.

C'est là que ça coince et où l'on se rend compte de l'aide apporté par l'assistant de macro d'Excel

Merci pour votre aide

[argyronet]

Bonjour,

Tu as une multitude de solutions...
En voici une, soit dans ton Formulaire 1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub cmd1Form1_Click()
    DoCmd.OpenForm "Formulaire2", acNormal, , , , acDialog, "Invisible"
End Sub

ou pour le désactiver...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub cmd2Form2_Click()
    DoCmd.OpenForm "Formulaire2", acNormal, , , , acDialog, "Désactivé"
End Sub

Et dans ton Formulaire 2:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Form_Load()
Dim vntEtatBouton As Variant
 
    vntEtatBouton = Me.OpenArgs
    If Not IsNull(vntEtatBouton) Then
        Select Case vntEtatBouton
            Case "Invisible"
                cmd1Form2.Visible = False
            Case "Désactivé"
                cmd1Form2.Enabled = False
            Case Else
                cmd1Form2.Visible = True
                cmd1Form2.Enabled = True
        End Select
    End If
End Sub

La valeur texte de l'argument OpenArgs peut être un nombre ou une chaîne complexe...

Argy

[SlySylvain]

Bonjour argyronet,

je te remercie pour ta réponse mais suis un peu confus...
J'ai essayé la première solution que tu proposes mais sans succès. Je ne comprends pas comment cette commande va rendre visible un bouton.

Je n'ai pas encore utilisé la dernière solution.

En fait je cherche à utiliser un seul formulaire qui me permettrait d'ouvrir deux formulaires, en fonction du cheminement. Je précise :
Dans un Form1, deux boutons (A et B) qui ouvrent tous deux le Form2
Dans le Form2, deux boutons de validations (C et D) que je masque par défaut.

Si dans Form1, je clique sur A, je souhaite ouvrir Form2 en rendant visible C,
Si dans Form1, je clique sur B, je souhaite ouvrir Form2 en rendant visible D,

J'espère avoir été plus clair.

merci encore

[SlySylvain]

Re tout le monde,

argyronet, je viens de comprendre ton code et vient de la faire fonctionné dans mon application.
C'est parfait !

Je te remercie grandement.

Bonne continuation.