Discussion :

[damsmut]

Bonjour,

Dans le menu : Données externes --> Importations enregistrées...
J'ai une importation (Excel) enregistrée, nommons la IMP1.

Comment faire pour modifier le chemin d'accès du fichier en VBA ?

Merci
a+
Damsmut

[LedZeppII]

Bonjour,

Quelque chose que j'ai testé vite fait et qui fonctionne chez moi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub SpecImpChangerFichier(strNomSpecImport As String, strNouvFichier As String)
Const STR_PATHTAG = "<ImportExportSpecification Path = """
Dim strNouvXml As String, strXml As String
Dim p1 As Long, p2 As Long, bOk As Boolean
 
strXml = CurrentProject.ImportExportSpecifications(strNomSpecImport).XML
 
p1 = InStr(1, strXml, STR_PATHTAG, vbTextCompare)
If p1 > 0 Then
   p2 = InStr(p1 + Len(STR_PATHTAG), strXml, """")
   If p2 > 1 Then
      strNouvXml = Left(strXml, p1 + Len(STR_PATHTAG) - 1) & _
                   strNouvFichier & Mid(strXml, p2)
      bOk = True
   End If
End If
 
If bOk Then
   CurrentProject.ImportExportSpecifications(strNomSpecImport).XML = strNouvXml
End If
 
End Sub

Premier argument : Nom de la spécification d'importation sauvegardée
Deuxième argument : Nom complet du fichier à importer (Chemin + Nom)

Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub tstSpecImpChangerFichier()
SpecImpChangerFichier "IMP1", _
                      "C:\Mes Documents\ . . . \Le Fichier.xls"
End Sub

A+

[Deustalos]

Hello,

Je ne sais pas si j'ai bien ciblé ton probléme.

Mais moi je passe directement en VBA pour l'importation/Exportation (docmd.transferspreadsheet) et donc à partir de là tu peux définir le chemin du fichier à importer (J'ai couplé cela avec une fenetre de séléction pour que l'utilisateur choisis le fichier à importé) trés trés pratique.

Bon continuation

Alex

[damsmut]

super ça marche merci

[Alexbubu]

Bonjour à tous ,
j'ai le même problème que vous mais la solution est pour mon cas celle de deustalos, puis-je avoir votre code ?
Je doit importer un fichier .CSV avec des spécifications du coup j'aimerais automatisé cela avec un bouton, du coup j'aimerais que ce bouton me demande de selectionné le fichier avant de lancer mon importation enregistrer.
Merci d'avance
Alex