Discussion :

[phil2]

Bonjour,

j'ai une feuille contenant une liste de noms.
J'ai une autre feuille avec un tableau croisé dynamique

Je voudrais créer une macro qui sélectionne le premier nom de cette liste dans un champ de page d'un tableau croisé dynamique et qui imprime ce tableau. Ensuite
Sélectionne le deuxième nom sur ma liste, imprime le TCD
Sélectionne le 3ème nom sur la liste, imprime le TCD

Et ainsi de suite jusqu'au dernier nom.

En vous remerciant énormément,

Phil

[Minick]

Salut,

Un petit exemple .

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Option Explicit
 
Sub ImpressionTCD()
    Dim Cpt As Integer
 
    For Cpt = 2 To Feuil1.Range("A65536").End(xlUp).Row
        Feuil2.PivotTables("Tableau croisé dynamique").PivotFields("Nom").CurrentPage = Feuil1.Range("A" & Cpt).Value
        Feuil2.PrintOut 'Preview:=True
    Next
End Sub

Avec :
Feuil1 colonne A -> la liste de noms
Feuil2 -> ton TCD avec en champ de page le champ 'NOM'

++
Minick

[phil2]

Merci Minik! ça fonctionne!

Toutefois, certaines cellules de ma liste sont vides et elles sont considérées dans le choix des valeurs à mettre au tcd. Pour éviter celà, je voudrais mettre une condition pour ne pas qu'elles le soient.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
if range("a65536") =""  then passe à l'autre cellule contenant une valeur
 
else
 
    Dim Cpt As Integer
 
    For Cpt = 2 To Feuil1.Range("A65536").End(xlUp).Row
        Feuil2.PivotTables("Tableau croisé dynamique").PivotFields("Nom").CurrentPage = Feuil1.Range("A" & Cpt).Value
        Feuil2.PrintOut 'Preview:=True
    Next
End Sub

Aussi, y a t'il moyen d'utiliser un nom prédéfini comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

range.[feuil1_nom de_ma_liste]

En espérant être assez clair, merci de ton aide

Phil

[Minick]

Salut,

La boucle ne va pas jusqu'a la ligne 65536, elle s'arrete a la derniere ligne de la liste de noms.

Oui on peut utiliser une plage definit avec Insertion/Nom/Definir
et on peut aussi tester si la valeur est vide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Option Explicit
 
Sub ImpressionTCD()
    Dim Cellule As Range
 
    For Each Cellule In Feuil1.Range("NomDeLaPlage")
        If Cellule.Value <> "" Then
            Feuil2.PivotTables("Tableau croisé dynamique").PivotFields("Nom").CurrentPage = Cellule.Value
            Feuil2.PrintOut 'Preview:=True
        End If
    Next
End Sub

++
Minick

PS : Pense aux balises code quand tu mets du code...

[phil2]

Fantastique! merci!

Maintenant, si je peux me permettre une dernière question!

si un nom de ma liste n'est pas présent dans les choix du pivotfield, je voudrais ouvrir une msgbox qui indique qu'aucune données n'a été entrée concernant ce nom et le désélectionner de ma liste. (ma liste est créée avec des cases à cocher)

Présentement, c'est une msgbox de vba qui s'ouvre ERREUR 1004, impossible de définir la propriété. C'est un peu agressant...

Phil2

[Minick]

Salut,

A adapter a tes cases a cocher.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
 
Sub ImpressionTCD()
    Dim Cellule As Range
    Dim Cpt As Integer
    Dim Existe As Boolean
 
    For Each Cellule In Feuil1.Range("NomDeLaPlage")
        Existe = False
        If Cellule.Value <> "" Then
            With Feuil2
                With .PivotTables("Tableau croisé dynamique1").PivotFields("Nom")
                    For Cpt = 1 To .PivotItems.Count
                        If LCase(.PivotItems(Cpt)) = LCase(Cellule.Value) Then
                            Existe = True
                            .CurrentPage = Cellule.Value
                            Exit For
                        End If
                    Next
                End With
 
                If Existe Then
                    .PrintOut 'Preview:=True
                Else
                    MsgBox "Pas de données pour " & Cellule.Value & " dans le rapport."
                End If
            End With
        End If
    Next
End Sub

++
Minick