Discussion :

[topmas]

Salut à tous,

J'ai un fichier XML avec la structure suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
<noeud type="delimiteur" />
<noeud type="contenu" />
<noeud type="contenu" />
<noeud type="delimiteur" />
<noeud type="contenu" />
<noeud type="contenu" />

que j'aimerais transformer en la structure :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
<noeud type="delimiteur">
            <noeud type="contenu" />
            <noeud type="contenu" />
</noeud type="delimiteur">
<noeud type="delimiteur">
              <noeud type="contenu" />
              <noeud type="contenu" />
</noeud type="delimiteur">

En gros transformer les noeuds avec l'attribut type="contenu" en fils de leur frêre type="délimiteur" précédent.

J'ai essayé pas mal de choses, mais je n'arrive pas à trouver la syntaxe correcte.

Une solution serait pour chaque délimiteur d'appeler un template pour tous ses frêres ayant une position plus petite que celle de son prochain frêre délimiteur.
Savez vous comment récupérer la position d'un noeud non courant ?


Merci d'avance si vous avez une solution

[Morbo]

C'est le principe de la méthode de muench :
http://xml.developpez.com/faq/?page=3#xslt_regroup
Il y a pas mal de ressources dessus sur le net.

[thelvin]

C'est le principe de la méthode de muench :
http://xml.developpez.com/faq/?page=3#xslt_regroup
Il y a pas mal de ressources dessus sur le net.

Hum. Tu es sûr ?

Je reconnais que je ne suis pas très doué en XSLT, mais la seule méthode que je trouve pour faire ça, n'a pas grand-chose à voir avec la méthode Muench. Au fond, l'idée de Muench est d'effacer ou fusionner des doublons. Or il n'est pas question de doublon ici.

Personnellement, je me base à coup de following-sibling dont le premier preceding-sibling délimiteur a le même generate-id() que le délimiteur encadrant.

Un truc genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

following-sibling::*[@type='contenu'][generate-id(preceding-sibling::*[@type='delimiteur'][1]) = generate-id(current())]

[Morbo]

Oui, autant pour moi, j'ai lu regroupement => muench
Mais là, c'est en fonction d'un séparateur.

[Erwy]

non, ce n'est pas du muench par contre on peut produire un code assez simple, et des xpath aussi, en utilisant les xsl:key

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
	<xsl:key name="fils" match="noeud [@type='contenu']" use="generate-id(preceding-sibling::noeud[@type='delimiteur'][1])"/>
	<xsl:template match="/">
		<r>
			<xsl:apply-templates select="//noeud [@type='delimiteur']"/>
		</r>
	</xsl:template>
	<xsl:template match="noeud [@type='contenu']">
		<xsl:copy-of select="."/>
	</xsl:template>
	<xsl:template match="noeud [@type='delimiteur']">
		<xsl:copy>
			<xsl:attribute name="type"><xsl:value-of select="@type"/></xsl:attribute>
			<xsl:apply-templates select="key('fils',generate-id())"/>
		</xsl:copy>
	</xsl:template>
</xsl:stylesheet>

[topmas]

Merci beaucoup, la solution de Erwy marche parfaitement !