Discussion :

[lagratteCchouette]

Bonjour.

Voilà, je souhaite déclencher une macro au changement quand dans la cellule par exemple A1 je rentre une valeur.

Pourquoi ? L'utilisation de bouton c'est bien, mais cela nécessite de ne pas oublier de l'activer et je ne souhaite pas avoir plein de bouton sur ma feuille.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Note As Integer
Dim Mention As String
Note = Range("A1")
 
If Note = 0 Then Mention = "Nul"
If Note >= 1 And Note < 6 Then Mention = "Moyen"
If Note >= 6 And Note < 11 Then Mention = "Passable"
If Note >= 11 And Note < 16 Then Mention = "Bien"
If Note >= 16 And Note < 20 Then Mention = "Très Bien"
If Note = 20 Then Mention = "Excellent"
Range("B1") = Mention
 
           End If
         End If
   End Sub

Voilà donc mon code mais cela plante et je ne comprends pas...
____
" La musique donne une âme à nos cœurs et des ailes à la pensée." - Platon

[Krovax]

Target correspond a la zone modifié
essaye

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("A1")) Is Nothing Then
'ton code
End If
End Sub

accésoirement tu n'as pas besoin des end if quand tu fait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

if un_test then action

tu l'utilise si tu fait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
if un_test then
action
end if

et a mon avis tu aura besoin de ca
pour savoir quel colonne a été modifié

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

target.row

A mon avis voila un code qui te plaira

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Worksheet_Change(ByVal Target As Range)
 
Dim Note As Integer
Dim Mention As String
 
If Not Intersect(Target, Range("B:B")) Is Nothing Then    'rempale le B par la colonne qui contient les notes
    Note = Target
 
    If Note = 0 Then Mention = "Nul"
    If Note >= 1 And Note < 6 Then Mention = "Moyen"
    If Note >= 6 And Note < 11 Then Mention = "Passable"
    If Note >= 11 And Note < 16 Then Mention = "Bien"
    If Note >= 16 And Note < 20 Then Mention = "Très Bien"
    If Note = 20 Then Mention = "Excellent"
 
    Cells(Target.Row, 3) = Mention  'remplace le 3 par le numéro de colonne que tu veux
 
End If
 
End Sub

'edit le code ne fonctionnera que si tu modifie les cellule 1 par 1. Si tu veux pouvoir modifier plusieur note a la fois (copier/coller par exemple) il va fgaloir un peu le modifier

[Qwazerty]

Salut
A mon avis il serait plus simple de gérer ça via des formule, ceci dis une remarque sur la structure de ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    If Note = 0 Then Mention = "Nul"
    If Note >= 1 And Note < 6 Then Mention = "Moyen"
    If Note >= 6 And Note < 11 Then Mention = "Passable"
    If Note >= 11 And Note < 16 Then Mention = "Bien"
    If Note >= 16 And Note < 20 Then Mention = "Très Bien"
    If Note = 20 Then Mention = "Excellent"

comme dis par Krovax effectivement chaque If Then étant sur une seule ligne, nul besoin de clôturer par un End If , ceci étant dis cette partie du code peut etre amélioré. si la note vaut 8, alors la seul ligne ou le test sera Vrai sera la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Note >= 6 And Note < 11 Then Mention = "Passable"

Uniquement celle ci et aucune autre, mais quand excel va parcourir ton programme, tu l'obliges a faire tous les testes un à un, il est donc préférable d'utiliser cette structure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
    If Note = 0 Then
        Mention = "Nul"
    ElseIf Note >= 1 And Note < 6 Then
        Mention = "Moyen"
    ElseIf Note >= 6 And Note < 11 Then
        Mention = "Passable"
    ElseIf Note >= 11 And Note < 16 Then
        Mention = "Bien"
    ElseIf Note >= 16 And Note < 20 Then
        Mention = "Très Bien"
    ElseIf Note = 20 Then
        Mention = "Excellent"
    End If 'il le faut dans cette structure la

Ici comme mis en commentaire il faut clôturer la série de If ElseIf par un End If dans cette structure des qu'excel trouve sont bonheur, plutôt que de tester les autre ligne, il va directement au End If.

