Discussion :

[sevyc64]

Salut à tous,

Voici un problème probablement assez pointu.
(Application Winform, framework 3.5, éventuellement compatible 2.0 mais c'est pas obligé)

Soit un certain nombre de type de contrôle différents mais ayant tous en commun une propriété nommé ProprieteMagique. Tous ces contrôles héritent de la classe générique Control, et font partis de mon écran :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
        Dim A As New MonTypeCtrl1
        Dim B As New MonTypeCtrl2
        Dim C As New MonTypeCtrl3
        Dim .....
 
        Me.Controls.AddRange(New Control() {A, B, C, ....})

J'ai besoin de modifier cette propriété sur l'ensemble des contrôles sans forcément en gérer leur type. L'idée est de faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
        For Each ctrl As Control In Me.Controls
            ctrl.ProprieteMagique = MaNouvelleValeur
        Next

Bien évidemment cela ne marche pas. ProprieteMagique n'est pas une propriété de Control, mais d'une des classes dérivées

Pourtant la variable ctrl, bien que de type Control, contient un objet d'un des types qui gèrent cette propriété. Comment je peux donc accéder à cette propriété à travers la variable Control ???
(Gérer le type des contrôles n'est pas trop envisageable, car il y déjà plus d'une dizaine de type, et c'est pas fini)

L'idée serait (peut-être) de pouvoir faire quelque chose du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ctrl.PropertyByName("ProprieteMagique")

Je n'imagine pas que ce ne soit pas possible en .Net d'autant plus que ça existe en standard dans d'autres langages Objet, mais je n'arrive pas à trouver un soupçon de solution dans le framework.
Ça me semble pourtant être une fonctionnalité de base en POO

[_PascalC_]

Salut, ce que tu cherche s'appelle de la "reflection" en .NET, mais l'utilisation d'une "Interface" me paraît plus approprié :

L'interface :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Public Interface IMagiqueControl
    Property ProprieteMagique() As String
End Interface

L'implementation sur les UserControls perso :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Public Class UserControl1
    Implements IMagiqueControl
 
    Public Property ProprieteMagique() As String Implements IMagiqueControl.ProprieteMagique
        Get
            '...
        End Get
        Set(ByVal value As String)
            '...
        End Set
    End Property
End Class
 
Public Class UserControl2
    Implements IMagiqueControl
 
    Public Property ProprieteMagique() As String Implements IMagiqueControl.ProprieteMagique
        Get
            '...
        End Get
        Set(ByVal value As String)
            '...
        End Set
    End Property
End Class

Et enfin l'utilisation avec ton foreach dans ta Form:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
For Each ctrl As Control In Me.Controls
    If TypeOf ctrl Is IMagiqueControl Then
        DirectCast(ctrl, IMagiqueControl).ProprieteMagique = "..."
    End If
Next

[sevyc64]

Je suis d'accord pour la reflexion, sauf que je n'ai pas su la mettre en oeuvre.

Quant aux contrôles, ce ne sont pas des UserControl. Ce sont des contrôles d'un éditeur tiers (des librairies qui ont été achetées par la boite dont on m'impose l'utilisation) et je n'ai pas accès au code source. Je ne peux donc rien modifier sur ces contrôles.

Et si j'ai donné l'exemple pour une propriété, je vais en fait (pour le moment) avoir besoin d'accéder à 2 ou 3 propriétés suivant les traitements

[_PascalC_]

ah ok ! Dans ce cas on va repartir sur de la reflection :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
For Each ctrl As Control In Me.Controls
    Dim pi As System.Reflection.PropertyInfo = ctrl.GetType().GetProperty("ProprieteMagique")
    If pi IsNot Nothing Then pi.SetValue(sender, MaNouvelleValeur, Nothing)
Next

[sevyc64]

Ca parait si simple comme ça , j'ai même pas su y arriver.

Je teste ça demain

[sevyc64]

Pour un peu, ça marchait du premier coup, mais non, j'ai eu un message d'erreur

La bonne syntaxe, apparemment, est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
For Each ctrl As Control In Me.Controls
    Dim pi As System.Reflection.PropertyInfo = ctrl.GetType().GetProperty("ProprieteMagique")
    If pi IsNot Nothing Then pi.SetValue(ctrl, MaNouvelleValeur, Nothing)
Next

Ça marche nickel, que du bonheur.

[_PascalC_]

Oups désolé ! Evidemment il fallait mettre "ctrl" à la place de "sender".
J'avais tapé vite fait un bout de code ou la variable à modifier s'appelait "sender". J'ai ensuite oublié de faire la modif à cet endroit avant de répondre sur le forum

[sevyc64]

Surtout que j'ai perdu un temps énorme à trouver comment corriger, environ 5 sec, le temps de lire le message d'erreur