Discussion :

[niamo]

Bonjour, j'aimerais savoir comment faire pour créer une macro qui change la police d'un document word svp, j'ai essayer quelques trucs mais rien ne marche. Pour l'instant j'ai ce code, mais cela ne marche pas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With DocWD2.ActiveDocument.Sections(1)
      .Footers(wdHeaderFooterPrimary).Range.Characters.Font.Size = 8
    End With

[mercatog]

Pour répondre à tes deux sujet en un seul

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim WdApp As Word.Application
Dim WdDoc As Word.document
 
Set WdApp = New Word.Application
WdApp.Visible = True
Set WdDoc = WdApp.documents.Open("C:\Documents and Settings\POSTE F\Bureau\Decl.doc")
With WdDoc.Sections(1)
    With .Footers(wdHeaderFooterPrimary).Range
        .Font.Size = 25
        .Text = Replace(.Text, "Med", "BlaBlaBla")
    End With
End With
WdDoc.Save
WdDoc.Close
WdApp.Quit
Set WdDoc = Nothing
Set WdApp = Nothing

Néanmoins, il faut ajouter une routine au cas où ton document Word est déjà ouvert.

à l'aide la FAQ de ce magnifique forum, http://excel.developpez.com/faq/inde...DocumentOuvert
et pour ma pratique personnelle, je me suis permis d'apprendre quelque chose, je propose le code global tenant compte de la vérification si le document est déjà ouvert

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Dim WdApp As Word.Application
Dim WdDoc As Word.document
Dim wdFich As String
 
wdFich = "C:\Documents and Settings\POSTE F\Bureau\Decl.doc"
 
On Error Resume Next
    Set WdApp = GetObject(, "Word.Application")
    Set WdDoc = WdApp.Documents(wdFich)
On Error GoTo 0
If WdDoc Is Nothing Then
    On Error Resume Next
    Set WdApp = New Word.Application
    Set WdDoc = WdApp.Documents.Open(wdFich)
    On Error GoTo 0
End If
If Not WdDoc Is Nothing Then
    With WdDoc.Sections(1)
        With .Footers(wdHeaderFooterPrimary).Range
            .Font.Size = 8
            .Text = Replace(.Text, "Kuku", "Nana")
        End With
    End With
    WdDoc.Save
    WdDoc.Close
Else
    MsgBox "Chemin fichier " & wdFich & " invalide"
End If
WdApp.Quit
Set WdDoc = Nothing
Set WdApp = Nothing

[niamo]

Un grand merci encore a toi mercatog