Discussion :

[aliosys]

windowsmediaplayer1.URL="c:\machanson.mp3"
ca se lance pas de problème
j'aimerai mettre les chanson que je charge dans une playlist
windowsmediaplayer1.*playlist*
après je ne connais pas les commandes.

les charger et le décharger de cette playlist
ex: if keyascii= 97 then 'code ascii "a"
' arrête la chanson1 en cours et lance la suivante.
windowsmediaplayer.playlist_chanson1 arrêt et effacement
else
load chanson suivante
end if

merci pour tout

[SilkyRoad]

bonjour


j'espere qu'avec uelques adaptations ces exemples pourront t'aider



Créer une PlayList de plusieurs séquences et les jouer à la suite
****************************************************

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub ajout_PlusieurSequences_PlayList_Et_Lance_Sequence()
Dim Xwmp As IWMPMedia
 
Wmp.currentPlaylist.Clear
 
Set Xwmp = Wmp.newMedia("C:\essai.mid") 'adapter les noms de fichiers
Wmp.currentPlaylist.insertItem 0, Xwmp
 
Set Xwmp = Wmp.newMedia("C:\maMusique.mp3")
Wmp.currentPlaylist.insertItem 1, Xwmp
 
Set Xwmp = Wmp.newMedia("C:\Jumbalaya.mid")
Wmp.currentPlaylist.insertItem 2, Xwmp
 
Wmp.Controls.Play
End Sub

nota:
-------
ne pas oublier de créer un bouton pour arreter la boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub arreterMediaPlayer()
Wmp.Controls.stop
End Sub

Les procédures qui suivent supposent que la macro "ajout_PlusieurSequences_PlayList_Et_Lance_Sequence" a préalablement été lancée et se trouve active


Pour passer à la séquence suivante ou précédente
*****************************************

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub passerSequenceSuivante()
Wmp.Controls.Next
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub passerSequencePrecedente()
Wmp.Controls.Previous
End Sub

Supprimer la deuxieme séquence dans la playlist
*****************************************
remarque: l 'index du premier élément = 0

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub supprimer_SequenceDansPlayList()
Dim It As Object
Set It = Wmp.currentPlaylist.Item(1)
Wmp.currentPlaylist.RemoveItem It
End Sub

Lancer une séquence spécifique de la playlist ( exemple le 3 eme item )
***********************************************************

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub JouerUneSequenceSpecifique()
Dim It As Object
Set It = Wmp.currentPlaylist.Item(2)
Wmp.Controls.playItem It
End Sub

Lister le nom des séquences contenues dans la PlayList
************************************************

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Lister_NomDesSequences_DansLaPlayList()
Dim Pl As IWMPPlaylist
Dim j As Integer, i As Integer
 
Set Pl = Wmp.currentPlaylist
j = Pl.Count
If Not j > 0 Then MsgBox "il n'y a pas d'éléments dans la playlist"
 
For i = 0 To j - 1
MsgBox Pl.Item(i).Name
'
'pour afficher la source :
'MsgBox Pl.Item(i).sourceURL
'
Next i
End Sub

Ajouter une séquence musicale dans la PlayList
***************************************
( la séquence est automatiquement placée à la suite des items existants )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub ajouterSequence_dans_playList()
Dim Ad As IWMPMedia
Set Ad = Wmp.newMedia("C:\couldntStandTheWeather.mp3") 'adapter le chemin
Wmp.currentPlaylist.appendItem Ad
End Sub

cordialement
michel

[aliosys]

je te remerci de ton aide precieuse
ca marche du tonnerre

Question:
la playlist est stocke en memoire ram
Ca ne risque pas de sature si on met 100 titre