Définir la position du scrollbar dans combobox

**Lufia** · 16/10/2009, 17h12

Bonjour le forum!!

Après avoir fait quelques recherche, je me tourne vers vous! J'ai un USF dans lequel il y a des combobox.
J'ai un combobox qui contient les valeurs 00:00 à 23:45 (J'ai donc 96 données).
j'ai trouvé comment afficher la valeur 07:00 par défaut à l'affichage du USF

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

cbxHeureDebutPrevue.ListIndex = 28

Mon problème est le suivant: lorsque je clic sur la flèche pour faire dérouler mon combobox, la première valeur affichée en haut est 00:00 même si ma valeur par défaut est 07:00.

Mes heures de début seront pratiquement toujours autour de 07:00, mais je dois conserver toutes les heures avant puisqu'il peut arriver que l'heure de début soir plus petite que 07:00 (03:45 par exemple).

Y a-t-il un moyen de définir la position du scrollbar dans mon combobox pour que ce soit la valeur #28 (07:00) qui soit affichée en tete de liste par défaut? J'ai plusieurs combobox où j'aimerais appliquer cette fonction!

Je vous remercie à l'avance!
Geneviève

**Fvandermeulen** · 16/10/2009, 18h00

Salut,
Par code je ne sais pas, tout comme je ne sais pas si la solution te convient comme tu as plusieurs combo a traiter, mais quand tu es en Design Mode sur ton module Forms, si tu choisi '07:00' dans ta liste tu devrais avoir le résultat souhaité à l'affichage.
A+

Edit: J'ai testé ton code par curiosité et chez moi j'ai le résultat souhaité

Dans quoi as tu placé cette ligne ?

**Lufia** · 16/10/2009, 18h19

Bonjour!

Je place ma ligne dans Userform_Initialize.
Mon problème n'est pas de faire afficher 07:00 comme valeur par défaut dans mon combobox. Pour ça ça fonctione #1.

Mon problème est que dans mon combobox qui est affiché 07:00 par défaut si je clic sur la flèche à droite du combobox pour ouvrire la liste (pour choisir une autre heure par exemple) la liste débute à 00:00. J'aimerais qu'elle début à 07:00. Je pourrais, selon le cas, remonter le scrollbar pour choisir une heure avant 07:00 ou la descendre pour choisir une heure après 07:00.

Présentement, l'utilisateur doit "scroller down" jusqu'à ce qu'il trouve l'heure désirée (généralement au tour de 07:00).

J'ai joins un fichier excel avec des Printscreens de ce que je souhaite.

Merci!

**laetitia** · 16/10/2009, 18h28

bonjour Lufia Fvandermeulen le forum
dans proprietees de ta combo tu definis ListRows a 28 !!!

**Fvandermeulen** · 16/10/2009, 18h35

Envoyé par Lufia

...
Mon problème est que dans mon combobox qui est affiché 07:00 par défaut si je clic sur la flèche à droite du combobox pour ouvrire la liste (pour choisir une autre heure par exemple) la liste débute à 00:00. J'aimerais qu'elle début à 07:00. Je pourrais, selon le cas, remonter le scrollbar pour choisir une heure avant 07:00 ou la descendre pour choisir une heure après 07:00.
...

C'est bien ça qui est étrange, chez moi il se place bien sur 07:00 dans la liste, ou autre si j'adapte l'index.

Bonjour Laetitia,

dans proprietees de ta combo tu definis ListRows a 28 !!!

Sauf erreur ton astuce ne fait qu'augmenter le nombre de lignes visible, mais n'hésite pas à me contredire (ce qui ne m'étonnerait pas vu la qualité habituelle de tes réponses

)

A+

**Lufia** · 16/10/2009, 19h14

Effectivement, ListRows ne fait qu'augmenter le nombre de ligne visibles dans mon combobox.

Je vous joins le fichier complet. Je ne comprend pas pourquoi ça ne fonctionne pas!

Merci!

**mercatog** · 16/10/2009, 22h27

Ce problème viendrait de la mise en forme de tes combo
sans elle, la scrollbar se positionne bien pour que la valeur par défaut soit visible en première ligne.

