Discussion :

[922374]

Bonjour,

J'ai deux problèmes avec un fichier xml :

1. le xml original n'a aucune structure car toutes les balises (exception faite de l'élément racine) sont au même niveau. Mon but est d'insérer une balise <toto> qui aurait pour enfant un FM1Titre et toutes les balises qui le suivent jusqu'à la prochaine occurence FM1Titre.

2. Je voudrais reporter le contenu de la balise FM1Titre comme nom de la balise mère que j'ai mentionné au dessus.

Voici un bout de mon fichier .xml :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
<XML> 
<FM1Titre>Description </FM1Titre> 
<Bloc-paragraphe>La table mère permet de paramétrer les tables. </Bloc-paragraphe> 
<Bloc-paragraphe>Toute nouvelle table doit être créée en premier lieu dans la table mère.</Bloc-paragraphe> 
 
<FM1Titre>Détails techniques </FM1Titre> 
...</XML>

Ce qu'il faudrait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
<XML> 
<Description> 
<FM1Titre>Description </FM1Titre> 
<Bloc-paragraphe>La table mère permet de paramétrer les tables. </Bloc-paragraphe> 
<Bloc-paragraphe>Toute nouvelle table doit être créée en premier lieu dans la table mère.</Bloc-paragraphe> 
</Description> 
 
<Détails techniques> 
<FM1Titre>Détails techniques </FM1Titre> 
</Détails techniques> 
 
...</XML>

Mes recherches sont restées infructueuses (recherches sur internet, solutions proposées sur le forum) et je commence à croire que ça ne peut peut-être pas se faire avec xslt 1.0.

D'habitude j'arrive à m'en sortir mais là je séche, alors si jamais quelqu'un à une solution ou une piste, aidez-moi...

Merci d'avance.

[Krantz]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
 
<xsl:output method="xml" version="1.0" encoding="ISO-8859-1" indent="yes"/>
	<xsl:strip-space elements="*"/>
 
	<xsl:key name="elemKey" match="FM1Titre" use="generate-id( parent::XML )" />
	<xsl:key name="elemKey" match="*[name() != 'FM1Titre' and name() != 'XML']" use="generate-id( preceding-sibling::FM1Titre[1]  )" />
 
	<xsl:template match="/">
		<xsl:apply-templates />
	</xsl:template>
 
	<xsl:template match="XML" >
		<XML>
			<xsl:apply-templates  select="key('elemKey', generate-id(.))"/>
		</XML>
	</xsl:template>
 
	<xsl:template match="FM1Titre" >
		<xsl:element name="{normalize-space(.)}">
			<xsl:apply-templates  select="key('elemKey', generate-id(.))"/>
		</xsl:element>
	</xsl:template>
 
	<xsl:template match="*" >
		<xsl:copy-of select="."/>
	</xsl:template>
 
</xsl:stylesheet>

attention toutefois : un contenu contenant un espace, comme "Détails techniques", ne passera pas comme nom d'élément !

Le code a été testé avec le XML suivant ("Détails techniques" est devenu ""Détails_techniques")

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
<?xml version="1.0" encoding="UTF-8"?>
<XML>
	<FM1Titre>Description </FM1Titre>
	<Bloc-paragraphe>La table mère permet de paramétrer les tables. </Bloc-paragraphe>
	<Bloc-paragraphe>Toute nouvelle table doit être créée en premier lieu dans la table mère.</Bloc-paragraphe>
	<FM1Titre> Détails_techniques</FM1Titre>
	<Bloc-paragraphe>2 La table mère permet de paramétrer les tables. </Bloc-paragraphe>
	<Bloc-paragraphe>2 Toute nouvelle table doit être créée en premier lieu dans la table mère.</Bloc-paragraphe>
</XML>

[Krantz]

... pour coller précisément à la structure attendue, le code est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
 
<xsl:output method="xml" version="1.0" encoding="ISO-8859-1" indent="yes"/>
	<xsl:strip-space elements="*"/>
 
	<xsl:key name="elemKey" match="FM1Titre" use="generate-id( parent::XML )" />
	<xsl:key name="elemKey" match="*[name() != 'FM1Titre']" use="generate-id( preceding-sibling::FM1Titre[1]  )" />
 
	<xsl:template match="XML" >
		<XML>
			<xsl:apply-templates  select="key('elemKey', generate-id(.))"/>
		</XML>
	</xsl:template>
 
	<xsl:template match="FM1Titre" >
		<xsl:element name="{normalize-space(.)}">
			<xsl:copy-of select="."></xsl:copy-of>
			<xsl:apply-templates  select="key('elemKey', generate-id(.))"/>
		</xsl:element>
	</xsl:template>
 
	<xsl:template match="*" >
		<xsl:copy-of select="."/>
	</xsl:template>
 
</xsl:stylesheet>

[922374]

Merci beaucoup pour la solution. J'avais finalement quelque chose d'à peu près similaire.

Vraiment merci d'avoir répondu.