Discussion :

[debdev]

Bonjour,

Dans une proc report, est il possible, pour un titre de colonne, de concaténer du texte et la valeur d'une variable ?

J'explique plus en détails:
- j'ai un dataset avec les variables label1 label2 total stat (voir pièce jointe 1)
- je voudrais que la proc report me sorte la même chose mais avec les modifications suivantes (voir pièce jointe 2)
a. pas de colonne total
b. la colonne stat qui s'appelle Total N= suivi du chiffre présent dans la colonne total d'origine

Voici mon code (qui n'est pas le mien en fait donc je ne le comprends pas vraiment d'où mes difficultés à le modifier):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
proc report data=MaTable nofs split = "$" headskip ;
	column ("Situation" label1 label2) ("Total N="!!total stat);	/* ça ne marche pas */
	define label1 /id flow order = data "" width=15 style=[cellwidth=6 cm] left;
	define label2 /id flow order = data "" width=15 style=[cellwidth=6 cm] left;
	define stat / ""  order = data width=15 style=[cellwidth=2.5 cm] left;
run ;

Je vous remercie pour votre aide.

[olivier.decourt]

Bonjour.
Pas facile de construire des en-têtes (qui sont souvent définis avant la lecture des données) à partir du contenu d'une table. C'est comme si tu voulais incruster ton N=54 dans un titre.
La solution la plus simple est de récupérer ta valeur 54 dans une macro-variable avec une étape Data, puis de l'injecter dans l'en-tête de ta variable au moment de la proc Report (à indiquer dans son DEFINE ; l'instruction COLUMN indique pour sa part les colonnes, leur ordre, et leur imbrication éventuelle sous un intitulé commun, comme ici "SITUATION").

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
DATA work.stats ;
    INFILE CARDS DLM="," MISSOVER DSD ;
    INPUT label1 $ label2 $ total stat :$20. ;
CARDS ;
a,,54,28 (51.9%)
b,,54,28 (51.9%)
,f1,,11 (64.7%)
,f2,,3 (17.6%)
;
RUN ;
/* récupération du total dans une macro-variable */
DATA _NULL_ ;
    SET work.stats ;
    IF _N_=1 THEN CALL SYMPUT ("totalN", COMPRESS(total)) ;
    STOP ;
RUN ;
/* tableau */
PROC REPORT DATA=work.stats NOFS SPLIT = "$" HEADSKIP ;
    COLUMN ("Situation" label1 label2) stat ;
    DEFINE label1 / ID FLOW ORDER = DATA "" WIDTH=15 STYLE=[CELLWIDTH=6 CM] LEFT;
    DEFINE label2 /ID FLOW ORDER = DATA "" WIDTH=15 STYLE=[CELLWIDTH=6 CM] LEFT;
    DEFINE stat / "Total N=&totalN" ORDER = DATA WIDTH=15 STYLE=[CELLWIDTH=2.5 CM] LEFT;
RUN ;

Olivier

[debdev]

Un grand merci à toi.
Une nouvelle fois, tu as trouvé la solution.
C'est trop cool !!!

Merci.
Bonne fin de journée et bon week end !