**laetitia** · 17/10/2009, 13h11

bonjour le fil le forum
l'ami Fvandermeulen c'est pas trompe j'ai écris une grosse "bouse" pas reflechi & surtout pas teste
comme le dit l'ami mercatog pb.. de concep...
j' ai fait l'essai sur une combo basique on a pas se pb....
un autre essai avec 3 combos pour arriver a un resultat a adapter!!

donnee des combos colonne A

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub UserForm_Initialize()
Dim c As Range
For Each c In Range("A1:a" & Range("A65536").End(xlUp).Row)
 ComboBox1.AddItem c
 ComboBox2.AddItem c
 ComboBox3.AddItem c
 Next c
ComboBox1.ListIndex = 28
ComboBox2.ListIndex = 28
ComboBox3.ListIndex = 28
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub ComboBox1_Click()
If ComboBox2.ListIndex = -1 Then Exit Sub
ComboBox2.ListIndex = ComboBox1.ListIndex
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub ComboBox2_Click()
If ComboBox3.ListIndex = -1 Then Exit Sub
ComboBox3.ListIndex = ComboBox2.ListIndex
End Sub

**Lufia** · 17/10/2009, 18h09

Bonjour et merci pour cette réponse!

Effectivement lorsque je test avec des combobox vide dans un nouveau USF ça fonctionne.

Avez-vous une idée de qu'est-ce qui pourrait causer cette "non compatibilité"?

Je vais continuer à faire des tests. J'attends de vos nouvelles.

Merci encore !
Ge

**mercatog** · 17/10/2009, 18h33

enlève de la mise en forme de tes combo (dans tes code Sub Combo_Change)
tu auras certes ce que tu voulais
mais tes heures s'afficheront en nombres décimaux
si dans ton code tu ne fais pas de calcul avec ces heurs, une variante de détournement c'est de remplir ta source de donnée avec du texte, genre '00:00, '00:15, '00:30 etc

**Lufia** · 17/10/2009, 18h36

Malheureusement, j'ai beaucoup de calcul par rapport aux heures

Je ne peux pas retirer la mise en forme puisque l'utilisateur doit savoir quoi prendre...

À ce que je comprend, il n'y a donc aucune facon que je puisse faire afficher la donnée #28 en haut de ma liste tant que j'ai des mises en forme dans mes combobox_change??

**mercatog** · 17/10/2009, 19h02

Peut être existe
sauf qu'hier j'ai fais des tâtonnements
quand la mise en forme dans combo est enlevée, ça fait ce que tu veux
pourquoi? je ne sais pas à ce stade
s'il y a donc une manière de contourner
genre mise en forme après la valeur par défaut ou avant.

**Lufia** · 19/10/2009, 20h11

Bonjour à vous tous!

Finalement, c'est définitivement le format de mes combobox qui pause problème:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

cbxHeureArriveMTCE.Value = Format(cbxHeureArriveMTCE.Value, "hh:mm")

J'ai tout de même résolu mon problème non pas par le code, mais plutôt à la source.
Ma source de données était:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
00:00
00:15
jusqu'à 
23:45

J'ai plutot décidé de mettre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
06:00
06:15
jusqu'à 
05:45

Ce qui fait que la première valeur affichée en haut est 06:00 (ce qui est tout à fait réaliste comme heure de début à comparer 00:00).

Bien que j'aurais aimé comprendre pourquoi le fomat de combobox ne semble pas compatible avec ListIndex, je mettrais la discussion comme résolue!

Merci beaucoup de vos bon commentaires, vous m'aidez encore une fois beaucoup!!!
Geneviève

**laetitia** · 20/10/2009, 08h42

rebonjour j'ai teste si tu mets le format a l' initialise tu devrais pas avoir ce souci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub UserForm_Initialize()
Dim c As Range
For Each c In Range("A1:a" & Range("A65536").End(xlUp).Row)
ComboBox1.AddItem Format(c, "hh:mm")
ComboBox2.AddItem Format(c, "hh:mm")
ComboBox3.AddItem Format(c, "hh:mm")
 Next c
