Discussion :

[cilala]

Bonjour,

J'essaie de créer une macro me permettant de faciliter ma gestion de compte.
Dans la colonne "C" j'indique le type d'opération : virement, retrait, paiement CB, virement, etc ...
Dans la colonne "D" je saisis mes débits et crédits, qui sont donc différenciés par le signe "-".
Le problème est que j'oublie parfois le signe négatif devant les débits, donc je voudrais automatiser cela.

Ce que je cherche à faire, c'est que dès que la valeur dans une cellule de la colonne "D" est saisie, effectuer un controle de
la valeur de la cellule juste à gauche (colonne "C"), et suivant cette valeur ("retrait CB" par exemple) alors passer la valeur saisie en négatif, ou laisser en positif.
Ce controle serait à effectuer dès que je quitte la cellule de la colonne "D".

J'ai commencé à regarder quelques pistes, mais je n'avance pas trop, alors une peu d'aide serait bienvenu.

merci.

[mercatog]

Bonsoir,
à mettre dans l'évènement Change de ta feuille (module de la feuille)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column = 4 Then
    If Target.Count = 1 Then
        On Error Resume Next
        Application.EnableEvents = False
        If Target.Offset(0, -1) = "retrait CB" Then
            If Target.Value > 0 Then Target.Value = -1 * Target.Value
        Else
            If Target.Value < 0 Then Target.Value = -1 * Target.Value
        End If
        Application.EnableEvents = True
    End If
End If

[PPz78]

C'est très bien, mais il faudra compléter l'instruction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Target.Offset(0, -1) = "retrait CB" Then

en y inscrivant tous les types de retrait.

De plus il faut aussi éviter les fautes d'orthographe dans la colonne C, une liste déroulante dans la cellule est à prévoir.

A+
PPz

[Didier Gonard]

Bonjour,

La bonne approche serait à la base d'avoir une colonne Débits et une colonne Crédits différentes

Du coup tu ne mets jamais de signe mais des valeurs absolues et c'est la nature de la colonne qui fait que le nombre sera positif ou non..

cordialement,

Didier

[mercatog]

Une autre variante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub Worksheet_Change(ByVal Target As Range)
Dim sg As Integer, P As Integer, Q As Integer
If Target.Column = 4 Then
    If Target.Count = 1 Then
        P = InStr("paiement CB_retrait_ZZZ", Target.Offset(0, -1)) > 0 And Target.Value > 0
        Q = InStr("Virement_XXX_YYY", Target.Offset(0, -1)) > 0 And Target.Value < 0
        sg = 2 * (P + Q) + 1
        On Error Resume Next
        Application.EnableEvents = False
        If sg <> 1 Then Target.Value = sg * Target.Value
        Application.EnableEvents = True
    End If
End If
End Sub

on met dans le Instr de P, tous les mots (pour lesquels la valeur devrait être négative) séparés par un caractère spécial.
on met dans le Instr de Q, tous les mots (pour lesquels la valeur devrait être positive) séparés par un caractère spécial

[cilala]

Bonjour,

merci à tous pour vos réponses, cela m'a permis de mettre en place ce que je voulais.
J'ai juste complété, sur le même principe, pour faire en sorte que si le type d'opération est modifié dans la colonne "C", cela soit pris en compte dans la colonne "D". A priori ça marche, mais si vous pouvez me confirmer que rien ne cloche ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Sub Worksheet_Change(ByVal Target As Range)
Dim sg As Integer, P As Integer, Q As Integer
If Target.Column = 4 Then
    If Target.Count = 1 Then
        P = InStr("retrait CB_Chèque", Target.Offset(0, -1)) > 0 And Target.Value > 0
        Q = InStr("Virement", Target.Offset(0, -1)) > 0 And Target.Value < 0
        sg = 2 * (P + Q) + 1
        On Error Resume Next
        Application.EnableEvents = False
        If sg <> 1 Then Target.Value = sg * Target.Value
        Application.EnableEvents = True
    End If
End If
 
If Target.Column = 3 Then
    If Target.Count = 1 Then
        P = InStr("retrait CB_Chèque", Target.Value) > 0 And Target.Value > 0
        Q = InStr("Virement", Target.Value) > 0 And Target.Value > 0
        sg = 2 * (P + Q) + 1
        On Error Resume Next
        Application.EnableEvents = False
        If sg <> 1 Then Target.Offset(0, 1) = sg * Target.Offset(0, 1)
        Application.EnableEvents = True
    End I
End If
End Sub

Encore merci

[mercatog]

Plutôt comme ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Worksheet_Change(ByVal Target As Range)
Dim sg As Integer, P As Integer, Q As Integer
On Error GoTo Fin
Application.EnableEvents = False
If Target.Count = 1 Then
    If Target.Column = 4 Then
        P = InStr("retrait CB_Chèque", Target.Offset(0, -1)) > 0 And Target.Value > 0
        Q = InStr("Virement", Target.Offset(0, -1)) > 0 And Target.Value < 0
        sg = 2 * (P + Q) + 1
        If sg <> 1 Then Target.Value = sg * Target.Value
    ElseIf Target.Column = 3 Then
        P = InStr("retrait CB_Chèque", Target.Value) > 0 And Target.Offset(0, 1).Value > 0
        Q = InStr("Virement", Target.Value) > 0 And Target.Offset(0, 1).Value < 0
        sg = 2 * (P + Q) + 1
        If sg <> 1 Then Target.Offset(0, 1) = sg * Target.Offset(0, 1)
    End If
End If
Fin:
Application.EnableEvents = True
End Sub

Ou bien dune façon concise

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub Worksheet_Change(ByVal Target As Range)
Dim sg As Integer, P As Integer, Q As Integer, t As Integer
 
On Error GoTo Fin
Application.EnableEvents = False
If Target.Count = 1 Then
    t = 4 - Target.Column
    If t * (1 - t) = 0 Then
        P = InStr("retrait CB_Chèque", Target.Offset(0, t - 1)) > 0 And Target.Offset(0, t).Value > 0
        Q = InStr("Virement", Target.Offset(0, t - 1)) > 0 And Target.Offset(0, t).Value < 0
        sg = 2 * (P + Q) + 1
        If sg <> 1 Then Target.Offset(0, t).Value = sg * Target.Offset(0, t).Value
    End If
End If
Fin:
Application.EnableEvents = True
End Sub