Discussion :

[ccedos]

Bonjour,

j'ai réalisé un classeur de 4 pages et je souhaite exporter vers un fichier texte une plage(A : D) de l'une des 4 feuilles (celle nommée "badugi") toutes les minutes en supprimant les lignes vides.
Le code ci-dessous fonctionne seulement si je me trouve sur la feuille en question.
Si cette feuille n'est pas active donc que je suis sur un autre onglet j'ai une erreur d'exécution 1004: La méthode Select de la classe Range a échoué.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
Sub enregistre()
 
' enregistre Macro
 
DansUneMinute = TimeSerial(Hour(Time), Minute(Time), Second(Time) + 60)
Application.OnTime DansUneMinute, "enregistre"
 
' Active une plage de cellule sur la feuille "badugi" même si elle est non active
Worksheets("badugi").Range("A1:F" & Sheets("badugi").Range("F65536").End(xlUp).Row).Select
 
' Déclaration variables
Dim i, j, nl, nc As Integer
Dim text As String
 
' Ouverture fichier d'enregistrement
Open "C:\Users\Cédric\Desktop\Badugi\badugi.txt" For Output As #1
nc = Selection.Columns.Count
nl = Selection.Rows.Count
 
' Boucle sur la selection
For i = 1 To nl
text = ""
For j = 1 To nc
' ajout de la tabulation comme separateur
If text <> "" Then text = text & Chr(9)
text = text & ActiveWindow.RangeSelection.Next(i, j - 1)
Next j
' Ecriture de la ligne dans le fichier si non vide
If text <> "" Then Print #1, text
Next i
 
' Fermeture fichier
Close #1
 
ActiveWorkbook.Save
 
End Sub

Merci de m'aider à trouver pourquoi.
Lire la suite ...
VBA EXCEL 2007 problème de sélection de plage »
J'ai une réponse

[le_dilem]

Si cette feuille n'est pas active donc que je suis sur un autre ....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("badugi"). Select

[mercatog]

Sans sélectionner les plages de données ou les feuilles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub enregistre()
Dim i As Long, nl As Long
Dim j As Integer, nc As Integer
Dim strTexte As String
Dim DansUneMinute As Date
Dim plage As Range
 
'DansUneMinute = TimeSerial(Hour(Time), Minute(Time), Second(Time) + 60)
'Application.OnTime DansUneMinute, "enregistre"
 
Set plage = Sheets("badugi").Range("A1:F" & Sheets("badugi").Range("A65536").End(xlUp).Row)
   Open "C:\Users\Cédric\Desktop\Badugi\badugi.txt" For Output As #1
   nc = plage.Columns.Count
   nl = plage.Rows.Count
   For i = 1 To nl
      If Application.CountBlank(plage.Rows(i)) < nc Then
         For j = 1 To nc
            strTexte = strTexte & Chr(9) & plage.Cells(i, j)
         Next j
         Print #1, Mid(strTexte, 2)
         strTexte = ""
      End If
   Next i
   Close #1
Set plage = Nothing
ActiveWorkbook.Save
End Sub

[ccedos]

Bonjour le_dilem, bonjour mercatog,


le_dilem que j'écrive Worksheets ou Sheets, la macro s'exécute de la même manière.

mercatog c'est exactement ce que je voulais et sur quoi je me suis cassé la tête tout le week-end

Un grand merci