Excel, Outlook probleme de sécurité

**Nako_lito** · 29/10/2009, 14h12

Bonjour a tous,
je développe une petite apli qui permet d'envoyer automatiquement des mails a un groupe de personne définis.
J'arrive a lancer la procedure, tout fonctionne correctement, seulement quand je suis sur la ligne de code "mail.send", un message dans Outlook me dis qu'un autre programme essaye d'envoyer un mail et que c'est peu etre un virus, alors faut attendre 5s et cliquer sur "oui je veux envoyer", existe t'il un moyen de zapper ce message et répondre automatiquement "oui" ?

Merci par avance.

**Fvandermeulen** · 29/10/2009, 14h27

Salut,
Pour ce "problème" tu as plusieurs possibilités, l'une c'est d'installer ClickYes (recherche via Google), l'autre c'est les SendKeys (mais pas toujours fiable) et ensuite la méthode CDO, voici un exemple.
Attention tu dois référencer Microsoft CDO for Windows 2... Library
Il faut aussi adapter quelques lignes pour l'adresse de l'envoyeur, et des destinataires et aussi adapter l'adresse SMTP (voir dans le code)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Sub MailAvecCDO2000()
'--------------------------------------------------------------------------------------
' Procedure : Envoi Mail Avec CDO2000; vérifier si référencé
' Author    : Fred Vandermeulen
' Date      : 16/10/2009
' Purpose   : Envoi un mail sans message de sécurité (validation)
' Method:   : Déclaration tardive ("Late Binding")
' Microsoft CDO for Windows 2000 Library
'---------------------------------------------------------------------------------------
Dim Cdo_Message As Object
Set Cdo_Message = CreateObject("CDO.Message")
Const CdoTo = 1
Const CdoCc = 2
Const CdoBcc = 3
 
Set Cdo_Message.Configuration = GetSMTPServerConfig()
    With Cdo_Message
        .To = "LeDest" & Chr(64) & "fournisseur.com"
        .From = "TonNom" & Chr(64) & "TonExtention.com" 'Adapter avec ton adresse e-mail
        .Subject = "Le Sujet"
        .TextBody = "Le Corps du message"
        .AddAttachment ("c:cheminfichier.ext") 'Si tu veux joindre un fichier
        '.Cc = "LeCC" & Chr(64) & "hotmail.com" 'Si tu veux mettre un/des personne(s) en copie
        .Send
    End With
Set Cdo_Message = Nothing
End Sub
 
Function GetSMTPServerConfig() As Object
' Microsoft CDO for Windows 2000 Library
    Const cdoSendUsingPickup = 1
    Const cdoSendUsingPort = 2
    Const cdoSendUsingMethod = "http://schemas.microsoft.com/cdo/configuration/sendusing"
    Const cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
    Const cdoSMTPServerPort = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
 
    Dim Cdo_Config As Object 'New CDO.Configuration
    Set Cdo_Config = CreateObject("CDO.Configuration")
    Dim Cdo_Fields As Object
    Set Cdo_Fields = Cdo_Config.Fields
 
    With Cdo_Fields
        .Item(cdoSendUsingMethod) = cdoSendUsingPort
        .Item(cdoSMTPServer) = "srv-mail.LaBoite.com" 'Adapter l'adresse SMTP
        .Item(cdoSMTPServerPort) = 25
        .Update
    End With
 
    Set GetSMTPServerConfig = Cdo_Config
    Set Cdo_Config = Nothing
    Set Cdo_Fields = Nothing
 
End Function

A+