Il existe d'autre type de structure, notamment le Select Case, qui donne un très bonne lisibilité du code, surtout dans un cas comme celui la, voila ce qu'il donnerait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
    Select Case target.Value
        Case 0: Mention = "Nul"
        Case 1 To 5: Mention = "Moyen"
        Case 6 To 10: Mention = "Passable"
        Case 11 To 15: Mention = "Bien"
        Case 16 To 19: Mention = "Très Bien"
        Case 20: Mention = "Excellent"
    End Select

Pour plus d'info sur les différentes structures, je t'invite a regarder les tutos, la faq et l'aide vba qui te fournira plus d'exemple et de cas possibles

A++
Qwaz

[lagratteCchouette]

Merci à tous les deux pour vos réponses.

Mais cela ne marche pas, je n'ai peut être pas tout bien compris.

* J'ai raisonné cellule pour commencer et pour bien comprendre et ensuite guidez-moi vers la notion de colonne. svp

1°)
"A1" = nom de l'élève
"B1" = je rentre la note
"C1" = je veux voir apparaître AUTOMATIQUEMENT la mention

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
Dim Note As Integer
Dim Mention As String
 
If Not Intersect(Target, Range("B1")) Is Nothing Then    'rempalce le B par la colonne qui contient les notes
    Note = Target
 
    If Note = 0 Then Mention = "Nul"
    If Note >= 1 And Note < 6 Then Mention = "Moyen"
    If Note >= 6 And Note < 11 Then Mention = "Passable"
    If Note >= 11 And Note < 16 Then Mention = "Bien"
    If Note >= 16 And Note < 20 Then Mention = "Très Bien"
    If Note = 20 Then Mention = "Excellent"
 
    Cells(Target.Row, 3) = Mention  'remplace le 3 par le numéro de colonne que tu veux
 
End If
End Sub

Ensuite une fois compris, 2ème cas de figure, je souhaite raisonner en colonnes.

2°)
colonne A = noms des élèves
colonne B = je rentre la note
colonne C = je veux voir apparaître AUTOMATIQUEMENT la mention

Merci à tous par avance..

___
" La musique donne une âme à nos cœurs et des ailes à la pensée." - Platon

[Qwazerty]

Salut
Kdo, avec plein de commentaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
'Dim Note As Integer 'on va s'en passer, on fera directement appelle a Target.value il est la pour ça
Dim Mention As String
 
'On vérifie que target correspond bien a une des cellules que l'on souhaite contrôler
'Je suppose que tout les nom des élèves sont en colonne A et les note en B, ca donne donc
If Not Intersect(Target, Range("B:B")) Is Nothing Then    'rempalce le B par la colonne qui contient les notes
    'B:B represente toute la colonne
    'Note = Target
 
    Select Case Target.Value
        Case 0: Mention = "Nul"
        Case 1 To 5: Mention = "Moyen"
        Case 6 To 10: Mention = "Passable"
        Case 11 To 15: Mention = "Bien"
        Case 16 To 19: Mention = "Très Bien"
        Case 20: Mention = "Excellent"
    End Select
 
    'Cells(Target.Row, 3) = Mention  'remplace le 3 par le numéro de colonne que tu veux
    'ici on va utiliser la notion d'offset, qui permet de décaler la celui "pointé" de y lignes et de x colonne,
    'y positif on descend, négatif... on remonte dans le tableau
    'x >0 on va vers la droite, x<0 on va vers la gauche
    'dans les 2 cas attention de ne pas sortir du tableau excel ;)
 
    'On va également éviter de re-déclencher Change (vu que l'on modifie une cellule OnChange se déclenche
    'Il ne faudra pas le faire si la modif de la cellule en colonne B doit exécuter du code dans l'événement Change
 
    On Error Resume Next 'si une erreur survient on passe qd même a la ligne suivante, jefais ca pour eviter de rester avec EnableEvent a false
    Application.EnableEvents = False 'Excel ne déclenchera plus de code événementiel
    Target.Offset(0, 1).Value = Mention 'la cellule immédiatement a coté de la notre prend la valeur contenu dans Mention
    Application.EnableEvents = True 'Excel recommence a gerer l'événementiel
    On Error GoTo 0 ' si des erreur surviennent a partir de maintenant excel nous avertira (comme avant le resume next - c'est par défaut)
 
