Discussion :

[bravojr]

bonjour,
j'aimera supprimer tous les noms commençant par "AAA"...
voici le code que j'ai fait mais il ne marche pas... il ne fait rien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub EffaceNom()
    Dim Nom As Name
        For Each Nom In ActiveWorkbook.Names
        If Left(Nom, 3) = "AAA" Then
        Nom.Delete
        End If
    Next Nom
End Sub

je me suis inspiré du code suivant qui marche mais qui n'est pas du tout sélectif....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub EffaceNom()
    Dim Nom As Name
        For Each Nom In ActiveWorkbook.Names
         Nom.Delete
     Next Nom
End Sub

merci de votre aide !

[Access Newbie]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub EffaceNom()
    Dim Nom As Name
        For Each Nom In ActiveWorkbook.Names
        If LCase(Left(Nom.Name, 3)) = "aaa" Then
        Nom.Delete
        End If
    Next Nom
End Sub

Comme ça cela devrait mieux marcher

[bravojr]

Merci de ta réponse

mais cela ne marche pas....ça n'efface aucun de mes noms
j'ai essayé avec UCase mais rien...

[sabzzz]

bonjour bravojr, Access Newbie,

j'ai fait un test avec la macro de Access Newbie, et cela fonctionne bien,
bravojr, as tu mit la macro dans un module standard du fichier concerné ?

[Access Newbie]

Quand tu parles de "noms", tu parles bien des noms que tu obtiens en faisant "Insertion/Noms/Définir" ?

[bravojr]

oui je parle bien de "Insertion/Noms/Définir"
et la macro de Access Newbie est bien dans un module standard!

je viens de faire un test sur un nouveau classeur ça marche....
mais pas sur mon classeur de "travail"!!!

bon en diminuant les données en en le comprimant j'ai réussi à le mettre en pièce jointe
merci de votre aide

[Access Newbie]

ta pièce jointe n'est pas valide (clique sur le lien que tu as mis)

[bravojr]

désolé mais j'avais trop réduit les données donc plus rien ne marchait... j'ai donc changé la pièce jointe...

[Access Newbie]

Hééé hoplaaa !!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub EffaceNom()
 
Dim Nom As Name
Dim strResult As Variant
 
 
For Each Nom In ActiveWorkbook.Names
    strResult = Split(Nom.Name, "!")
    strResult = strResult(UBound(strResult))
    If LCase(Left(strResult, 3)) = "aaa" Then
        Nom.Delete
    End If
Next Nom
 
End Sub

Petite explication, les noms que tu as définit sont préfixés par "requete", j'ignore pourquoi, il fallait donc récupérer la deuxième partie du nom

Enjoy

[bravojr]

he bien alors là chapeau !

merci beaucoup... je n'y serai jamais arrivé

peux-tu m'expliquer cette partie du code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    strResult = Split(Nom.Name, "!")
    strResult = strResult(UBound(strResult))

Et juste pour ma culture perso, où as tu vu que les étaient préfixés par "requete" ?

encore merci

[Access Newbie]

la fonction split découpe une chaine de caractère (cette chaine est le premier paramètre de la fonction). Le 2nd paramètre permet de définir quel est le caractère sur lequel tu veux que ta découpe se fasse.

Par exemple, pour ton cas Nom.name était de la forme "Requete!AAArequete1"

le split te crée 2 chaines de caracteres :
- une dans laquelle il y a "requete", l'autre dans lquelle il y a "AAArequete1"

Pour le ubound, ceci est utilisé pour les tableaux (variables variant ou tableau). Dans le cas présent, ceci te permet de récupérer la dernière valeur du tableau : "AAArequete1"

Je sais pas si j'ai été très clair.

Sinon pour aller plus loin http://msdn.microsoft.com/fr-fr/libr...5f(VS.80).aspx


Pour voir ou était l'erreur, j'ai placé un point d'arret dans le code, puis j'ai passé le code en "pas à pas" (touche F8) et j'ai mis un espion sur ma variable name (clique droit sur la variable, puis "ajouter un espion")

Et voilou

[bravojr]

eh bien franchement merci!

ton code me fait penser au serpent qui ce mord la queue !! j'ai bien compris les formules mais j'ai eu du mal pour la logique !
donc voici le code avec un peut plus d'informations..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
'le nom du champ créé est du type "Requete!aaaRequete"
'===================
    Dim Nom As Name
    Dim strResult As Variant
'===================
    For Each Nom In ActiveWorkbook.Names
        strResult = Split(Nom.Name, "!")
        ' "split" : séparation en fonction de "!"
        ' "strResult" est défini comme un tableau 1x2 (0 et 1 indices) de contenu : "Requete" ; "aaaRequete"
        strResult = strResult(UBound(strResult))
        ' "UBond(strResult)" = valeur indices max du tableau : 1 (indices = 0 et 1)
        ' "strResult(1)" valeur 1 du tableau 1x2 (indices = 0 et 1)
        ' "strResult" est donc redéfini comme la seconde valeur du tableau "strResult" précédement défini
            If LCase(Left(strResult, 3)) = "aaa" Then
            Nom.Delete
            End If
    Next Nom

aller encore merci