Piloter une application externe

**Asdorve** · 23/07/2010, 09h53

Bonjour à tous,

Je cherche à piloter une appli externe (développée en Windev)

Pour celà j'utilise les handles de mes fenetres et des composants.

Puis j'envoie des instructions

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
lRet = SendMessage(ChampOuLabel, WM_SETTEXT, 0, "10")

Lorsque j'envoie l'instruction ci-dessus, des caractères bizarres s'affichent dans le champ.

Lorsque je fais un WM_GETTEXT pour récupérer la valeur du champ (par ex: 10) il me retourne le 1 suivi d'un carré.

D'après vous, de quoi est-ce que celà peut provenir?

Merci d'avance.

**DarkVader** · 23/07/2010, 10h11

Bonjour,
Sans indiquer la valeur de ce caractère «bizarre», cela va être difficile de te répondre.
A tout hasard, ce ne serait pas un Carriage Return ou un car 0 ?

**Asdorve** · 23/07/2010, 10h16

ça varie à chaque fois (pour la même valeur envoyée):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
œZ 
ì
|°

**l_autodidacte** · 23/07/2010, 11h55

Le dernier paramètre doit être ByVal, essaie ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const WM_GETTEXT = &HD
Private Const WM_SETTEXT = &HC
Dim lRet&
 
Private Sub Command1_Click()
    lRet = SendMessage(Text1.hwnd, WM_SETTEXT, -1, ByVal "BONJOUR")
    lRet = SendMessage(Command1.hwnd, WM_SETTEXT, -1, ByVal "BONJOUR")
End Sub

**Asdorve** · 23/07/2010, 11h59

ok, merci beaucoup, ça marche.

A y être, j'ai le handle du bouton "OK", comment lancer le clic du bouton avec SendMessage?

Je regarde la piste du WM_COMMAND, mais sans succès pour l'instant.

**l_autodidacte** · 23/07/2010, 13h30

Ajoute au code précédent ce

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Const BM_CLICK& = &HF5&
Private Sub Form_Load()
    lRet = SendMessage(Command1.hwnd, BM_CLICK, 0&, 0&)
End Sub

Tu peux utiliser Form_Click au lieu de Form_Load pour mieux voir le résultat.
Bonne journée.

**Asdorve** · 23/07/2010, 15h13

super, ça marche.

Où est-ce que tu trouves toutes ces infos? ça me serait bien utile, parce que je galère.
Là je dois envoyer une instruction pour double cliquer sur une valeur d'une listbox...

**l_autodidacte** · 23/07/2010, 17h12

Voici tout le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const WM_GETTEXT = &HD
Private Const WM_SETTEXT = &HC
Dim lRet&
Private Const WM_LBUTTONDBLCLK = &H203
Private Const BM_CLICK& = &HF5&
 
Private Sub Command1_Click()
    lRet = SendMessage(Text1.hwnd, WM_SETTEXT, 0, ByVal "BONJOUR")
    lRet = SendMessage(Command1.hwnd, WM_SETTEXT, 0, ByVal "BONJOUR")
End Sub
 
Private Sub Form_DblClick()
    lRet = SendMessage(Text1.hwnd, WM_LBUTTONDBLCLK, 0&, 1&)
    lRet = SendMessage(List1.hwnd, WM_LBUTTONDBLCLK, 0&, 1&)
End Sub
 
Private Sub Form_Load()
    lRet = SendMessage(Command1.hwnd, BM_CLICK, 0&, 0&)
    With List1
     .AddItem Text1.Text & UCase(" Asdorve")
     .AddItem Me.Caption
     .AddItem Now
    End With
End Sub
Private Sub List1_DblClick()
  'List1 ne doit être vide, sinon pas de réaction
  With List1
      .BackColor = vbGreen
      .FontName = "Arial Black"
      .FontSize = 14
  End With
End Sub
 
Private Sub Text1_DblClick()
    Text1.ForeColor = vbRed
    Text1.FontBold = 1
    Text1.FontSize = 16
End Sub

Double-clique sur la feuille et tu verras les changements dans les contrôles.
MSDN contient presque la totalité des astuces et aide à la programmation.
Autre chose qu'il ne faut négliger : La visionneuse d'API Apiloader.exe.

Bonne journée