End If

A++
Qwaz

[lagratteCchouette]

Merci pour ces explications, tu es vraiment super sympa...

Mais en réintégrant ton travail dans la procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub Worksheet_Change(ByVal Target As Range)

Il ne se passe rien dans la colonne mention...

En colonne A les noms des élèves - En colonne B les notes - en C les mentions et rien NADA...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
'Dim Note As Integer 'on va s'en passer, on fera directement appelle a Target.value il est la pour ça
Dim Mention As String
 
'On vérifie que target correspond bien a une des cellules que l'on souhaite contrôler
'Je suppose que tout les nom des élèves sont en colonne A et les note en B, ca donne donc
If Not Intersect(Target, Range("B:B")) Is Nothing Then    'rempalce le B par la colonne qui contient les notes
    'B:B represente toute la colonne
    'Note = Target
 
    Select Case Target.Value
        Case 0: Mention = "Nul"
        Case 1 To 5: Mention = "Moyen"
        Case 6 To 10: Mention = "Passable"
        Case 11 To 15: Mention = "Bien"
        Case 16 To 19: Mention = "Très Bien"
        Case 20: Mention = "Excellent"
    End Select
 
    'Cells(Target.Row, 3) = Mention  'remplace le 3 par le numéro de colonne que tu veux
    'ici on va utiliser la notion d'offset, qui permet de décaler la celui "pointé" de y lignes et de x colonne,
    'y positif on descend, négatif... on remonte dans le tableau
    'x >0 on va vers la droite, x<0 on va vers la gauche
    'dans les 2 cas attention de ne pas sortir du tableau excel ;)
 
    'On va également éviter de re-déclencher Change (vu que l'on modifie une cellule OnChange se déclenche
    'Il ne faudra pas le faire si la modif de la cellule en colonne B doit exécuter du code dans l'événement Change
 
    On Error Resume Next 'si une erreur survient on passe qd même a la ligne suivante, jefais ca pour eviter de rester avec EnableEvent a false
    Application.EnableEvents = False 'Excel ne déclenchera plus de code événementiel
    Target.Offset(0, 1).Value = Mention 'la cellule immédiatement a coté de la notre prend la valeur contenu dans Mention
    Application.EnableEvents = True 'Excel recommence a gerer l'événementiel
    On Error GoTo 0 ' si des erreur surviennent a partir de maintenant excel nous avertira (comme avant le resume next - c'est par défaut)
 
End If
End Sub

Qu'est-ce qui cloche, ou qu'est-ce que j'aurais oublié ???

______
" La musique donne une âme à nos cœurs et des ailes à la pensée." - Platon

[Qwazerty]

Salut
Étonnant ça fonction bien chez moi.
Voila un fichier implémente
++
Qwaz

[lagratteCchouette]

Exacte, cela marche.

T'es vraiment smypa, cela m'a faite gagner beaucoup de temps.
Le code....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
Private Sub Worksheet_Change(ByVal Target As Range)
'Dim Note As Integer 'on va s'en passer, on fera directement appelle a Target.value il est la pour ça
Dim Mention As String
 
