Discussion :

[Bilou_Gateux]

Exposé du problème :

Je récupère des mises à jour (19 fichiers) nommés selon le principe nod[0x????].nup où [0x????] est un nombre hexadécimal de 4 chiffres aléatoire dans un dossier Updfiles.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Set "source=%ProgramFiles%\Eset\ESET Online Scanner\Modules\data\updfiles\"
dir /A-D /B "%Source%*.nup"

Je souhaite les renommer en fonction de la chaine de caractères trouvée dans leur contenu :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Colonne 1 : chaine de caractères de recherche | Colonne 2 : nom du fichier destination
LOADER0 em000_32_l0.nup
PERSEUS0 em001_32_l0.nup
PERSEUS1 em001_32_l1.nup
ENGINE0 em002_32_l0.nup
ENGINE1 em002_32_l1.nup
ENGINE2 em002_32_l2.nup
ARCHIVES0 em003_32_l0.nup
ADVHEUR0 em004_32_l0.nup
ADVHEUR1 em004_32_l1.nup
CLEANER0 em005_32_l0.nup
CLEANER1 em005_32_l1.nup
CLEANER2 em005_32_l2.nup
ANTISTEALTH0 em006_32_l0.nup
ANTISTEALTH1 em006_32_l1.nup
ANTISTEALTH2 em006_32_l2.nup

Exemple : la commande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
pushd "%Source%"
findstr /R "ENGINE[0-2]" *.nup
popd

retourne

nod156A.nup:name=ENGINE0
nod284E.nup:name=ENGINE1
nod504C.nup:name=ENGINE2

avec ma table précédente, le 1er fichier nod156A.nup doit être renommé en em002_32_l0.nup
Je souhaite trouver le code le plus concis possible pour faire cette opération sur les 19 fichiers.

Mon code actuel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@echo off &Setlocal enableextensions
Set "source=%ProgramFiles%\Eset\ESET Online Scanner\Modules\data\updfiles\"
set "filtre=*.nup"

for /f "skip=1 tokens=1-2 delims= " %%a in ('findstr /R "_32_l[0-2]*" %~s0') do (
	for /f "tokens=*" %%c in ('dir /A-D /B "%source%*.nup"') do (
		for /f "tokens=*" %%z in ('findstr /R "%%a" "%source%%%c"') do (
		@echo found: %%a in %%c &pushd "%source%" &echo.ren %%c %%b &popd
		)
	)
)
goto :eof

[TABLE]
LOADER0 em000_32_l0.nup
PERSEUS0 em001_32_l0.nup
PERSEUS1 em001_32_l1.nup
ENGINE0 em002_32_l0.nup
ENGINE1 em002_32_l1.nup
ENGINE2 em002_32_l2.nup
ARCHIVES0 em003_32_l0.nup
ADVHEUR0 em004_32_l0.nup
ADVHEUR1 em004_32_l1.nup
CLEANER0 em005_32_l0.nup
CLEANER1 em005_32_l1.nup
CLEANER2 em005_32_l2.nup
ANTISTEALTH0 em006_32_l0.nup
ANTISTEALTH1 em006_32_l1.nup
ANTISTEALTH2 em006_32_l2.nup

[Flamby38]

Je ne comprends pas bien pourquoi tu cherches le code le plus concis possible? un code concis n'est pas nécessairement plus compréhensible ni plus rapide à executer. Quel est le but final?

[Bilou_Gateux]

Quel est le but final?

Améliorer mes connaissances en "programmation" de scripts en soumettant mon code et avoir l'avis de [1-2] experts sur ce forum qui apportent toujours des réponses qui démontrent la distance qui sépare le débutant (éclairé) de l'expert (avisé).

J'aime les réponses de ces personnes car elles me donnent matière à réflexion et me permettent de progresser.

C'est après avoir trouvé une réponse à un problème pour moi insoluble postée sur ce forum que j'ai décidé de m'inscrire pour pouvoir leur poser des questions quand je ne sais pas... encore.

[Flamby38]

ok, eh bien bon apprentissage alors
par contre je ne peux pas t'aider.

[Mac LAK]

Améliorer mes connaissances en "programmation" de scripts en soumettant mon code et avoir l'avis de [1-2] experts sur ce forum qui apportent toujours des réponses qui démontrent la distance qui sépare le débutant (éclairé) de l'expert (avisé).

J'aime les réponses de ces personnes car elles me donnent matière à réflexion et me permettent de progresser.

C'est après avoir trouvé une réponse à un problème pour moi insoluble postée sur ce forum que j'ai décidé de m'inscrire pour pouvoir leur poser des questions quand je ne sais pas... encore.

Le problème de la "concision" est un faux problème, et un vrai piège à c..

Je t'explique : certains langages, dont le batch, peuvent devenir "write-only". C'est à dire que dans certains cas, on peut écrire un programme effectuant une action donnée, mais qu'il est presque impossible de comprendre avec une simple lecture (= sans exécution) ce que fait le programme en question... Ce qui pose le problème de la maintenabilité du programme par la suite, y compris par le développeur initial.