ComboBox1.ListIndex = 28
ComboBox2.ListIndex = 28
ComboBox3.ListIndex = 28
End Sub

plus le code pour l'index

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub ComboBox1_Click()
If ComboBox2.ListIndex = -1 Then Exit Sub
ComboBox2.ListIndex = ComboBox1.ListIndex
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub ComboBox2_Click()
If ComboBox3.ListIndex = -1 Then Exit Sub
ComboBox3.ListIndex = ComboBox2.ListIndex
End Sub

**Lufia** · 20/10/2009, 17h42

!!!!!!!!!!!!
MERCI

!!!!!!!!!!!

Ça fonctionne super bien!

Parcontre, je n'ai pas besoin de la partie Combobox_Click...
Je ne sais pas ce que c'est supposé faire, mais ça fonctionne très bien sans!!!

Même si j'avais trouvé une autre façon de faire, cette façon me permet de rendre mon code beaucoup plus "propre"! Et surtout j'aime beaucoup comprendre pourquoi les choses ne fonctionnent pas.

Dans ce cas ci, j'utilisais Combobox.Rowsource et j'allais ensuite dans Combobox_Change pour définir mon format. En utilisant .Additem ça fonctionne super bien!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Private Sub Userform_Initialize()
Dim derlig As Long
Dim feuilSuivi As Worksheet
Dim HeureDef As String
Dim c As Range
 
'Définition des valeur de date picker par défaut
MultiPage1.Value = 0
DTPDatePrevue.Value = Now
MultiPage1.Value = 1
DTPDateDebut.Value = Now
MultiPage1.Value = 0
 
' Définition et mise en forme des items combobox Heures
For Each c In Worksheets("feuil1").Range("A1:a" & Range("A65536").End(xlUp).Row)
cbxHeureArriveMTCE.AddItem Format(c, "hh:mm")
cbxHeureArriveOperateur.AddItem Format(c, "hh:mm")
cbxHeureCadenassage.AddItem Format(c, "hh:mm")
cbxHeureCadenPrevue.AddItem Format(c, "hh:mm")
cbxHeureDebutDemarPrevue.AddItem Format(c, "hh:mm")
cbxHeureDebutPrevue.AddItem Format(c, "hh:mm")
cbxHeureDebutTravaux.AddItem Format(c, "hh:mm")
cbxHeureDecadenassage.AddItem Format(c, "hh:mm")
cbxHeureDecadenPrevue.AddItem Format(c, "hh:mm")
cbxHeureDemarrage.AddItem Format(c, "hh:mm")
cbxHeureFinAutresTravaux.AddItem Format(c, "hh:mm")
cbxHeureFinPrevue.AddItem Format(c, "hh:mm")
cbxHeureFinProd.AddItem Format(c, "hh:mm")
cbxHeureFinTravaux.AddItem Format(c, "hh:mm")
cbxHeureRemisMTCE.AddItem Format(c, "hh:mm")
Next c
 
' Définition des heures par défaut
HeureDef = 28
 
cbxHeureDebutPrevue.ListIndex = HeureDef
cbxHeureArriveMTCE.ListIndex = HeureDef
cbxHeureArriveOperateur.ListIndex = HeureDef
cbxHeureCadenassage.ListIndex = HeureDef
cbxHeureCadenPrevue.ListIndex = HeureDef
cbxHeureDebutDemarPrevue.ListIndex = HeureDef
cbxHeureDebutPrevue.ListIndex = HeureDef
cbxHeureDebutTravaux.ListIndex = HeureDef
cbxHeureDecadenassage.ListIndex = HeureDef
cbxHeureDecadenPrevue.ListIndex = HeureDef
cbxHeureDemarrage.ListIndex = HeureDef
cbxHeureFinAutresTravaux.ListIndex = HeureDef
cbxHeureFinPrevue.ListIndex = HeureDef
cbxHeureFinProd.ListIndex = HeureDef
cbxHeureFinTravaux.ListIndex = HeureDef
cbxHeureRemisMTCE.ListIndex = HeureDef
 
 
' Récupération du numéro de PostMortem
Set feuilSuivi = Sheets("Data suivi Arrets")
derlig = Cells(65536, 2).End(xlUp).Row + 1
txbNoPost.Value = feuilSuivi.Cells(derlig, 1).Value
 
