Discussion :

[babybell]

Bonjour les amis du forum

Aujourd'hui j'ai une question pour mettre automatiquement à jour, après création un graphique d'après des données nouvelles.
En pièce jointe un exemple (je sais que beaucoup n'aiment pas, mais c'est plus parlant) que j'explique :
Je copie le dernier graphique pour en créer un autre(feuille graphique). Je voudrais le remplir des données nouvelles concernant le mois 05/09(feuille données) nouvellement remplies. Mais je bute sur la manière de remplir ce nouveau graphique.

Si une âme charitable pouvait se pencher sur mon problème, je l'en remercierai

[babybell]

Le fichier joint n'était pas le bon pour les tests. Celui-ci est mieux.

Merci

[Fvandermeulen]

Bonjour,
Voici ma proposition, je ne me suis pas basé sur ce que tu avais déjà fait car je ne m'y retrouvais pas, n'hésites pas si tu as des questions.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub CopieGraph()
 
Dim NbGraph As Integer
Dim LDest As Integer
Dim CVal As Integer
Dim Ma As String
 
 
NbGraph = Sheets("Graphique").ChartObjects.Count 'Compte le nombre de graph
LDest = (NbGraph * 20) - 1 'Defini la ligne où copier le nouveau graph
CVal = Sheets("Données").UsedRange.Columns.Count - 3 'Renvoi le numéro de colonne du dernier mois
 
If NbGraph = CVal Then Exit Sub 'Sort si le nombre de graph = nombre de mois
 
Ma = Format(DateSerial(Right(Sheets("Données").Cells(1, CVal).Value, 2), NbGraph + 1, 1), "mmmm/yyyy")
 
'
    Sheets("Graphique").ChartObjects(NbGraph).Activate
    ActiveChart.ChartArea.Copy
    Sheets("Graphique").Cells(LDest, 1).Select 'je sais les select sont a éviter mais...
    ActiveSheet.Paste
'On adapte la série de données source; CVal + 2 car le mois+2 = colonne utilisée
    ActiveChart.SeriesCollection(1).Values = _
        "=(Données!R2C" & CVal + 2 & ":R3C" & CVal + 2 & ",Données!R5C" & CVal + 2 & ":R6C" & CVal + 2 & ",Données!R8C" & CVal + 2 & ":R9C" & CVal + 2 & ")"
    ActiveChart.SeriesCollection(1).Name = "=Données!R1C" & CVal + 2
'Adapte le nom du graph
    ActiveChart.ChartTitle.Select
    Selection.Characters.Text = "TESSI" & Chr(10) & "Comparatif RNI CVC" & Chr(10) & Ma
 
 
    Sheets("Graphique").Cells((NbGraph * 20) + 19, 1).Select 'se place sous le graph copié
 
End Sub

A+

[babybell]

Merci Fvandermeulen, c'est tout à fait ce que je voulais. Je n'arrivais pas à mettre les nouvelles données.

Merci encore

[babybell]

Bonjour à tous et en particulier à Fvandermeulen.

J'ai oublié un détail qui a son importance, mon tableau va évoluer(voir pièce jointe).
Par programme, lorsque j'ai un nouveau centre, il se créé automatiquement et vient insérer 3 lignes, avec les détails correspondants, au dessus de la dernière ligne de total, où en-dessous du dernier centre, c'est comme on veut.
Est-il possible par macro d'inclure les deux lignes nouvelles de pourcentage, sachant qu'il pourra y en avoir d'autres encore en-dessous, ou dois-je, en dur, les rajouter dans le corps de la macro ?

Merci de votre aide

[Fvandermeulen]

Salut,
En ce qui concerne l'ajout de séries il faudra adapter la partie du code ci-dessous en randant les lignes dynamiques.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
'On adapte la série de données source; CVal + 2 car le mois+2 = colonne utilisée
    ActiveChart.SeriesCollection(1).Values = "=(Données!R2C" & CVal + 2 & ":R3C" & CVal + 2 & ",Données!R5C" & CVal + 2 & ":R6C" & CVal + 2 & ",Données!R8C" & CVal + 2 & ":R9C" & CVal + 2 & ")"
    ActiveChart.SeriesCollection(1).Name = "=Données!R1C" & CVal + 2

Je te laisse essayer...je ragarderai un peu plus tard de mon côté, j'ai un peu de boulot qui m'attend...
Mais pour te mettre sur la piste de mon idée tu peux (je pense) utiliser une variable dans une boucle du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MaSource = MaSoure + nouvelles lignes

A+

[Fvandermeulen]

Re,
Réunion annulée... J'ai retravaillé ton code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Sub CopieGraph()
 
