Discussion :

[Julie!!!]

Bonjour,

J'ai beau chercher, je ne trouve pas comment afficher le numero de chaque ligne dans un formulaire continu. L'idéal pour moi, serait que si on efface une des lignes, le numero se remette à jour.

Exemple :
1 Anne (poubelle)
2 Bambi (poubelle)
3 Diane (poubelle)

Si on efface la ligne 2 Bambi grace à la cmd Poubelle alors :

1 Anne (poubelle)
2 Diane (poubelle)

Quelqu'un a une idée ?

Merci d'avance !

Julie

[Muhad'hib]

Salut,

J'ai rencontré le même besoin. J'avais créé un champ N_num dans ma table.
Dans mon formulaire j'aivais vérouillé ce champ pour qu'il ne soit pas modifiable par l'utilisateur.

En utilisant les événement avant insertion et suppression comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Public Sub Form_AfterDelConfirm(Status As Integer)
sNumero_Carac
End Sub
 
Private Sub Form_BeforeInsert(Cancel As Integer)
 
Me.N_num = DCount("ID", "t_rapport", "[N_ID_controles] = " & Forms("f_controles").ID) + 1
 
End Sub

et la fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Public Sub sNumero_Carac()
 
 
    On Error GoTo sNumero_Carac_Error
Dim Sql As String
Dim Rs As DAO.Recordset
Dim I As Integer
 
Sql = "SELECT T_rapport.N_num FROM T_rapport WHERE T_rapport.N_ID_controles = " & Forms("f_controles").ID & ";"
Set Rs = CurrentDb.OpenRecordset(Sql, dbOpenDynaset)
If Not (Rs.EOF = True And Rs.BOF = True) Then
    Rs.MoveFirst
    I = 1
    Do Until Rs.EOF = True
        Rs.Edit
        Rs(0) = I
        Rs.Update
        I = I + 1
        Rs.MoveNext
    Loop
    Forms("f_controles").T_rapport.Form.Requery
 
End If
 
 
    On Error GoTo 0
 
sNumero_Carac_Exit:
    'Libération des variables
    Exit Sub
 
sNumero_Carac_Error:
 
    MsgBox "Erreur inatendue N°" & Err.Number & " (" & Err.Description & ") dans la fonction/procédure sNumero_Carac du Module M_prog"
GoTo sNumero_Carac_Exit
 
End Sub

[Julie!!!]

Bonjour !

Merci pour ta réponse ! J'ai du ajouter des fonctions à la base et du coup j'ai un peu laissé de côté ce problème.
J'ai toutefois essayé ton code mais ca n'a pas fonctionné : ( ... Malheureusement, le temps me presse et je ne peux plus essayer de resoudre ce problème....

Merci encore pour ton aide

Julie

[lucas-18]

Bonjour !

Merci pour ta réponse ! J'ai du ajouter des fonctions à la base et du coup j'ai un peu laissé de côté ce problème.
J'ai toutefois essayé ton code mais ca n'a pas fonctionné : ( ... Malheureusement, le temps me presse et je ne peux plus essayer de resoudre ce problème....

Merci encore pour ton aide

Julie

Essayes ceci ; cela marche impeccablement :
Colles ce code dans un module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Function NombreLigne(Frm As Form, NomClef As String, _
                    ClefValue As Variant) As Long
    Dim Rs As Object
    Dim ComptLigne As Integer
    On Error GoTo Err_NombreLigne
    Set Rs = Frm.Recordset.Clone
    Select Case Rs.Fields(NomClef).Type
        Case dbText, dbMemo, dbChar, dbByte
            Rs.FindFirst "[" & NomClef & "] = '" & ClefValue & "'"
        Case Else
            Rs.FindFirst "[" & NomClef & "] = " & ClefValue
    End Select
    Do Until Rs.BOF
        ComptLigne = ComptLigne + 1
        Rs.MovePrevious
    Loop
Sortie_NombreLigne:
    NombreLigne = ComptLigne
    Exit Function
Err_NombreLigne:
    ComptLigne = 0
    Resume Sortie_NombreLigne
End Function

Ensuite, crées une zone de texte dans ton formulaire (pas dans ta table) que tu nommes :
NomClef
et come source de contrôle :
=NombreLigne([Form];"N°";[N°])

Tu remplaçes uniquement les 2 "N°" par le nom que porte le champ NumAuto de ta table ...

Voilà

[Julie!!!]

Merci lucas-18, ton code marche parfaitement !