Discussion :

[grping]

Bonjour,

je recherche comment faire sur excel pour faire la somme de cellules réparties sur plusieurs feuilles de calcul (au sein d'un même classeur), sans avoir à indiquer le nom de la feuille.

en effet, le classeur en question peut contenir un nombre variable de feuilles, ainsi je recherche le moyen de créer une fonction qui fait la chose suivante :

ex. : dans la cellule A1 de "Feuil1" afficher la somme de la cellule A1 toutes les feuilles suivantes...

Pourriez-vous SVP m'aider à trouver la bonne méthode (fonction ou VBA)

Merci d'avance

Zico

[Fvandermeulen]

Salut,
Les deux options sont possibles, tu peux faire une somme placée en A1 de la feuille 1 du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SUM(Feuil2:Feuil9!A1)

Toute feuille "insérée" entre ces feuilles seront incluses dans le total de la feuille1.

Sinon par VBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub SumF()
 
Dim NbWs As Long, MonTot As Long, i As Long
 
NbWs = ActiveWorkbook.Worksheets.Count
 
For i = 2 To NbWs
    MonTot = MonTot + Worksheets(i).Range("A1").Value
Next i
 
Worksheets(1).Range("a1") = MonTot
 
End Sub

A+

[tranzebou]

Salut,

S'il s'agit toujours de la meme cellule sur chaque feuille et que c'est toi meme qui ajoute les feuilles tu dois pouvoir t'en sortir avec une fonction.

Ex :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(Feuil1:Feuil3!B5)

fera la somme de toutes les cellules B5 sur les feuilles comprises entre 'Feuil1' et 'Feuil3'. Donc si tu ajoutes une feuille entre ces 2 là la somme se fera automatiquement

Cdlt

[grping]

Super merci à vous 2 !

la version VBA est exactement ce que je cherchais, car le nom des feuilles et leur nombre varie !
Maintenant je vais chercher comment conditionner la somme en référence à une autre cellule car je m'aperçois que les fichiers que je récupère n'ont pas tous la même structure.

Ex. le tableau récapitulatif fait une somme selon le schéma suivant :

item1 | somme
item2 | somme
item3 | somme
item4 | somme
...etc

et dans certains tableaux j'ai un truc du genre

item1 | somme
item2 | somme
item4 | somme
...etc
(manque item 3), ce qui fout en l'air les coordonées cellule colonne et je dois donc rechercher comment additionner toutes les valeurs de la colonne "Somme" ayant dans la colonne "item" la valeur item(x)...

mais c'est un autre problème...


Encore merci à vous

[Fvandermeulen]

Re,
Tes Item sont unique pu tu peux avoir plusieurs fois un même Item ?

[grping]

oui, en effet mes items sont uniques (c'est déjà bien assez compliqué comme ça ;-)

merci
Zico

[Fvandermeulen]

Dans ce cas, ce code devrait faire l'affaire, j'ai considéré ton exemple, les Item en colonne A (1) avec les valeurs en colonne B (2)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub SumF()
 
Dim NbWs As Long, MonTot As Long, i As Long, c As Long, DerLig As Long
Dim MaPlage As Range, MaRech As Range
Dim ToSearch As String
 
NbWs = ActiveWorkbook.Worksheets.Count
 
For c = 1 To Cells(Columns(1).Cells.Count, 1).End(xlUp).Row
    ToSearch = Worksheets(1).Cells(c, 1).Value
    For i = 2 To NbWs
        Worksheets(i).Select 'Obligatoire pour le Find
        Set MaPlage = Worksheets(i).Range(Cells(1, 1), Cells(Cells(Columns(1).Cells.Count, 1).End(xlUp).Row, 1))
            With MaPlage
                Set MaRech = .Find(ToSearch, LookIn:=xlValues)
                If Not MaRech Is Nothing Then
                    MonTot = MonTot + MaRech.Offset(0, 1).Value
                End If
            End With
    Next i
    Worksheets(1).Cells(c, 2) = MonTot
    MonTot = 0
Next c
 
End Sub

Attention le Find en l'état trouve la correspondance exacte item1 <> Item1

A+

[grping]

Pardon de ne pas avoir répondu plus tôt et un grand merci pour ta réponse.

En effet cette macro m'a aidé à trouver la solution à mon problème (comme toujours sur ce forum) avec au passage la découverte de la méthode find, bien pratique.

encore merci et à bientôt

Zico