Dim NbGraph As Integer
Dim LDest As Integer
Dim CVal As Integer
Dim Ma As String
Dim i As Integer
Dim Nl As Integer
Dim MaSerie As String
Dim MonXVal As String
 
 
NbGraph = Sheets("Graphique").ChartObjects.Count 'Compte le nombre de graph
LDest = (NbGraph * 20) - 1 'Defini la ligne où copier le nouveau graph
CVal = Sheets("Données").UsedRange.Columns.Count - 3 'Renvoi le numéro de colonne du dernier mois
 
    If NbGraph = CVal Then Exit Sub 'Sort si le nombre de graph = nombre de mois
 
Ma = Format(DateSerial(Right(Sheets("Données").Cells(1, CVal).Value, 2), NbGraph + 1, 1), "mmmm yyyy")
 
'
    Sheets("Graphique").ChartObjects(NbGraph).Activate
    ActiveChart.ChartArea.Copy
    Sheets("Graphique").Cells(LDest, 1).Select 'je sais les select sont a éviter mais...
    ActiveSheet.Paste
 
Nl = Application.Subtotal(3, Sheets("Données").Range("b:b"))
 
For i = 2 To Nl + 3 Step 3 'Step 3 pour avoir la bonne ligne à chaque boucle
    If i <> Nl + 3 Then 'Dernière boucle fini pas par , mais par )
        MaSerie = MaSerie & "Données!R" & i & "C" & CVal + 2 & ":R" & i + 1 & "C" & CVal + 2 & ","
        MonXVal = MonXVal & "Données!R" & i & "C1:R" & i + 1 & "C2" & ","
    Else
        MaSerie = MaSerie & "Données!R" & i & "C" & CVal + 2 & ":R" & i + 1 & "C" & CVal + 2 & ")"
        MonXVal = MonXVal & "Données!R" & i & "C1:R" & i + 1 & "C2" & ")"
    End If
Next i
 
MaSerie = "=(" & MaSerie
MonXVal = "=(" & MonXVal
 
'On adapte la série de données source; CVal + 2 car le mois+2 = colonne utilisée
    ActiveChart.SeriesCollection(1).Values = MaSerie
    ActiveChart.SeriesCollection(1).Name = "=Données!R1C" & CVal + 2
    ActiveChart.SeriesCollection(1).XValues = MonXVal
 
'Adapte le nom du graph
    ActiveChart.ChartTitle.Select
    Selection.Characters.Text = "TESSI" & Chr(10) & "Comparatif RNI CVC" & Chr(10) & Ma
 
    Sheets("Graphique").Cells((NbGraph * 20) + 19, 1).Select 'se place sous le graph copié
 
End Sub

PS. J'ai jouté la série des valeurs des X étant donné qu'elle change si plus de lignes.

A+

[babybell]

Bonjour Fvandermeulen, le forum

Je te remercie, j'étais justement en train de tester des boucles, mais les miennes ne fonctionnaient pas bien, je n'arrivais pas à avoir les bonnes lignes. Ton code fonctionne très bien. Je t'en remercie encore.
Bonne journée

[babybell]

Désolé, Fvandermeulen, c'est encore moi.
Ton code fonctionne à merveille si je rajoute bien 3 lignes pour une nouveau total de référence. Par contre, tel que, si je ne rajoute rien, il se plante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveChart.SeriesCollection(1).Values = MaSerie

Erreur d'exécution '1004':
Impossible de définir la propriété Values de la classe Series.

Quand je défile le code pas à pas, il ne passe pas par le else, donc il ne finit pas les variables par ")"

[Fvandermeulen]

Re,
Ben oui, c'est logique (et moi qui suis c..) j'ai pris la colonne B comme référence pour calculer le nombre d'élements mais si des éléments et la vérification de la dernière boucle mais ça ne correspond pas toujours aux données.
On doit utiliser la colonne qui correspond au mois ajouté donc il faut adapter les lignes suivantes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Nl = Application.Subtotal(3, Sheets("Données").columns(CVal))
 
For i = 2 To Nl + 3 Step 3 'Adapter le +3 pour que NL+x = 1ère ligne de dernière série
    If i <> Nl + 3 Then 'Dernière boucle fini pas par , mais par )

Désolé, j'ai pas réouvert ton fichier pour tester, je te laisse faire.
Si ça plante dis le, et encore désolé j'aurais du y penser

Edit: A priori Nl prendra la bonne valeur => enlever le "+3" dans la ligne "For i" et la ligne "If"

[babybell]

Je pense que NI ne prend pas la bonne valeur, car quand je rajoute plus que 3 lignes, cela ne prend que les 3 premières références et seulement la 4ème.
Regarde la PJ

