Discussion :

[samawati]

Salut tout le monde,

j'aurais besoin d'un code VBA afin de réaliser le suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Si(ou(B4="XT",B4="YT",A4="ZT"),B4,"")

c.àd. que si la valeur de B4 est XT, YT ou ZT, il m'insère automatiquement la valeur de B4 dans les Céllules C4 et D4. Si j'éfface le contenu (XT,YT..) de B4, il les éfface aussi des Céllules C4 et D4.

Je doit avoir la possibilité d'entrer d'autres données dans les céllules B4,C4 et D4 sans que la macro intervienne!

Et tout celà est valable de B4 jusq'à B34

merci d'avance pour votre aide.

[Gorfael]

Salut samawati et le forum
Pour me répéter encore et encore : on n'est pas dans ta tête, pas devant ton écran, ni magicien et on ne connaît du problème que ce que tu nous dis !!!
Tout élément évident ne l'est que pour toi !
Ce que je crois comprendre :
un changement dans les cellules A4 à A34 entraîne des modifications :
si A est différent de "XT", "YT" ou "ZT" les cellules B, C et D doivent être vides. Sinon, on peut entrer une valeur quelconque dans ces cellules.

Si ce n'est pas ça, relis ton sujet et corriges-le !
A+

[samawati]

Salut Gorfael,

Merci premièrement pour la réponse rapide

Sorry j'ai fait une faute, il n'y a pas de A4!!

un changement dans les cellules B4 à B34 entraîne des modifications :
- si la valeur de B est égale à "XT", "YT" ou "ZT" les cellules C et D doivent prendre la même valeur que B.

- si B est différent de "XT", "YT" ou "ZT" les cellules C et D doivent être vides. Et on peut entrer une valeur quelconque dans ces cellules (C et D).

*********************
Et que ca doit fonctionner pour tout le classeur qui comporte 13 feuilles.
*********************

Voilà je pense que c'est plus claire maintenant

Merci encore une fois.

[Gorfael]

Salut samawati et le forum
Sous VBEditor, tu vas dans le module ThisWorkBook et tu colles la macro suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim Cel As Range
If Intersect(Target, Range([B4], [B34])) Is Nothing Then Exit Sub
'si ça ne concerne pas B4:B34, on sort
For Each Cel In Intersect(Target, Range([B4], [B34]))
'pour chaque cellule modifié de B4:B34
    If Cel = "XT" Or Cel = "YT" Or Cel = "ZT" Then
        Cel.Offset(0, 1) = Cel  'B+1=>C
        Cel.Offset(0, 2) = Cel  'B+2=>D
    Else
        Cel.Offset(0, 1) = ""   'B+1=>C
        Cel.Offset(0, 2) = ""   'B+2=>D
    End If
Next Cel
'cellule suivante
End Sub

Attention : la macro ne fait que ce qui est demandé : si une cellule de la plage est en minuscule, B4="zt" par exemple, C4 et D4 seront vidées.
La macro agit dès qu'une cellule de la plage B4:B34 est modifiée, quelque soit la feuille du classeur où est le module ThisWorkBook.
Si besoin de plus de précisions, les demander
A+

[samawati]

Salut Gorfael,

eh ben bravo c'est ce que je voulais exactement. Un grand merci!!

Je peux savoir stp pourquoi il fait la difference entre minuscule et majuscule? et s'il y a une solution pour ce genre probleme?

merci encore une fois.

==> Edit:
bon j'ai mis un changement et ca fonctionne.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
If Cel = "u" Or Cel = "U" Or Cel = "k" Or Cel = "K" Or Cel = "dv" Or Cel = "DV" Or Cel = "ft" Or Cel = "FT" Then
        Cel = UCase(Cel)
        Cel.Offset(0, 1) = Cel  'B+1=>C
        Cel.Offset(0, 2) = Cel  'B+2=>D
    Else
        Cel.Offset(0, 1) = ""   'B+1=>C

[laetitia]

bonjour samawati Gorfael le forum en debut de ton module tu rajoute

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Option Explicit'oblige a declarer les variables
Option Compare Text'pas de difference maj & min
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim Cel As Range
If Intersect(Target, Range([B4], [B34])) Is Nothing Then Exit Sub
'si ça ne concerne pas B4:B34, on sort
For Each Cel In Intersect(Target, Range([B4], [B34]))
 
ect...

je viens de voir ton edit avec option compare text pas besoin de l'ecrire comme cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Cel = "u" Or Cel = "U" Or Cel = "k" Or Cel = "K" Or Cel = "dv" Or Cel = "DV" Or Cel = "ft" Or Cel = "FT" Then

[samawati]

ok merci laetitia, c'est fait et ca fonctionne aussi

[Gorfael]

Salut à tous
Option Compare est une solution, mais elle est globale pour le module.
Je préfère utiliser d'autre solution :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
If ucase(Cel) = "U" Or ucase(Cel) = "K" Or ucase(Cel) = "DV" Or ucase(Cel) = "FT" Then
        Cel = UCase(Cel)
        Cel.Offset(0, 1) = Cel  'B+1=>C
        Cel.Offset(0, 2) = Cel  'B+2=>D
    Else
        Cel.Offset(0, 1) = ""   'B+1=>C

ou mettre le cel=Ucase(cel) avant le test (normalement, on ne fait que 2 passages de la macro, mais comme je n'ai pas testé...), mais ça met en majuscules les cellules qui ne correspondent pas aux critères.
A+