Discussion :

[pulls]

Bonjour je cherche une formule qui va me permettre de faire ce calcul:

je vais saisir par exemple 3a dans une cellule et le chiffre 2 dans l'autre cellule et ça m'affiche 3c. c'est à dire 3a incrementé de 2 donne 3c. exemple: 4c incrementé de 7 donne 4j.

aidez moi merci

[cb_60]

Bonjour
Un début de pîste:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

GAUCHE(A7;1)&CAR(CODE(DROITE(A7;1))+A8)

en A7 ====3A
en A8====4
la formule en A9 donne 3E

[Iwober]

Bonjour je cherche une formule qui va me permettre de faire ce calcul:

je vais saisir par exemple 3a dans une cellule et le chiffre 2 dans l'autre cellule et ça m'affiche 3c. c'est à dire 3a incrementé de 2 donne 3c. exemple: 4c incrementé de 7 donne 4j.

aidez moi merci

Bonjour,
J'ai regardé ton souci sur Open Office mais sur excel cela doit être pareil.
J'ai mis 3a dans la cellule D16.
J'ai mis 6 dans la cellule F16.
J'ai mis la formule suivante dans la cellule J16:
=CONCATENER(GAUCHE(D16;1);CAR(CODE(STXT(D16;2;NBCAR(D16-1)))+F16))

Est-ce que cela te convient ?
On doit pouvoir faire plus court mais en attendant, c'est mieux que rien.
Maintenant, si tu veux que les cases sopient côte à côte, il te suffit de changer les coordonnées des cellules.

[Invité]

Bonjour,

En effet la formule de CB_60 est plus courte et fonctionne très bien pour ce qui est demandé (tant que le résultat ne va pas plus loin que la 26e colonne).

[cb_60]

re
Oui j'ai mis un debut de piste ne sachant pas trop, mais si deux chiffres ou deux lettres ça ne fonctionne plus, j'ai surtout voulu dégrossir.

[Invité]

C'est vrai mais ce n'est pas demandé pour l'instant et je pense que dans ce cas on doit pouvoir s'en sortir avec "nbcar" (un peu comme proposé par Iwober) à condition que ce ne soit pas presque du hasard, deux chiffres et une lettre, deux lettres et un chiffre et pourquoi pas plus.

Et c'est au demandeur que revient le fait d'être le plus précis possible.

Sinon, il faut, je pense, passer par quelques lignes de code ?

[alsimbad]

Bonjour tt le monde
on pourrait tenter un mod(xx;26) pour rester dans l'alphabet, mais je ne vois pas (encore)de solution pour le gauche, c'est a dire, s'il y a plusieur chiffres avant la lettre

=GAUCHE(A1;1)&(CHOISIR(MOD(EQUIV(DROITE(A1;1);{"a";"b";"c";"d";"e";"f";"g";"h";"i";"j";"k";"l";"m";"n";"o";"p";"q";"r";"s";"t";"u";"v";"w";"x";"y";"z"})+B1;26);"a";"b";"c";"d";"e";"f";"g";"h";"i";"j";"k";"l";"m";"n";"o";"p";"q";"r";"s";"t";"u";"v";"w";"x";"y";"z"))

[pulls]

Bonjour tt le monde,

je vous remercie de vouloir m'aider.

Je veux être plus explicite; je voudrais trouver la catégorie des employés à leur âge de départ en retraite, sachant qu'un employé bénéficie d'un échelon tous les trois ans. Un employé qui a été embauché en 3a au bout de 9ans sera en 3d. le coefficient ici c'est 9/3=3. donc je saisi 3a ds une cellule et 3 dans l'autre je vais voir afficher comme résultat 3d.

Le dernier échelon alphabetique c'est G, mais après G il ya G1, G2, ... G20

donc un employé peut partir de 3A à 3G10 à la retraite.

Cordialement

[tototiti2008]

Bonjour à tous,

un essai, 3A en A1 et 3 en B1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=GAUCHE(A1;1)&CAR(MIN(CODE(MAJUSCULE(STXT(A1;2;1)))+B1;71))&SI(CODE(MAJUSCULE(STXT(A1;2;1)))+B1>71;CODE(MAJUSCULE(STXT(A1;2;1)))+B1-71;"")

[pulls]

La formule de Tototiti2008 marche. je vous remercie infiniment.

encore merci

Je voudrais demander ce que represente le nombre 71 dans cette formule.

[tototiti2008]

Re,

71 est le code de la lettre G (pour se limiter à G)

[pulls]

merci