Discussion :

[jo281]

Bonjour

J'ai beaucoup chercher sa vraiment avoir de réponse.
Ce que je cherche c'est comment ouvrir ou enregistrer un fichier (word,excel,...)

Merci beaucoup

[jo281]

J'ai trouvé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
 
<%@Language="VBScript"%>  
<%Option Explicit%>  
<%Response.Buffer = True%>  
<%  
 On Error Resume Next  
 Dim strPath,nom
 strPath = CStr(Request.QueryString("ref")) 
 nom = Request.QueryString("name")  
  '-- do some basic error checking for the QueryString   
 
 
If strPath = "" Then  
     Response.Clear  
     Response.Write("No file specified.")  
     Response.End  
 ElseIf InStr(strPath, "..") > 0 Then  
     Response.Clear  
     Response.Write("Illegal folder location.")  
     Response.End  
 ElseIf Len(strPath) > 1024 Then  
     Response.Clear  
     Response.Write("Folder path too long.")  
     Response.End  
 Else  
     Call DownloadFile(strPath)  
 End If  
 
Private Sub DownloadFile(file)  
     '--declare variables  
     Dim strAbsFile  
     Dim strFileExtension  
     Dim objFSO  
     Dim objFile  
     Dim objStream  
     '-- set absolute file location  
     strAbsFile = file  
     '-- create FSO object to check if file exists and get properties  
     Set objFSO = Server.CreateObject("Scripting.FileSystemObject")  
     '-- check to see if the file exists  
     If objFSO.FileExists(strAbsFile) Then  
         Set objFile = objFSO.GetFile(strAbsFile)  
         '-- first clear the response, and then set the appropriate headers  
         Response.Clear  
         '-- the filename you give it will be the one that is shown  
         ' to the users by default when they save  
         Response.AddHeader "Content-Disposition", "attachment; filename=" & nom
         Response.AddHeader "Content-Length", objFile.Size  
         Response.ContentType = "application/octet-stream"  
         Set objStream = Server.CreateObject("ADODB.Stream")  
         objStream.Open  
         '-- set as binary  
         objStream.Type = 1  
         Response.CharSet = "UTF-8"  
         '-- load into the stream the file  
         objStream.LoadFromFile(strAbsFile)  
         '-- send the stream in the response  
         Response.BinaryWrite(objStream.Read)  
         objStream.Close  
         Set objStream = Nothing  
         Set objFile = Nothing  
     Else 'objFSO.FileExists(strAbsFile)  
         Response.Clear  
         Response.Write("No such file exists.")  
     End If  
     Set objFSO = Nothing  
 End Sub 
%>

Merci quand même