Discussion :

[Atatorus]

Bonjour,

je cherche à savoir comment récupérer des paramètres passés depuis la ligne de commande dans une macro VBA (et non VB). Par exemple, si je lance la commande :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

excel classeur.xls param1=azerty param2=123

je voudrais une macro du genre getParam(String name), et getParam("param1") me retourne "azerty" et getParam("param2") me renvoie "123".

Merci à vous de votre aide.

[Jean-Philippe André]

salut,
regarde si mon tutoriel (dans ma signature) sur les passages de paramètres depuis batch te convient

[Atatorus]

Ça ne marche malheureusement pas. Ma macro doit s'exécuter dans Excel, et ce dernier ne semble pas reconnaitre les commutateurs /x et /cmd.

Je pense donc passer mes paramètres dans un fichier texte portant le nom de l'utilisateur.

Merci quand même pour l'aide.

[Jean-Philippe André]

Salut,
si tu le souhaites, j'ai trouvé une approche en utilisant le commutateur /e

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

"C:\Program Files\Microsoft Office\OFFICE11" /e/parametres "C:\temp\fichierxls.xls"

L'idée est donc de récupérer la ligne de commande qui lance Excel, et tu manipules la chaine de caractères dans la foulée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Declare Function GetCommandLine Lib "kernel32" Alias "GetCommandLineA" () As Long 
 
Private Declare Function lstrlen Lib "kernel32" Alias "lstrlenA" (lpString As Any) As Long 
 
Private Declare Function lstrcpy Lib "kernel32" Alias "lstrcpyA" (lpString1 As Any, lpString2 As Any) As Long 
 
'fonction disponible sur microsoft.public.vb.winapi
Private Function GetCmd() As String    
   Dim lpCmd As Long
   lpCmd = GetCommandLine()
   GetCmd = Space$(lstrlen(ByVal lpCmd))
   lstrcpy ByVal GetCmd, ByVal lpCmd
End Function

et tu appelleras cette fonction dans l'évènement Workbook_Open()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Workbook_Open()
 
   Dim CommandLine As String 'Ligne de Commande
   Dim MesParam As Variant
   CommandLine = GetCmd 'Lire la ligne de Commande
   'pour info
   'MsgBox CommandLine 
   CommandLine = Replace(CommandLine, ThisWorkbook.FullName, "")
   MesParam = Split(CommandLine,"/e")
   MsgBox MesParam(1)
End Sub

il me reste encore certains blindages à mon avis, mais l'idée est là.

[Atatorus]

Super, ça marche .

Merci beaucoup !