Discussion :

[doudou8mc]

Bonjou tout le monde,

je débute sur sql server 2000 et je m'entraine sur des procédures.J'ai récupéré cette procédure qui permet d'archiver des commandes (vieilles de plus de 6 mois) ds une table "order" et orderdetail"vers des tables identiques ds la base "archives". Mais j'ai du mal avec @cutoffdate, set nocount on, rollback tran, raise error,CURRENT_TIMESTAMP, DATEADD;

Quelqu'un pourrait-il m'expliquer les étapes de cette procédure , en français ?

Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
CREATE PROC dbo.ArchiveData
(
   @CutOffDate datetime = NULL
)
AS
BEGIN
	SET NOCOUNT ON
 
	IF @CutOffDate IS NULL 
	BEGIN
		SET @CutOffDate = DATEADD(mm, -6, CURRENT_TIMESTAMP)
 
	END
	ELSE
	BEGIN
		IF @CutOffDate > DATEADD(mm, -3, CURRENT_TIMESTAMP)
		BEGIN
			RAISERROR ('Cannot delete orders from last three months', 16, 1)
			RETURN -1
		END
	END
 
	BEGIN TRAN
 
		INSERT INTO Archive.dbo.Orders
		SELECT * 
		FROM dbo.Orders
		WHERE OrderDate < @CutOffDate
 
		IF @@ERROR <> 0
		BEGIN
			ROLLBACK TRAN
			RAISERROR ('Error occured while copying data to Archive.dbo.Orders', 16, 1)
			RETURN -1
		END
 
		INSERT INTO Archive.dbo.OrderDetails
		SELECT *
		FROM dbo.OrderDetails
		WHERE OrderID IN
		(
			SELECT OrderID
			FROM dbo.Orders
			WHERE OrderDate < @CutOffDate
		)
 
		IF @@ERROR <> 0
		BEGIN
			ROLLBACK TRAN
			RAISERROR ('Error occured while copying data to Archive.dbo.OrderDetails', 16, 1)
			RETURN -1
		END
 
		DELETE dbo.OrderDetails
		WHERE OrderID IN
		(
			SELECT OrderID
			FROM dbo.Orders
			WHERE OrderDate < @CutOffDate
		)
 
		IF @@ERROR <> 0
		BEGIN
			ROLLBACK TRAN
			RAISERROR ('Error occured while deleting data from dbo.OrderDetails', 16, 1)
			RETURN -1
		END
 
		DELETE dbo.Orders
		WHERE OrderDate < @CutOffDate
 
		IF @@ERROR <> 0
		BEGIN
			ROLLBACK TRAN
			RAISERROR ('Error occured while deleting data from dbo.Orders', 16, 1)
			RETURN -1
		END
 
	IF @@TRANCOUNT > 0
	BEGIN
		COMMIT TRAN
		RETURN 0
	END
 
END

[SQLpro]

Un petit cours sur le sujet : http://sqlpro.developpez.com/cours/s...r/transactsql/

A +

[doudou8mc]

merci bcp ça va m'aider à avancer .

[doudou8mc]

Au fait , je bloque surtout sur la première partie de la procédure;en effet le"@CutOffDate datetime = NULL" est ce bien ue variable de type date qu'on initialise à NULL?
Ce n'est pas tant au niveau de la syntaxe que je coince mais niveau algorithme du début de la procédure.
Le "SET @CutOffDate = DATEADD(mm, -6, CURRENT_TIMESTAMP)" c'est bien pour dire que @CutOffDate = date actuelle - 6mois ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
CREATE PROC dbo.ArchiveData
(
	@CutOffDate datetime = NULL
)
AS
BEGIN
	SET NOCOUNT ON
 
	IF @CutOffDate IS NULL 
	BEGIN
		SET @CutOffDate = DATEADD(mm, -6, CURRENT_TIMESTAMP)
 
	END
	ELSE
	BEGIN
		IF @CutOffDate > DATEADD(mm, -3, CURRENT_TIMESTAMP)
		BEGIN
			RAISERROR ('Cannot delete orders from last three months', 16, 1)
			RETURN -1
		END

Merci

[elsuket]

Bonjour,

en effet le"@CutOffDate datetime = NULL" est ce bien ue variable de type date qu'on initialise à NULL?

Attention, c'est une variable de type DATETIME (date + heure) car sous SQL Server 2008, le type DATE (et le type TIME) existent.

Quand on met = NULL derrière un paramètre d'entrée d'une procédure stockée, ou bien une valeur, cela signifie que si on appelle la procédure stockée sans ce paramètre, alors la variable prend la valeur par défaut ou est à NULL.

Le "SET @CutOffDate = DATEADD(mm, -6, CURRENT_TIMESTAMP)" c'est bien pour dire que @CutOffDate = date actuelle - 6mois ?

C'est exact

Veillez à utiliser la balide [CODE] (bouton # lorsque vous publiez du code)

@++

[doudou8mc]

Mais alors pour décrire le fonctionnement de l'algorithme c'est qu'il va prendre chaque valeur de la colonne date de la table "order", qu'il va la comparer à @CutOffDate , et si elle est plus vieille de 6 mois il l'archive et la supprime de la base ; mais si elle a moins de 3 mois alors un message apparait pour dire que c'est pas possible ?

et ce que je comprends pas aussi c'est que fait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
IF @@ERROR <> 0
		BEGIN
			ROLLBACK TRAN
			RAISERROR ('Error occured while deleting data from dbo.OrderDetails', 16, 1)
			RETURN -1

Merci pour votre aide et désolé d'être si insistant mais je tiens à comprendre cet procédure .

[elsuket]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
IF @CutOffDate > DATEADD(mm, -3, CURRENT_TIMESTAMP)
BEGIN
RAISERROR ('Cannot delete orders from last three months', 16, 1)
RETURN -1
END

Signifie que si la date d'archivage passée en entrée de la procédure stockée est supérieure à "maintenant" - trois mois, alors on lève une exception (RAISERROR).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
IF @@ERROR <> 0
BEGIN
ROLLBACK TRAN
RAISERROR ('Error occured while deleting data from dbo.OrderDetails', 16, 1)
RETURN -1

La fonction @@ERROR retourne le numéro d'erreur (la liste complète des numéros d'erreur et de leur libellés se trouve sous SQL Server 2000 dans la table sysmessages).
Elle retourne 0 s'il n'y a pas eu d'erreur lors de l'exécution de l'instruction qui précède directement IF @@ERROR <> 0

ROLLBACK TRAN permet de défaire la transaction, c'est à dire annuler toutes les modifications de données qui ont été effectuées depuis le BEGIN TRAN.

RETURN permet de terminer sans condition une procédure stockée, ou bien de retourner une valeur.
Nous pouvons écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
DECLARE @retVal INT
EXEC @retVal = dbo.ArchiveData
IF @retVal = -1
BEGIN
	-- Traitement pour -1 ...
END

Merci pour votre aide et désolé d'être si insistant mais je tiens à comprendre cet procédure .

Aucun problème, le forum est fait pour ça

@++

[doudou8mc]

Juste un GRAND MERCI !!!

[elsuket]

Avec plaisir, et à bientôt sur le forum

@++