Discussion :

[Filippo]

Bonjour,
Je souhaiterais récupérer le résultat d'une macro dans une variable.

La macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
%macro FoundInTable(MyTable, MyVar, MyValue);
	%global FoundInTable;
	%let FoundInTable=FALSE;
 
	proc sql noprint;
		SELECT COUNT(1) INTO :NbOcc FROM &MyTable WHERE &MyVar=&MyValue;
	quit;
 
	%If &NbOcc gt 0 %THEN %let FoundInTable=TRUE;
	&FoundInTable
%mend;

L'étape data :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
data titi;
	set titi;
	Length toto $8;
	toto=Symget('%FoundInTable(l.ListeCodes, crem, ''10000S'')');
 
	if toto=TRUE and tutu>0 then tata=1;
run;

Je me suis inspiré d'un autre post pour la syntaxe sans point-virgule à la fin de la macro. Mais je cale sur la syntaxe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

toto=Symget('%FoundInTable(l.ListeCodes, crem, ''10000S'')');

Si quelqu'un a une idée je suis preneur.

Merci

[lucaslu]

Avec des fonctions SCL, tu auras peut être ton bonheur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
%macro a(MyTable=, MyVar=, MyValue=);
  %let dsid=%sysfunc(open(&MyTable(where=(&MyVar="&MyValue")),i));
  %if (&dsid = 0) %then %put %sysfunc(sysmsg());
  %else %do;
      %let rc=%sysfunc(attrn(&dsid., NLOBSF ));  
  %end;
  %let rc=%sysfunc(close(&dsid.));
 
  %IF &NbOcc gt 0 %THEN %let FoundInTable=TRUE;
	"&FoundInTable"
  %mend;

et voici un appel possible

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
data a;
  a=%a(MyTable=sashelp.prdsale, MyVar=country, MyValue=CANADA);
run;

[Filippo]

Merci lucaslu,
je n'ai pas compris où tu donnais une valeur à NbOcc.

[lucaslu]

Effectivement!

J'ai voulu garder tes noms de variables mais j'avais fais des chagements. Voilà qui devrait être mieux.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
%macro a(MyTable=, MyVar=, MyValue=);
  %let FoundInTable=FALSE;
  %let dsid=%sysfunc(open(&MyTable(WHERE=(&MyVar="&MyValue")),i));
  %IF (&dsid = 0) %then %put %sysfunc(sysmsg());
  %else %do;
      %let rc=%sysfunc(attrn(&dsid., NLOBSF ));  
  %end;
 
  %IF &rc gt 0 %THEN %let FoundInTable=TRUE;
  %let rc=%sysfunc(close(&dsid.));
  "&FoundInTable"
  %mend;

Un petit exemple d'appel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
data a;
  a="FRANCE";
  b=%a(MyTable=sashelp.prdsale, MyVar=country, MyValue=FRANCE);
  output;
  a="CANADA";
  b=%a(MyTable=sashelp.prdsale, MyVar=country, MyValue=CANADA);
  output;
run;

[Filippo]

Ca marche très bien.

Merci beaucoup.