Discussion :

[ANOVA]

Bonjour,

j'ai programmé une fonction qui copie des données d'une feuille appelée "Classement" vers une feuille appelée "Classement2". Je souhaite trier les données contenues dans "Classement2" sans que cette feuille ne soit visible. Voici mon programme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public Sub trierClassementTE()
    'Modification : Récupère les données de la feuille "Classement",
    'Copie ces données dans "Classement2",
    'Puis trie ces données
 
    Dim derniereCellule As Range
    Dim plage As Range
 
    Set derniereCellule = Sheets("Classement").Range("A3").End(xlDown).Offset(0, 1)
    Sheets("Classement").Range("A3", derniereCellule).Copy
    Sheets("Classement2").Range("A2").PasteSpecial Paste:=xlPasteValues
 
    Sheets("Classement").Range("D3", derniereCellule.Offset(0, 2)).Copy
    Sheets("Classement2").Range("C2").PasteSpecial Paste:=xlPasteValues
 
    Set derniereCellule = Sheets("Classement2").Range("A2").End(xlDown).Offset(0, 2)
    Set plage = Sheets("Classement2").Range("A2", derniereCellule)
 
    plage.Sort Key1:=Range("B1"), Order1:=xlDescending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
        DataOption1:=xlSortNormal
End Sub

Lorsque je teste cette fonction en la lançant depuis la feuille "Classement2", tout se passe bien : ma fonction renvoie bien ce que je veux. Seulement, lorsque le lance cette fonction alors que la feuille active est une autre feuille que "Classement2", j'ai l'erreur :

Erreur d'exécution '1004':

Erreur définie par l'application ou par l'objet

ce qui me pose problème étant donné que je souhaite faire tourner cette fonction sans que la feuille "Classement2" ne soit visible.

Ma question est donc : est il possible de trier des données sans que le focus soit sur la feuille où on effectue le tris ?

Je vous remercie.

[thorg]

Oui ce que tu cherches à faire est tout à fait possible.
Néanmoins cela requiert de coder différemment que si tu es dans une feuille active.
Je suis confronté au même problème et je suis convaincu que l'utilisation de code qui reflète une action spécifique de l'utilisateur dans l'activesheet ne fonctionne pas sans activesheet.

Je te conseille pour déboguer, de lancer ton code en pas à pas, par pression de F8 successives pour détecter ce qui ne passe pas. Et aussi de regarder dans la fenêtre locals les valeurs des variables et objets.

Cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set derniereCellule = Sheets("Classement").Range("A3").End(xlDown).Offset(0, 1)

ne doit pas passer je pense, car xlDown correspond à ctrl+fleche du bas. Ce serait valide dans une feuille activee mais pas dans une feuille non active.
Du moins c'est ce que j'ai déduit de ma faible expérience car je débute en VBA.

Je pense de ce fait soit repasser sur feuille active sinon tu pourrais créer une fonction émule de ce xldown. Ce n'est certainement pas la seule fonction qui pose ce genre de problème.

Enfin, je ne suis pas sûr à 100% et quelqu'un de plus expérimenté pourra certainement en dire plus.

[delphine35]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public Sub trierClassementTE()
    'Modification : Récupère les données de la feuille "Classement",
    'Copie ces données dans "Classement2",
    'Puis trie ces données
 
    Dim derniereCellule As Range
    Dim plage As Range
 
    Set derniereCellule = Sheets("Classement").Range("A3").End(xlDown).Offset(0, 1)
    Sheets("Classement").Range("A3", derniereCellule).Copy
    Sheets("Classement2").Range("A2").PasteSpecial Paste:=xlPasteValues
 
    Sheets("Classement").Range("D3", derniereCellule.Offset(0, 2)).Copy
    Sheets("Classement2").Range("C2").PasteSpecial Paste:=xlPasteValues
 
    Set derniereCellule = Sheets("Classement2").Range("A2").End(xlDown).Offset(0, 2)
    Set plage = Sheets("Classement2").Range("A2", derniereCellule)
 
    plage.Sort Key1:=Range("B1"), Order1:=xlDescending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
        DataOption1:=xlSortNormal
End Sub

change la derniere ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    plage.Sort Key1:=Sheets("Classement2").Range("B1"), Order1:=xlDescending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
        DataOption1:=xlSortNormal

[mapeh]

Bonjour,

Tu essaies de trier ta zone "plage", mais tu lui donnes une mauvaise clé de tri...

Il faut aussi y référencer la feuille

Comme ceci par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim Fc as WorkSheet
Set Fc = Sheets("Classement2")
...
...
Set derniereCellule = Fc.Range("A2").End(xlDown).Offset(0, 2)
Set plage = Fc.Range("A2", derniereCellule)
 
    plage.Sort Key1:=Fc.Range("B1"), Order1:=xlDescending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
        DataOption1:=xlSortNormal

Bonne journée