[babybell]

La pièce jointe ne peut être envoyée

[Fvandermeulen]

Tu dois peut-être "purger" tes pièces jointes,
Mais de ce que je comprends tu peux avoir plus que 2 éléments dans ton axes X, c'est bien ça ?
Si oui, ça t'amuse de chaque fois rajouter une difficulté

[babybell]

Comment purger les PJ ?
Je ne rajoute pas de difficulté, mais quand je t'avais dit que mon fichier était évolutif, et que des lignes se rajoutaient automatiquement, je n'ai pas dit qu'en tout, il n'y en aurait que 3, je m'excuse de m'être mal exprimé.

[Fvandermeulen]

Pour purger vas dans le Tableau de Bord utilisateur et ensuite personnalisation du profil, en bas à gauche dans Divers tu verras "Pièces jointes". De là tu pourras supprimer des fichiers pour récupérer de la place.

Et ne sois pas désolé, c'était pour rire, pas de stress, ça m'amuse moi ce genre de fichier évolutif

[babybell]

Ca y est, j'ai fait le ménage.
Tu verras donc en PJ ce à quoi pourra ressembler mon tableau final(sans limitation de ligne).

[Fvandermeulen]

Re,
J'ai réouvert ton fichier pour être certain de ce que je dis, donc voici le code adapté.
J'ai adapté la ligne de la récup de la variable Nl et CVal
(CVal car j'avais mis en comment qu'elle prenais le N° de colonne mais c'était pas correct => erreur de l'adaptation précédente du code)

Je pensais que tu pouvais avoir plus que 2 données par ratio, c'est là que je pensais que ça allait ce corser...mais tu n'auras jamais que LS et LB pour chaque ratio, n'est ce pas?
Si oui, le code suivant devrait te convenir:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Sub CopieGraph()
 
Dim NbGraph As Integer
Dim LDest As Integer
Dim CVal As Integer
Dim Ma As String
Dim i As Integer
Dim Nl As Integer
Dim MaSerie As String
Dim MonXVal As String
 
 
NbGraph = Sheets("Graphique").ChartObjects.Count 'Compte le nombre de graph
LDest = (NbGraph * 19) - 1 'Defini la ligne où copier le nouveau graph
CVal = Sheets("Données").UsedRange.Columns.Count - 1 'Renvoi le numéro de colonne du dernier mois
 
    If NbGraph = CVal - 2 Then Exit Sub 'Sort si le nombre de graph = nombre de mois
 
Ma = Format(DateSerial(Right(Sheets("Données").Cells(1, CVal).Value, 2), NbGraph + 1, 1), "mmmm yyyy")
 
'
    Sheets("Graphique").ChartObjects(NbGraph).Activate
    ActiveChart.ChartArea.Copy
    Sheets("Graphique").Cells(LDest, 1).Select 'je sais les select sont a éviter mais...
    ActiveSheet.Paste
 
Nl = Application.Subtotal(3, Sheets("Données").Columns(CVal)) - 3
 
For i = 2 To Nl Step 3 'Adapter le +3 pour que NL+x = 1ère ligne de dernière série
    If i <> Nl Then 'Dernière boucle fini pas par , mais par )
        MaSerie = MaSerie & "Données!R" & i & "C" & CVal & ":R" & i + 1 & "C" & CVal & ","
        MonXVal = MonXVal & "Données!R" & i & "C1:R" & i + 1 & "C2" & ","
    Else
        MaSerie = MaSerie & "Données!R" & i & "C" & CVal & ":R" & i + 1 & "C" & CVal & ")"
        MonXVal = MonXVal & "Données!R" & i & "C1:R" & i + 1 & "C2" & ")"
    End If
Next i
 
MaSerie = "=(" & MaSerie
MonXVal = "=(" & MonXVal
 
'On adapte la série de données source
    ActiveChart.SeriesCollection(1).Values = MaSerie
    ActiveChart.SeriesCollection(1).Name = "=Données!R1C" & CVal
    ActiveChart.SeriesCollection(1).XValues = MonXVal
 
'Adapte le nom du graph
    ActiveChart.ChartTitle.Select
    Selection.Characters.Text = "TESSI" & Chr(10) & "Comparatif RNI CVC" & Chr(10) & Ma
 
    Sheets("Graphique").Cells((NbGraph * 20) + 19, 1).Select 'se place sous le graph copié
 
End Sub

[babybell]

T'es un chef Fvandermeulen, ça marche du tonnerre. Effectivement, comme tu l'as deviné, il n'y aura jamais que LS et LB pour chaque ratio.

Merci encore mille fois et bon après-midi.