'On vérifie que target correspond bien a une des cellules que l'on souhaite contrôler
'Je suppose que tout les nom des élèves sont en colonne A et les note en B, ca donne donc
If Not Intersect(Target, Range("B:B")) Is Nothing Then    'rempalce le B par la colonne qui contient les notes
    'B:B represente toute la colonne
    'Note = Target
 
    Select Case Target.Value
        Case 0: Mention = "Nul"
        Case 1 To 5: Mention = "Moyen"
        Case 6 To 10: Mention = "Passable"
        Case 11 To 15: Mention = "Bien"
        Case 16 To 19: Mention = "Très Bien"
        Case 20: Mention = "Excellent"
    End Select
 
    'Cells(Target.Row, 3) = Mention  'remplace le 3 par le numéro de colonne que tu veux
    'ici on va utiliser la notion d'offset, qui permet de décaler la celui "pointé" de y lignes et de x colonne,
    'y positif on descend, négatif... on remonte dans le tableau
    'x >0 on va vers la droite, x<0 on va vers la gauche
    'dans les 2 cas attention de ne pas sortir du tableau excel ;)
 
    'On va également éviter de re-déclencher Change (vu que l'on modifie une cellule OnChange se déclenche
    'Il ne faudra pas le faire si la modif de la cellule en colonne B doit exécuter du code dans l'événement Change
 
    On Error Resume Next 'si une erreur survient on passe qd même a la ligne suivante, jefais ca pour eviter de rester avec EnableEvent a false
    Application.EnableEvents = False 'Excel ne déclenchera plus de code événementiel
    Target.Offset(0, 1).Value = Mention 'la cellule immédiatement a coté de la notre prend la valeur contenu dans Mention
    Application.EnableEvents = True 'Excel recommence a gerer l'événementiel
    On Error GoTo 0 ' si des erreur surviennent a partir de maintenant excel nous avertira (comme avant le resume next - c'est par défaut)
 
End If
End Sub

LagratteCchouette

______
" La musique donne une âme à nos cœurs et des ailes à la pensée." - Platon

[lagratteCchouette]

Bon ce code marche très bien avec la gestion par colonne.

Ma question la voilà :

- Comme ce code marche en feuille2 et que les données arrivent sur la feuille2 de la feuille1 en liaison relative du genre =feuille1.!F15

Ce code ne marche que quand l'on saisie des valeurs manuellement, mais y-a-t'il un code ou une fonction qui réagisse simplement en fonction du lien ou valeur transmise par ce lien dans cette cellule dans cette cellule ?

LagratteCchouette

[Gorfael]

Salut lagratteCchouette et le forum

Comme ce code marche en feuille2 et que les données arrivent sur la feuille2 de la feuille1 en liaison relative du genre =feuille1.!F15 (?)

La macro Worksheet_Change ne réagit que à la sortie du "mode édition" d'une cellule, quand on modifie le contenu d'une cellule. Pas quand on modifie son affichage (format, résultat d'une formule).
Le problème est que maintenant on doit retrouver la bonne ligne dans "feuille2" en fonction de l'égalité d'un critère de la ligne concernée en "feuille1". et on ne dispose pas des infos.

On peut faire une recherche sur la formule du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

if sheets("feuille2").range("B" & x).formulalocal like "*" & target.address(0,0) then

Mais faudrait être sûr de la correspondance. il serait préférable d'avoir les adresses d'un identifiant commun aux deux (ou plus) feuilles.
Et les noms exacts des feuilles, les adresses concernées, etc.
A+

[lagratteCchouette]

Merci,

Je mets au propre les bonnes infos avec les vrais noms et liens et je soumets à nouveau.

LagratteCchouette

[Gorfael]

Salut lagratteCchouette et le forum
une autre solution : dans un module général tu colles le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Function Mention(Note As Range) As String
Application.Volatile
If Note.Count > 1 Then
    Mention = "# Impossibilité de traiter pluseurs notes #"
    Exit Function
End If
If IsEmpty(Note) Then
    Mention = ""
    Exit Function
End If
If Not (IsNumeric(Note)) Then
    Mention = "# Impossibilité de noter #"
    Exit Function
End If
Select Case Note
    Case Is < 1
        Mention = "Nul"
    Case Is < 6
        Mention = "Moyen"
    Case Is < 11
        Mention = "Passable" 'j'aurais inversé les mentions passable et moyen
    Case Is < 16
        Mention = "Bien"
    Case Is < 20
        Mention = "Très bien"
    Case Else
        Mention = "Excellent"
End Select
End Function

Tu retourne sur ta feuille de calcul
tu te mets sur une cellule devant recevoir la mention => barre de formule => Fx => catégorie : "Personnalisée"
Tu choisis Mention
et tu l'utilises comme une formule classique.
Dans l'argument Note, tu mets l'adresse de ta note, et tu valides.
A+

[lagratteCchouette]

Merci au forum.

Comme il est nécessaire d'avoir plus d'informations j'ouvre donc une autre discussion.