[XSLT] regroupement dans un regroupement.

Invité · 08/04/2010, 08h38

Bonjour,

Je souhaite effectué un 1er regroupement (celui la j'y arrive), puis ensuite un 2nd en plus du premier (et la ça bloque) pour au final afficher les titres trié pa LIEU puis par CAT

voici un exemple de code XML sur lequel j'aimerais appliqué ce procédé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
<BIBLIO>
 
	<LIVRES>
 
		<LIVRE isbn="i_123" cat="NR">
			<TITRE>Les fourmis</TITRE>
			<AUTEUR>Bernard Werber</AUTEUR>
			<EDITEUR>Albin Michel</EDITEUR>
			<LIEU>ex_biblio1</LIEU>
		</LIVRE>
 
		<LIVRE isbn="i_762" cat="P">
			<TITRE>Capitaine Hornblower</TITRE>
			<AUTEUR>C.S Forester</AUTEUR>
			<LIEU>ex_biblio2</LIEU>
		</LIVRE>
 
		<LIVRE isbn="i_521" cat="NR">
			<TITRE>Hercule Poirot</TITRE>
			<AUTEUR>Agatha CHRISTIE</AUTEUR>
			<EDITEUR>Bodley Head</EDITEUR>
			<LIEU>ex_biblio1</LIEU>
		</LIVRE>

et voici mon code XSLT pour le 1er regroupement (peut-être moche car c'est la 1ère fois que j'utilise la méthode muench...)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
<xsl:key name="regrouperL" match="LIEU" use="."/>
 
    <xsl:template match="/BIBLIO">
     ...                    
                    <xsl:apply-templates select="LIVRES/LIVRE"/> 
     ...
    </xsl:template>
 
 
    <xsl:template match="LIVRE">
        <td>
            <xsl:apply-templates select="LIEU[generate-id(.)=generate-id(key('regrouperL',.)[1])]"/>
        </td>    
    </xsl:template>
 
 
    <xsl:template match="LIEU">
        <tr>
            <td>
                <xsl:copy-of select="."/>
            </td>
            <td>
                <xsl:apply-templates select="//LIVRE/TITRE[../LIEU = current()]"/>
            </td>
        </tr>
    </xsl:template>
 
 
    <xsl:template match="TITRE">      
    <li>
        <xsl:value-of select="."/>
    </li>
    </xsl:template>

En sortie, j'ai un tableau avec 2 colonnes, 1 pour chaque lieu, et ls livres sont bien dans leur bonne colonne.
Maintenant il me faut réitiré ce procédé sur le nouvelle arbre en triant par l'attribut "cat"...

J'ai beau rééssayer d'appliqué Muench, j'obtiens un tableau vide à la fin...

Merci pour vos remarques.

PS: JE N'AI PAS LE DROIT AU FOR EACH POUR CETTE APPLICATION ^^

**Erwy** · 08/04/2010, 09h07

je ne suis pas sûr de comprendre ou vous voulez en venir

Vous pourriez montrer le resultat que vous voulez obtenir ?

une optimisation :
plutot que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
<xsl:apply-templates select="//LIVRE/TITRE[../LIEU = current()]"/>

preferez

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
<xsl:apply-templates select="key('regrouperL',current())/../TITRE"/>
[

Invité · 08/04/2010, 09h21

j'aimerais un résultat, après mise en forme, du genre

lieu1

cat1

livreA
livreD

cat2

livreC
livreZ

lieu2

cat1

livreT

cat2

livreS
livreR

Invité · 08/04/2010, 09h42

Je dois avancer légèrement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
    <xsl:key name="grpCategorie" match="@cat" use="." />
    <xsl:key name="grpSecteur" match="LIEU" use="." />
 
    <xsl:template match="/BIBLIO">
        <HTML>
            <head>
                <META http-equiv="Content-Type" content="text/html ; charset=UTF-8"/>
                <title>Bibliothèque</title>
            </head>
                <xsl:apply-templates select="//@cat[generate-id()=generate-id(key('grpCategorie',.)[1])]"/>
        </HTML>
    </xsl:template>
 
    <xsl:template match="@cat">
        <xsl:variable name="categorie" select="."/>
        <h1>Categorie : <xsl:value-of select="$categorie"/></h1>
        <xsl:apply-templates select="//LIVRE[@cat=$categorie]/LIEU[generate-id()=generate-id(key('grpSecteur',.)[1])]"/>
    </xsl:template>
 
    <xsl:template match="LIEU">
        <xsl:variable name="lieux" select="."/>
        <h2>Lieu : <xsl:value-of select="$lieux"/></h2>
        <xsl:apply-templates select="//LIVRE[LIEU=$lieux]"/>
    </xsl:template>

Je trouve mes catégories, les livres sont dans le bon lieu, mais pas dans la bonne catégorie, on dirait que des qu'il match un lieu, il prend tous les livres qui lui corresponde...

Categorie : NR

Lieu : ex_biblio1

Les fourmis
Hercule Poirot

Categorie : C

Lieu : ex_biblio2

Capitaine Hornblower
La Bible
Number, the Language of Science
Tales of Grandpa Cat
Language and the Science of Number
Evolution of Complexity in Animal Culture
Patterns of Crime in Animal Culture
When We Were Very Young
Learn Java Now
Design Patterns

Categorie : S
Categorie : F
Categorie : P

**Erwy** · 08/04/2010, 10h38

oui vous vous rapprochez de la solution, j'ai fais ça à partir de votre exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
	<xsl:key name="regrouperL" match="LIEU" use="."/>
	<xsl:key name="regrouperC" match="@cat" use="concat(../LIEU,.)"/>
	<xsl:template match="/BIBLIO">
     ...                    
                    <xsl:apply-templates select="LIVRES/LIVRE"/> 
     ...
    </xsl:template>
	<xsl:template match="LIVRE">
		<table>
			<xsl:apply-templates select="LIEU[generate-id(.)=generate-id(key('regrouperL',.)[1])]"/>
		</table>
	</xsl:template>
	<xsl:template match="LIEU">
		<tr>
			<td>
				<xsl:copy-of select="."/>
			</td>
			<td>
				<xsl:apply-templates select="//@cat[generate-id(.)=generate-id(key('regrouperC',concat(current(),.))[1])]"/>
			</td>
		</tr>
	</xsl:template>
	<xsl:template match="@cat">
		<xsl:value-of select="."/>
		<xsl:apply-templates select="key('regrouperC',concat(../LIEU,current()))/../TITRE"/>
	</xsl:template>
	<xsl:template match="TITRE">
		<li>
			<xsl:value-of select="."/>
		</li>
	</xsl:template>
</xsl:stylesheet>

Invité · 08/04/2010, 11h22

J'étais pas loin et j'ai réussi finalement, mais la tienne est plus optimale et plus courte que la mienne

Merci beaucoup

Invité · 20/04/2010, 21h53

Hum, finalement, en m'attardant un peu plus sur votre réponse, j'ai compris la clé associé à LIEU, mais celle associé à CAT, du tout !

Si vous pouviez me donner quelques explications sur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:key name="regrouperC" match="@cat" use="concat(../LIEU,.)"/>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:apply-templates select="key('regrouperC',concat(../LIEU,current()))/../TITRE"/>

Merci d'avance

Invité · 22/04/2010, 11h48

Vraiment personne qui comprend ces 2 lignes de code ? (même si vous avez pas l'arbre XML sous les yeux ?)

**thelvin** · 22/04/2010, 12h10

Je ne suis pas très à l'aise, mais de ce que j'en comprends :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:key name="regrouperC" match="@cat" use="concat(../LIEU,.)"/>

La première groupe les attributs @cat du document par couple (nom-de-lieu,nom-de-categorie)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:apply-templates select="key('regrouperC',concat(../LIEU,current()))/../TITRE"/>

Cela appelle le template de titre, pour tous les titres de livres qui ont la même catégorie et le même lieu que le nœud de l'attribut @cat considéré.

**Erwy** · 27/04/2010, 11h50

Oui c'est ça en effet

[XSLT] regroupement dans un regroupement.

XSL/XSLT/XPATH XML

Discussions similaires

Partager

Partager