Salut lexi92 et le forum
Pas sûr de tout comprendre
Plage 4:13 un planning permanent
Plage 18:27 ??? une base de données ?
En E6 :
=SI($B6="";"";SI(($B6<=E$4)*(E$4<=$C6);"x";""))
c'est une formule recopiable
Mais en faisant ça, tu t'interdis d'écrire dans la cellule E6 (et les autres)
Ne serait-il pas plus pratique de modifier la MFC :
Insertion>>Noms>>Définir
Noms dans le classeur : Jour_Feriers
Fait référence à : =Feuil2!$D$5:$D$16
E6 sélectionné : Format>>Mise ne Format conditionnel
Condition 1 :
Case 1 : La formule est
Case 2 : =($B6<>"")*($B6<=E$4)*(E$4<=$C6)*((JOURSEM(E$4;2)>5)+SOMMEPROD((E$4=Jour_Feriers)*1))
Format : Rose saumon + Hachure
Condition 2 :
Case 1 : La formule est
Case 2 : =($B6<>"")*($B6<=E$4)*(E$4<=$C6)
Format : Rose saumon
Condition 3 :
Case 1 : La formule est
Case 2 : =((JOURSEM(E$4;2)>5)+SOMMEPROD((E$4=Jour_Feriers)*1))
Format : Hachure
J'ai un peu modifié le principe de ta mise en forme : La couleur est liée aux tâches. Les hachures aux jours fériers et aux Week-End. Il faut que les deux conditions puissent être appliquées simultanément. C'est pour ça que les WE et jours fériers sont hachurés
L'importance de l'écriture des conditions est importante :
Si la condition 1 est appliquée, on ne va pas plus loin.
Il faut que la condition 1 ne soit pas applicable pour pouvoir vérifier la condition 2. Et la condition 3 ne sera testée que si la une et la deux ne sont pas applicable.
Tu peux reproduire la mi
se en forme, soit par recopie de mise en forme, soit par recopie de la cellule. Les formules tiennent compte des recopies.
Teste et dis si ça te va...
A+
Partager