Jmail : image dans corps du mail ?

**delavega** · 10/07/2009, 16h47

Bonjour,

Aujourd'hui, pour envoyer un mail dans le corps du message de mon mail, j'utilise la ligne de code ci-dessous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
jmail.appendHTML "<img src=""http://www.monsite.fr/logo.jpg"">"

Lorsque celui qui reçoit mon mail est en ligne, il peut voir mon logo, mais pas lorsqu'il est hors ligne.

Comment envoyer une image directement dans le corps du message, mais sans que ce soit un lien vers l'image ? Directement envoyé, du coup, avec le mail.

Merci d'avance,

Denis

**phyro** · 13/07/2009, 12h13

Bonjour,
Avec l'aide de Jmail on a un exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
 <%@LANGUAGE="VBSCRIPT" %>
<HTML>
<BODY>
<%
 
    Set jmail = Server.CreateObject("JMail.Message" )
 
    jmail.AddRecipient "myRecipient@hisdomain.com", "Mr.Example"
    jmail.From = "me@mydomain.com"
    jmail.Subject = "Here's some graphics!"
    jmail.Body = "A nice picture if you can read HTML-mail."
    ' The return value of AddAttachment is used as a
    ' reference to the image in the HTMLBody.
    contentId = jmail.AddAttachment("c:\myCoolPicture.gif" )
    ' As only HTML formatted emails can contain inline images
    ' we use HTMLBody and appendHTML
    jmail.HTMLBody = "<html><body><font color=""red"">Hi, here is a nice picture:</font><br>"
    jmail.appendHTML "<img src=""cid:" & contentId & """>"
    jmail.appendHTML "<br><br>good one huh?</body></html>"
    ' But as not all mailreaders are capable of showing HTML emails
    ' we will also add a standard text body
    jmail.Body = "Too bad you can't read HTML-mail."
    jmail.appendText " There would have been a nice picture for you"
   jmail.Send( "mailserver.mydomain.com" )
    %>
 Email sent! </BODY>
 </HTML>

Bon courage

Jmail : image dans corps du mail ?

ASP

Discussions similaires

Partager

Partager