Discussion :

[Daniel MOREAU]

Bonjour à tous,

Depuis plusieurs jours, je suis sur le même problème et j'ai passé une partie de mon WE à consulter les cours et tutoriels.

Je ne m'en sort pas.

Voilà je souhaiterai connaître la liste des calendriers dans Outlook (J'ai déjà exposé mon problème mais n'ai pas eu de réponse)

Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub cal()
Dim objOutlook As outlook.Application
Dim objAppt As outlook.AppointmentItem
Dim olns As outlook.NameSpace
Dim MycalendarFolder As outlook.MAPIFolder
Dim MyFolder As outlook.Items
Set objOutlook = CreateObject("Outlook.Application")
Set olns = objOutlook.GetNamespace("MAPI")
Set MycalendarFolder = olns.GetDefaultFolder(olFolderCalendar)
Set MycalendarFolder = olns.GetDefaultFolder(olFolderCalendar)
For ical = 0 To (MycalendarFolder.Folders.Count - 1) ' Va de 0 jusqu'au nombre de calendrier -1 (ex de 0 à 7 si il y a 8 calendriers)
    MsgBox MycalendarFolder.Folders(ical).Name
Next ical
End Sub

Je n'arrive pas à faire afficher les noms des différents calendriers. Pourquoi :

Pouvez-vous m'aider :

Merci d'avance.

Daniel

[Frank]

Est ce que tu arrives déjà à récupérer le nombre de calendriers ?

[Tofalu]

Hello je connais trés peu le modèle objet d'Outlook, toutefois vu le peu de succès de ton thread je vais me lancer dans une réponse qui est peut être un peu hasardeuse.

A priori sous Outlook, l'utilisateur peut disposer ses calendriers dans n'importe quel dossier qu'il aura créé et même imbriquer des sous dossier. Dés lors, un parcours récurssif semble nécessaire.

Problème : comment identifier un calendrier. Je ne sais pas mais je part de l'hypothèse qu'un calendrier utilise comme item par défaut olAppointmentItem (un rendez-vous). Je peux donc parcourir l'ensemble des dossiers et stocker les calendriers dans une collection

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub test()
Dim objOutlook As Outlook.Application
Dim olns As Outlook.NameSpace
Dim c As New Collection
Dim i As Integer
'Instancie les objets Outlook
Set objOutlook = CreateObject("Outlook.Application")
Set olns = objOutlook.GetNamespace("MAPI")
'Lance l'examen récurssif afin de récupérer les calendriers
exploreFolder olns.Folders, c
'Parcours la collection resultante
For i = 1 To c.Count
MsgBox c(i).Name
Next i
 
End Sub
 
Sub exploreFolder(ofld As Outlook.Folders, colResult As Collection)
Dim oTmpFld As Outlook.MAPIFolder
For Each oTmpFld In ofld
  If oTmpFld.DefaultItemType = olAppointmentItem Then
    colResult.Add oTmpFld
  Else
    exploreFolder oTmpFld.Folders, colResult
  End If
Next
End Sub

C'est surement améliorable, notamment au niveau de la determination du type de dossier. Mais bon, c'est toujours mieux que rien

[Daniel MOREAU]

Je suis débutant et j'ai encore beaucoup de mal.

Sinon je viens d'essayer ton code et je viens de pousser un OUF de soulagement. CA MARCHE

Je peux maintenant consulter les noms des différents calendriers.

Merci mille fois pour ton aide Tofalu.

Je vais pouvoir continuer.

Merci encore

Daniel