Je ne saurais donc t'encourager à ne PAS chercher la concision à tout prix, mais plutôt à bien comprendre ce que tu fais, par exemple en comprenant ce que "coûtent" chacune des opérations élémentaires que tu effectues.

Typiquement, j'ai une sainte horreur des instructions multiples : tout code possédant plusieurs instructions sur une même ligne passe chez moi au broyeur, et ceci quel que soit le langage. Batch inclus.

Tu peux également aller jeter un œil à ce post sur l'utilisation correcte des commandes avec FOR /F : je ne saurais trop te conseiller d'utiliser usebackq avec tes commandes.

Pour le reste (optimisation du programme), je t'avoue qu'habituellement, il est relativement simple de recréer un jeu de test. Ce n'est pas le cas de ton problème initial, donc ce serait mieux que tu uploades une archive ZIP avec des fichier .NUP adéquats de façon à pouvoir, éventuellement, tester une solution plus optimale. Il doit être possible de faire ça avec seulement deux boucles imbriquées, je pense.

[I'm_HERE]

salut,



:: untested.bat

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
@echo off &Setlocal enableextensions


Set "source=%ProgramFiles%\Eset\ESET Online Scanner\Modules\data\updfiles\"

cd /d "%source%"

for /f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do (
  for %%c in (*.nup) do find "%%a" <"%%c">nul && echo  ren "%%c" "%%b"
)
pause
goto :eof

[TABLE]
LOADER0 em000_32_l0.nup
PERSEUS0 em001_32_l0.nup
PERSEUS1 em001_32_l1.nup
ENGINE0 em002_32_l0.nup
ENGINE1 em002_32_l1.nup
ENGINE2 em002_32_l2.nup
ARCHIVES0 em003_32_l0.nup
ADVHEUR0 em004_32_l0.nup
ADVHEUR1 em004_32_l1.nup
CLEANER0 em005_32_l0.nup
CLEANER1 em005_32_l1.nup
CLEANER2 em005_32_l2.nup
ANTISTEALTH0 em006_32_l0.nup
ANTISTEALTH1 em006_32_l1.nup
ANTISTEALTH2 em006_32_l2.nup

si ça fonctionne enlève le echo

[Flamby38]

Ecoutez les sages paroles de mac lak, un code simple et bien organisé c'est la garantie que quand tu le reliras 1 an plus tard tu le comprendras encore

[I'm_HERE]

Ecoutez les sages paroles de mac lak, un code simple et bien organisé c'est la garantie que quand tu le reliras 1 an plus tard tu le comprendras encore

salut,

syntaxe compact ou aérer...., pour ma part c'est une question de goût.

[Mac LAK]

syntaxe compact ou aérer...., pour ma part c'est une question de goût.

En fait, non, ce n'est pas un problème de goût... C'est un problème de lisibilité globale, du débutant à l'expert.

Une syntaxe "compacte" (= plusieurs instructions par ligne) rend la lecture difficile, et ceci quel que soit le langage. Le debug est encore plus difficile, car on ne peut pas poser de breakpoint sur (par exemple) l'instruction du milieu sans passer par le code ASM.

Dans le cas du batch (ou du shell), celà peut introduire des effets de bord ou des bugs pouvant être vicieux à trouver. Pour le debug, cela rend très difficile l'insertion de code de debug entre deux instructions.

Sachant qu'il m'étonnerait beaucoup que le temps de décodage d'un batch soit significativement modifié par le fait d'utiliser une instruction par ligne ou un "tas compact", je n'arrive vraiment pas à voir l'intérêt d'un regroupement d'instructions sur une ligne unique... Pour moi, c'est vraiment à réserver exclusivement à des choses très précises (ex : exécution d'une commande complexe dans un sous-shell sans créer un batch intermédiaire), mais sûrement pas à l'écriture "normale".

Sur un site comme DVP, je pense que la lisibilité est un facteur crucial dans le code que l'on donne. C'est pour ça que j'indente toujours correctement mon code (y compris en batch), et que je mets des commentaires explicites... Cela ne gêne pas les habitués du langage, mais ça permet aux débutants de s'y retrouver plus facilement.


Certes, ce n'est que mon avis, mais je ne saurais trop t'encourager à en tenir compte. Surtout que tu as un très bon niveau en batch, il serait dommage de "nuire" à la qualité de tes codes pour un problème de lisibilité !

[I'm_HERE]

Surtout que tu as un très bon niveau en batch,

non, je me considère toujours débutant.

[Mac LAK]

non, je me considère toujours débutant.

Si tu crois que parce que tu continues d'apprendre tu es "débutant", t'es bien parti pour mourir débutant...

Pour moi, on cesse d'être débutant quand on commence à plus souvent apprendre aux autres qu'apprendre soi-même. Celui qui cesse d'apprendre n'est pas un "expert", c'est un FOSSILE. Pas pareil...

[Bilou_Gateux]

Tu peux également aller jeter un œil à ce post sur l'utilisation correcte des commandes avec FOR /F : je ne saurais trop te conseiller d'utiliser usebackq avec tes commandes.

Il doit être possible de faire ça avec seulement deux boucles imbriquées, je pense.

J'avoue ne jamais m'être posé la question de l'utilité ou non de usebakq. Merci de m'avoir éclairé sur son objectif.

Par concision, j'entendais justement avoir le minimum de boucles imbriquées.

La solution de I'm_HERE répond à mes attentes :

salut,



:: untested.bat

Merci, résultat OK. Une seule modification de ma part pour toujours être postionné dans le bon répertoire en cas d'appel de ce batch depuis un autre.

@echo off &Setlocal enableextensions


Set "source=%ProgramFiles%\Eset\ESET Online Scanner\Modules\data\updfiles\"

pushd "%source%"

for /f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do (
for %%c in (*.nup) do find "%%a" <"%%c">nul && echo ren "%%c" "%%b"
)
popd
pause
goto :eof

[TABLE]
LOADER0 em000_32_l0.nup
PERSEUS0 em001_32_l0.nup
PERSEUS1 em001_32_l1.nup
ENGINE0 em002_32_l0.nup
ENGINE1 em002_32_l1.nup
ENGINE2 em002_32_l2.nup
ARCHIVES0 em003_32_l0.nup
ADVHEUR0 em004_32_l0.nup
ADVHEUR1 em004_32_l1.nup
CLEANER0 em005_32_l0.nup
CLEANER1 em005_32_l1.nup
CLEANER2 em005_32_l2.nup
ANTISTEALTH0 em006_32_l0.nup
ANTISTEALTH1 em006_32_l1.nup
ANTISTEALTH2 em006_32_l2.nup

[I'm_HERE]

Merci, résultat OK. Une seule modification de ma part pour toujours être postionné dans le bon répertoire en cas d'appel de ce batch depuis un autre.

merci du retour

[Bilou_Gateux]

merci du retour

Après avoir testé en réel (cad sans l'echo devant la commande ren), Je m'aperçoie en définitive que le script renvoie 'la syntaxe de la commande est incorrecte' autant de fois que j'ai de fichiers à renommer avant de réellement renommer ces fichiers.
En testant avec l'echo activé, je n'avais pas tenu compte des résultats de l'echo avant les commandes ren proprement dites.

Exemple avec 13 fichiers .nup dans le dossier

ren "nod5703.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod42FC.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod5E22.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod61B3.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod38E5.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod2ACF.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod07E5.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod2A08.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod0EEA.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod1C11.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod2827.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod7479.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod7A69.nup" "/f "tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do ("
ren "nod42FC.nup" "em002_32_l0.nup"
ren "nod5E22.nup" "em002_32_l1.nup"
ren "nod61B3.nup" "em002_32_l2.nup"
ren "nod38E5.nup" "em003_32_l0.nup"
ren "nod2ACF.nup" "em004_32_l0.nup"
ren "nod5703.nup" "em004_32_l1.nup"
ren "nod07E5.nup" "em005_32_l0.nup"
ren "nod2A08.nup" "em005_32_l1.nup"
ren "nod0EEA.nup" "em005_32_l2.nup"
ren "nod1C11.nup" "em006_32_l0.nup"
ren "nod2827.nup" "em006_32_l1.nup"
ren "nod7479.nup" "em006_32_l2.nup"

%%c prend la valeur du nom de fichier nod0x????.nup
%%b prend la valeur d'une partie de la commande du script %~s0
ensuite les fichiers sont renommés.

[I'm_HERE]

j'ai pas eu ce problème dans mes tests,

essaye en ajoutant un "skip=1" dans ta première boucle

[Bilou_Gateux]

j'ai pas eu ce problème dans mes tests,

essaye en ajoutant un "skip=1" dans ta première boucle

C'est mieux ainsi !

Je poste à nouveau le code final qui donne satisfaction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
@echo off &Setlocal enableextensions


Set "source=R:\temp\Updfiles\"

pushd "%source%"

for /f "skip=1 tokens=1*" %%a in ('findstr /R "_32_l[0-2]*" %~s0') do (
for %%c in (*.nup) do find "%%a" <"%%c">nul && echo ren "%%c" "%%b"
)
popd
pause
goto :eof

[TABLE]
LOADER0 em000_32_l0.nup
PERSEUS0 em001_32_l0.nup
PERSEUS1 em001_32_l1.nup
ENGINE0 em002_32_l0.nup
ENGINE1 em002_32_l1.nup
ENGINE2 em002_32_l2.nup
ARCHIVES0 em003_32_l0.nup
ADVHEUR0 em004_32_l0.nup
ADVHEUR1 em004_32_l1.nup
CLEANER0 em005_32_l0.nup
CLEANER1 em005_32_l1.nup
CLEANER2 em005_32_l2.nup
ANTISTEALTH0 em006_32_l0.nup
ANTISTEALTH1 em006_32_l1.nup
ANTISTEALTH2 em006_32_l2.nup