End Sub

Un gros merci à vous tous pour votr aide!!!!

Geneviève

**laetitia** · 20/10/2009, 17h58

re, les combobox clik servent a caler les autres sur ta premiere combo
exemple combo1 a 8h00 les autres combos 2,3 se mettent a 8h00
bien sur ca marche que si tu commences par la combo 1 on pourrait le faire pour les autres. enfin pas utiles!!

evite Combobox.Rowsource aucune souplesse derriere!!! pour moi le mieux est AddItem ou mieux encore combobox.list

**Lufia** · 21/10/2009, 03h06

Je dois dire que c'est une première les combobox pour moi en USF excel alors j'apprend de mes erreurs

J'en prend très certainement bonne note

Merci encore!!!
Geneviève

**mercatog** · 21/10/2009, 13h55

Si je me permet d'ajouter un peu de sel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub Userform_Initialize()
Dim Ktrl As Control
Dim Cel As Range
Dim derlig As Long
Dim feuilSuivi As Worksheet
 
MultiPage1.Value = 0
DTPDatePrevue.Value = Now
MultiPage1.Value = 1
DTPDateDebut.Value = Now
MultiPage1.Value = 0
 
For Each Ktrl In Me.Controls
 
    If TypeOf Ktrl Is MSForms.ComboBox And Left(Ktrl.Name, 8) = "cbxHeure" Then
        For Each Cel In Sheets("Feuil1").Range("A1:A96")
            Ktrl.AddItem Format(Cel.Value, "hh:mm")
        Next Cel
        Ktrl.ListIndex = 28
    End If
Next Ktrl
 
Set feuilSuivi = Sheets("Data suivi Arrets")
derlig = feuilSuivi.Cells(65536, 2).End(xlUp).Row + 1
txbNoPost.Value = feuilSuivi.Cells(derlig, 1).Value
 
With tbxCommentaires
        .MultiLine = True
        .EnterKeyBehavior = True
End With
End Sub

**Lufia** · 21/10/2009, 16h09

Bonjour!

Effecitvement ça allège beaucoup mon code!

Un grand merci encore à vous pour tout votre savoir!!

Bonne journée!!

Geneviève

Code final:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub Userform_Initialize()
Dim derlig As Long
Dim feuilSuivi As Worksheet
Dim HeureDef As String, SourceHeure As String
Dim Ktrl As Control
Dim Cel As Range
 
'Définition des valeur de date picker par défaut
MultiPage1.Value = 0
DTPDatePrevue.Value = Now
MultiPage1.Value = 1
DTPDateDebut.Value = Now
MultiPage1.Value = 0
 
' Définition et mise en forme des items combobox Heures
For Each Ktrl In Me.Controls
 
    If TypeOf Ktrl Is MSForms.ComboBox And Left(Ktrl.Name, 8) = "cbxHeure" Then
        For Each Cel In Sheets("Feuil1").Range("A1:A96")
            Ktrl.AddItem Format(Cel.Value, "hh:mm")
        Next Cel
        Ktrl.ListIndex = 28
    End If
 
Next Ktrl
 
' Récupération du numéro de PostMortem
Set feuilSuivi = Sheets("Data suivi Arrets")
derlig = Cells(65536, 2).End(xlUp).Row + 1
txbNoPost.Value = feuilSuivi.Cells(derlig, 1).Value
 
End Sub

**mercatog** · 21/10/2009, 16h13

par contre il faut faire un peu attention a derlig
pour éviter toute "mauvaise surprise" éventuelle
mieux spécifier la feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

derlig = feuilSuivi.Cells(65536, 2).End(xlUp).Row + 1

Définir la position du scrollbar dans combobox [XL-2003]

Macros et VBA Excel

Discussions similaires

Partager

Partager